C_MaintenancePlanQuickVw

@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@EndUserText.label: 'Quick View for Maintenance Plan'

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@ObjectModel.representativeKey: 'MaintenancePlan'
@Analytics.technicalName: 'CMAINTPLANQW'

@UI.headerInfo : {
  typeName: 'Maintenance Plan',
  typeNamePlural: 'Maintenance Plans',
  typeImageUrl: 'sap-icon://gantt-bars',

  imageUrl: 'MaintenancePlanThumbnailURL'
}
define view entity C_MaintenancePlanQuickVw
  as select from I_MaintenancePlan
{

      @UI.facet: [{ purpose: #QUICK_VIEW, type: #FIELDGROUP_REFERENCE, targetQualifier: 'MaintPlanQuickView' }]
      @UI: { fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 10 }]}
      @ObjectModel.text.element:  [ 'MaintenancePlanDesc' ]
      @UI.hidden: true
      @EndUserText.label: 'Maintenance Plan'

  key MaintenancePlan,
      MaintenancePlanDesc,
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 30}]
      }
      @EndUserText.label: 'Long Text'
      @Semantics.text: true
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_LTXT_EXIT'
      cast (' ' as eams_ltext )                    as MaintenancePlanLongText,
      @UI: {
        fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 40}]
        }
      @EndUserText.label: 'Category'
      @ObjectModel.text.element:  [ 'MaintenancePlanCategoryDesc' ]
      @UI.textArrangement: #TEXT_FIRST
      MaintenancePlanCategory,
      @EndUserText.label: 'Maintenance Plan Category Text'
      _MaintenancePlanCatParam._Text[1:Language = $session.system_language].MaintenancePlanCategoryDesc,
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 50}]
      }
      @EndUserText.label: 'Maintenance Strategy'
      @ObjectModel.text.element:  [ 'MaintenanceStrategyDesc' ]
      @UI.textArrangement: #TEXT_FIRST
      MaintenanceStrategy,

      @EndUserText.label: 'Maintenance Plan Strategy Text'
      _MaintenanceStrategy._MaintenanceStrategyText[1:Language = $session.system_language].MaintenanceStrategyDesc,

      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 60}]
      }
      @EndUserText.label: 'Start Of Cycle'
      BasicStartDate,

      @UI.hidden: true
      MaintenancePlanInternalID,

      @ObjectModel: {
                 virtualElement: true,
                 virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_ACTSTATUSTXT_EXIT'
               }
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 70}]
      }
      @EndUserText.label: 'System Status'
      @ObjectModel.text.element:  [ 'MaintPlanActvSystemStatusDesc' ]
      @UI.textArrangement: #TEXT_FIRST
      cast ('' as vdm_j_system_status_concat_t)    as ConcatenatedActiveSystStsName,

      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_ACTSTATUSTXT_EXIT'
      cast( '' as eam_maintplan_active_sy_status ) as MaintPlanActvSystemStatusDesc,


      @ObjectModel: {
                 virtualElement: true,
                 virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_CALLOBJ_EXIT'
               }
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 80}]
      }
      @EndUserText.label: 'Last Scheduled Call Date'
      cast ('' as eams_last_sched_call_date)       as LastScheduledMaintCallDate,
      @ObjectModel: {
                virtualElement: true,
                virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_CALLOBJ_EXIT'
              }
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 90}]
      }
      @EndUserText.label: 'Last Scheduled Call Object'
      cast ('' as eams_last_sched_call_object)     as LastScheduledMaintCallObject,
      @ObjectModel: {
                virtualElement: true,
                virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_CALLOBJ_EXIT'
              }
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 100}]
      }
      @EndUserText.label: 'Next Scheduled Call Date'
      cast ('' as eams_next_sched_call_date)       as NextScheduledMaintCallDate,
      @ObjectModel: {
                virtualElement: true,
                virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_CALLOBJ_EXIT'
              }
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 110}]
      }
      @EndUserText.label: 'Next Scheduled Call Object'
      cast ('' as eams_next_sched_call_object)     as NextScheduledMaintCallObject,
      @ObjectModel: {
                virtualElement: true,
                virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_CALLOBJ_EXIT'
              }
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 120}]
      }
      @EndUserText.label: 'Last Manual Call Date'
      cast ('' as eams_last_man_call_date)         as LastManualMaintCallDate,
      @ObjectModel: {
                virtualElement: true,
                virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_CALLOBJ_EXIT'
              }
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 130}]
      }
      @EndUserText.label: 'Last Manual Call Object'
      cast ('' as eams_last_man_call_object)       as LastManualMaintCallObject,
      @ObjectModel: {
                virtualElement: true,
                virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_CALLOBJ_EXIT'
              }
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 140}]
      }
      @EndUserText.label: 'Next Manual Call Date'
      cast ('' as eams_next_man_call_date)         as NextManualMaintCallDate,
      @ObjectModel: {
                virtualElement: true,
                virtualElementCalculatedBy: 'ABAP:CL_EAM_MPLAN_CALLOBJ_EXIT'
              }
      @UI: {
      fieldGroup:     [{ qualifier:'MaintPlanQuickView', position: 150}]
      }
      @EndUserText.label: 'Next Manual Call Object'
      cast ('' as eams_next_man_call_object)       as NextManualMaintCallObject,

      @Semantics.imageUrl: true
      @EndUserText.label: 'Image'
      @Consumption.filter.hidden: true
      'sap-icon://gantt-bars'                      as MaintenancePlanThumbnailURL


}