C_ManageJournalEntryHistory

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.auditFilter: #ENABLED
@EndUserText.label: 'Journal Entry History'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  viewType: #CONSUMPTION
}
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XL,
  dataClass: #MIXED
}

@AccessControl.privilegedAssociations: ['_ChangedByContactCard']

@UI.presentationVariant: [{    
    sortOrder: [{
      by: 'LastChangeDateTime',
      direction: #DESC
    }]
}]

@UI.headerInfo: {
  typeNamePlural: 'Change Documents',
  typeName: 'Change Document'  
}

define view entity C_ManageJournalEntryHistory
  as select from R_ManageJournalEntryHistory as _History
{
      @Consumption.valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeVH', element: 'CompanyCode' } }]
      @ObjectModel.text.element: ['CompanyCodeName']
      @UI.textArrangement: #TEXT_LAST
      @UI: {
        selectionField: [{ position: 30 }]
      }
      @Consumption.filter.mandatory: true
  key _History.CompanyCode,
      @ObjectModel.text.element:  [ 'LedgerName' ]
      @UI.textArrangement: #TEXT_LAST
  key _History.Ledger,
      @Consumption.semanticObject: 'AccountingDocument'
      @UI: {
        lineItem: [{ position: 10 }],
        selectionField: [{ position: 40 }]
      }
  key _History.AccountingDocument,
  key _History.ChangeDocument,
  key _History.DatabaseTable,
  key _History.ChangeDocTableKey,
      @ObjectModel.text.element:  [ 'DatabaseTableFieldName' ]
      @UI.textArrangement: #TEXT_LAST
      @UI: {
        lineItem: [{ position: 40 }]
      }
  key _History.ChangeDocDatabaseTableField,
  key _History.JournalEntryItem,
  key _History.FiscalYear,
      _History.DocumentDate,
      _History.PostingDate,
      @EndUserText.label: 'Changed By'
      @ObjectModel.text.element:  [ 'ChangedByUserName' ]
      @UI.textArrangement: #TEXT_LAST
      @UI: {
        selectionField: [{ position: 20 }],
        lineItem: [{ position: 30 }]
      }
      @Consumption.valueHelpDefinition: [  { entity:  { name: 'C_MngJrnlEntryHistoryUserVH', element: 'UserID' } }]
      _History.ChangedBy,
      @Semantics.text: true
      @UI.hidden: true
      _History._ChangedByContactCard.FullName as ChangedByUserName,
      @UI.hidden: true
      _History.LastChangedDate,
      @UI: {
        lineItem: [{ position: 50 }]
      }
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_AUDIT_MASK'
      @ObjectModel.filter.transformedBy: 'ABAP:CL_MJE_AUDIT_MASK'
      @ObjectModel.sort.transformedBy: 'ABAP:CL_MJE_AUDIT_MASK'
      _History.ChangedFieldOldValue,
      @Consumption.hidden: true
      ChangedFieldOldValue as ChangedFieldOldValueForFilter,
      
      @UI: {
        lineItem: [{ position: 60 }]
      }
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_AUDIT_MASK'
      @ObjectModel.filter.transformedBy: 'ABAP:CL_MJE_AUDIT_MASK'
      @ObjectModel.sort.transformedBy: 'ABAP:CL_MJE_AUDIT_MASK'
      _History.ChangedFieldNewValue,
      @Consumption.hidden: true
      ChangedFieldNewValue as ChangedFieldNewValueForFilter,
      
      @UI.hidden: true
      _History.LastChangeTime,
      @EndUserText.label: 'Changed On'
      @UI: {
        selectionField: [{ position: 10 }],
        lineItem: [{ position: 20 }]
      }
      @Consumption.filter.selectionType: #INTERVAL
      @Consumption.filter.mandatory: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_MJE_DATETIME_FLTR_TRANSFORM'
      @ObjectModel.sort.transformedBy: 'ABAP:CL_MJE_DATETIME_FLTR_TRANSFORM'
      _History.LastChangeDateTime,
      @ObjectModel.filter.transformedBy: 'ABAP:CL_MJE_DATETIME_FLTR_TRANSFORM'
      @ObjectModel.sort.transformedBy: 'ABAP:CL_MJE_DATETIME_FLTR_TRANSFORM'
      _History.CreationDateTime,
      @UI.hidden: true
      _History.CreationDate,
      @UI.hidden: true
      _History.CreationTime,
      @UI.hidden: true
      _History.DatabaseTableFieldName,
      @Semantics.text: true
      cast(_History.CompanyCodeName as fis_butxt preserving type) as CompanyCodeName,
      @Semantics.text: true
      _History.LedgerName,
      
      @Consumption.valueHelpDefinition: [  { entity:  { name: 'I_AccountingDocumentCategory', element: 'AccountingDocumentCategory' } }]
      @UI: {
        selectionField: [{ position: 50 }]
      }      
      @ObjectModel.text.element:  [ 'AccountingDocumentCategoryName' ]
      @UI.textArrangement: #TEXT_LAST
      _History.AccountingDocumentCategory,
      @Semantics.text: true
      cast(_History._AccountingDocumentCategoryT.AccountingDocumentCategoryName as fis_bstat_name preserving type ) as AccountingDocumentCategoryName,
      
      @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_AccountingDocumentTypeStdVH', element: 'AccountingDocumentType' } }]
      @ObjectModel.text.element:  [ 'AccountingDocumentTypeName' ]
      @UI.textArrangement: #TEXT_LAST
      _History.AccountingDocumentType,
      @Semantics.text: true
      _History._AccountingDocumentTypeText.AccountingDocumentTypeName,
      
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MJE_AUDIT_MASK'
      @UI.hidden: true  
      @Semantics.booleanIndicator 
      cast ('' as abap.char(1)) as UICT_AuditMask,
      
      @Consumption.filter.hidden: true
      _ChangedByContactCard
}