C_MaterialStockByKeyDate

DDL: C_MATERIALSTOCKBYKEYDATE Type: view_entity CONSUMPTION Package: MM_IM_VDM_STOCK

Material Stock at posting date

C_MaterialStockByKeyDate is a Consumption CDS View that provides data about "Material Stock at posting date" in SAP S/4HANA. It reads from 1 data source (I_MaterialStock_2) and exposes 21 fields. Part of development package MM_IM_VDM_STOCK.

1 data source(s) 21 fields

Data Sources (1)

SourceAliasJoin Type
I_MaterialStock_2 I_MaterialStock_2 from

Parameters (2)

NameTypeDefault
P_Language sylangu
P_KeyDate vdm_v_key_date

Annotations (10)

NameValueLevelField
EndUserText.label Material Stock at posting date view
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.modelingPattern #ANALYTICAL_QUERY view
VDM.viewType #CONSUMPTION view
Analytics.query true view
Analytics.technicalName CMATSTOCKBYKDATE view
Metadata.allowExtensions true view

Fields (21)

KeyFieldSource TableSource FieldDescription
Material Material
Plant Plant
StorageLocation StorageLocation
Batch Batch
Supplier Supplier
SDDocument SDDocument
SDDocumentItem SDDocumentItem
WBSElementInternalID
InventoryStockType InventoryStockType
InventorySpecialStockType InventorySpecialStockType
CompanyCode CompanyCode
MaterialBaseUnit MaterialBaseUnit
MatlWrhsStkQtyInMatlBaseUnit MatlWrhsStkQtyInMatlBaseUnit
MaterialName
CompanyCodeName
PlantName
StorageLocationName
SupplierName
CustomerName
InventoryStockTypeName
InventorySpecialStockTypeName 
@EndUserText.label: 'Material Stock at posting date'
@AccessControl.authorizationCheck:#PRIVILEGED_ONLY
@ObjectModel: {
                usageType: {
                             sizeCategory: #XXL,
                             serviceQuality: #D,
                             dataClass:#TRANSACTIONAL
                           },
                modelingPattern: #ANALYTICAL_QUERY,
                supportedCapabilities: [#ANALYTICAL_QUERY]
              }
@VDM.viewType: #CONSUMPTION
@Analytics.query : true
@Analytics.technicalName: 'CMATSTOCKBYKDATE'
@Metadata.allowExtensions: true
define view entity C_MaterialStockByKeyDate
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language : sylangu,
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate  : vdm_v_key_date
  as select from I_MaterialStock_2
{
  // Stock Identifier

  @ObjectModel.text.element: ['MaterialName']
  Material,
  @ObjectModel.text.element: ['PlantName']
  @AnalyticsDetails.query.axis: #ROWS
  Plant,
  @ObjectModel.text.element: ['StorageLocationName']
  StorageLocation,
  Batch,
  @ObjectModel.text.element: ['SupplierName']
  Supplier,
  SDDocument,
  SDDocumentItem,
  cast( WBSElementInternalID as mat_pspnr preserving type ) as WBSElementInternalID,   --I_MaterailStock_2 does a cast to a DE w/o conversion exit, for compatibility reason: cast back
  @ObjectModel.text.element: ['CustomerName']
  Customer,
  @ObjectModel.text.element: ['InventoryStockTypeName']
  InventoryStockType,
  @ObjectModel.text.element: ['InventorySpecialStockTypeName']
  InventorySpecialStockType,

  // Further Stock Groups

  CompanyCode,

  // Quantity and Unit

  MaterialBaseUnit,
  @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit' 
  @AnalyticsDetails.query.axis: #COLUMNS
  MatlWrhsStkQtyInMatlBaseUnit,

  // Names and descriptions

  _Material._Text[1: Language=$parameters.P_Language].ProductName as MaterialName,
  I_MaterialStock_2._CompanyCode.CompanyCodeName,
  I_MaterialStock_2._Plant.PlantName,
  I_MaterialStock_2._StorageLocation.StorageLocationName,
  I_MaterialStock_2._Supplier.SupplierName,
  I_MaterialStock_2._Customer.CustomerName,
  _InventoryStockType._Text[1: Language=$parameters.P_Language].InventoryStockTypeName,
  _InventorySpecialStockType._Text[1: Language=$parameters.P_Language].InventorySpecialStockTypeName
}
where
  MatlDocLatestPostgDate <= $parameters.P_KeyDate

Learn More