C_MasterDataImportTP_2

DDL: C_MASTERDATAIMPORTTP_2 Type: view_entity CONSUMPTION Package: MDC_LOAD

Master Data Import

C_MasterDataImportTP_2 is a Consumption CDS View that provides data about "Master Data Import" in SAP S/4HANA. It reads from 1 data source (I_MasterDataImportTP_2) and exposes 25 fields with key field MasterDataImportUUID. It is exposed through 1 OData service (C_MASTERDATAIMPORTTP_2SD). Part of development package MDC_LOAD.

1 data source(s) Exposed by 1 service(s) 25 fields

Data Sources (1)

SourceAliasJoin Type
I_MasterDataImportTP_2 I_MasterDataImportTP_2 projection

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
EndUserText.label Master Data Import view
Metadata.allowExtensions true view
Search.searchable true view
VDM.viewType #CONSUMPTION view
UI.headerInfo.typeName Import view
UI.headerInfo.typeNamePlural Imports view

OData Services (1)

ServiceBindingVersionContractRelease
C_MASTERDATAIMPORTTP_2SD C_MASTERDATAIMPORTTP_2_V4 V4 C1 NOT_RELEASED

Fields (25)

KeyFieldSource TableSource FieldDescription
KEY MasterDataImportUUID MasterDataImportUUID
MasterDataImportFileName _ImportFile MasterDataImportFileName
MasterDataImportStatus MasterDataImportStatus
MasterDataImportStatusTextlocalized
MDImportStatusCriticality MDImportStatusCriticality
MasterDataImportSourceSystem MasterDataImportSourceSystem
MasterDataImportSourceFilter MasterDataImportSourceFilter
MasterDataImportObjectTypeCode MasterDataImportObjectTypeCode
MDChgProcessGoal MDChgProcessGoal
MDImprtIsSkipConflictRecdReqd MDImprtIsSkipConflictRecdReqd
MasterDataImportCreator MasterDataImportCreator
CreatedByUserName _ImportUserVH CreatedByUserName
MDImportCreationDateTime MDImportCreationDateTime
MDImportCreationDate MDImportCreationDate
MDImportFileTemplateName MDImportFileTemplateName
MDImportFileTemplateMimeType MDImportFileTemplateMimeType
MDImportFileTemplateBinary MDImportFileTemplateBinary
MDImportFileIsUploaded MDImportFileIsUploaded
MDImportSourceSystemIsOmitted MDImportSourceSystemIsOmitted
MDImprtNmbrOfRecordsImported MDImprtNmbrOfRecordsImported
MasterDataChangeProcess MasterDataChangeProcess
_ImportUserVH _ImportUserVH
_ImportStatusVH _ImportStatusVH
_ImportSystemVH _ImportSystemVH
_RequestorContactCard _RequestorContactCard 
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [
  '_RequestorContactCard'
]
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@EndUserText.label: 'Master Data Import'
@Metadata.allowExtensions: true
@Search.searchable: true
@VDM.viewType: #CONSUMPTION
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@ObjectModel.semanticKey: ['MasterDataImportUUID', 'MasterDataImportFileName']
@UI.headerInfo: { typeName: 'Import', typeNamePlural: 'Imports' }
define root view entity C_MasterDataImportTP_2
  provider contract transactional_query 
  as projection on I_MasterDataImportTP_2
{
  key MasterDataImportUUID,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.6
      _ImportFile.MasterDataImportFileName,
      @ObjectModel.text.element: ['MasterDataImportStatusText']
      MasterDataImportStatus,
      _ImportStatusVH._Text.MasterDataImportStatusText : localized,
      MDImportStatusCriticality,
      @Search.defaultSearchElement: true
      MasterDataImportSourceSystem,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      MasterDataImportSourceFilter,
      MasterDataImportObjectTypeCode,
      MDChgProcessGoal,
      MDImprtIsSkipConflictRecdReqd,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @ObjectModel.text.element: ['CreatedByUserName']
      MasterDataImportCreator,
      _ImportUserVH.CreatedByUserName,
      @Semantics.systemDateTime.createdAt:true
      MDImportCreationDateTime,
      @Semantics.systemDate.createdAt:true
      MDImportCreationDate,
      //not persisted fields

      MDImportFileTemplateName,
      MDImportFileTemplateMimeType,
      @Semantics.largeObject.contentDispositionPreference: #ATTACHMENT
      @Semantics.largeObject.fileName: 'MDImportFileTemplateName'
      @Semantics.largeObject.mimeType: 'MDImportFileTemplateMimeType'
      MDImportFileTemplateBinary,
      MDImportFileIsUploaded,
      @Semantics.booleanIndicator: true
      MDImportSourceSystemIsOmitted,
      MDImprtNmbrOfRecordsImported,
      MasterDataChangeProcess,
      
      _File : redirected to composition child C_MasterDataImportFileTP,
      _ImportFile : redirected to C_MasterDataImportFileTP,
      _ImportUserVH,
      _ImportStatusVH,
      _ImportSystemVH,
      _RequestorContactCard
}

Learn More