C_MaintWorkRequestDamageCodeVH

DDL: C_MAINTWORKREQUESTDAMAGECODEVH Type: view_entity CONSUMPTION Package: RAP_EAM_NTF

Value help for work request failure mode code

C_MaintWorkRequestDamageCodeVH is a Consumption CDS View that provides data about "Value help for work request failure mode code" in SAP S/4HANA. It reads from 1 data source (I_InspectionCode) and exposes 10 fields with key fields InspectionCatalog, InspectionCode, InspectionCodeGroup. It has 1 association to related views. It is exposed through 1 OData service (UI_MAINTWORKREQUESTOVERVIEW). Part of development package RAP_EAM_NTF.

1 data source(s) Exposed by 1 service(s) 10 fields

Data Sources (1)

SourceAliasJoin Type
I_InspectionCode I_InspectionCode from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_Inspectioncodegrouptext _InspectionCodeGroupText _InspectionCodeGroupText.InspectionCatalog = $projection.InspectionCatalog and _InspectionCodeGroupText.InspectionCodeGroup = $projection.InspectionCodeGroup

Annotations (8)

NameValueLevelField
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #CUSTOMIZING view
Search.searchable true view
ObjectModel.dataCategory #VALUE_HELP view

OData Services (1)

ServiceBindingVersionContractRelease
UI_MAINTWORKREQUESTOVERVIEW UI_MAINTWORKREQUESTOVW_V2 V2 C1 NOT_TO_BE_RELEASED_STABLE

Fields (10)

KeyFieldSource TableSource FieldDescription
KEY InspectionCatalog I_InspectionCode InspectionCatalog
KEY InspectionCode I_InspectionCode InspectionCode Failure Mode
KEY InspectionCodeGroup I_InspectionCode InspectionCodeGroup Failure Mode Group
CatalogProfile
InspectionCodeText Failure Mode Text
InspSpecAddlCodeGroupText Failure Mode Group Text
CodeIsInactive I_InspectionCode CodeIsInactive
_InspectionCodeGroupText _InspectionCodeGroupText
_InspectionCodeGroup I_InspectionCode _InspectionCodeGroup
_InspectionCatalog _InspectionCatalog 
@VDM.viewType: #CONSUMPTION

@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  usageType: {
    serviceQuality: #B,
    sizeCategory: #M,
    dataClass: #CUSTOMIZING }
}
@Search.searchable: true
@ObjectModel.dataCategory: #VALUE_HELP
define view entity C_MaintWorkRequestDamageCodeVH as select from I_InspectionCode

  association [0..*] to I_Inspectioncodegrouptext as _InspectionCodeGroupText on  _InspectionCodeGroupText.InspectionCatalog   = $projection.InspectionCatalog
                                                                              and _InspectionCodeGroupText.InspectionCodeGroup = $projection.InspectionCodeGroup

{
      @UI.lineItem: [{ position: 10 }]
      @Search.defaultSearchElement: true
      @Consumption.filter.defaultValue: 'D'
  key I_InspectionCode.InspectionCatalog,
      // @Search.defaultSearchElement: true

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7  }
      @ObjectModel.text.element:  [ 'InspectionCodeText' ]
      @EndUserText.label: 'Failure Mode'
      @UI.lineItem: [{ position: 20 }]
  key I_InspectionCode.InspectionCode,
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7  }
      //--[ GENERATED:012:GFBfhxvv7jY4hYOuhNduX0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'C_MaintWrkReqDamageCodeGroupVH',
                     element: 'InspectionCodeGroup' },
          additionalBinding: [{ localElement: 'InspectionCatalog',
                                element: 'InspectionCatalog' ,
                                usage: #FILTER }]
        }]
      // ]--GENERATED

      @ObjectModel.text.element: ['InspSpecAddlCodeGroupText']
      @EndUserText.label: 'Failure Mode Group'
      @UI.lineItem: [{ position: 30 }]
  key I_InspectionCode.InspectionCodeGroup,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_EAM_MALF_CODE_VH_EXIT'
      cast ('' as rbnr) as CatalogProfile,

      @Search.defaultSearchElement: true
      @Semantics.text: true
      @EndUserText.label: 'Failure Mode Text'
      I_InspectionCode._Text[1: Language = $session.system_language ].InspectionCodeText,
      @Search.defaultSearchElement: true
      @EndUserText.label: 'Failure Mode Group Text'
      _InspectionCodeGroupText[1: Language = $session.system_language ].InspSpecAddlCodeGroupText,
      @Consumption.hidden: true
      @UI.hidden: true
      I_InspectionCode.CodeIsInactive,
      _InspectionCodeGroupText,
      I_InspectionCode._InspectionCodeGroup,
      _InspectionCatalog

}
where
      I_InspectionCode.CodeIsInactive                           = ''
  and I_InspectionCode._InspectionCodeGroup.CodeGroupStatus     = '2' // Released

  and I_InspectionCode._InspectionCodeGroup.CodeGroupIsInactive = ''

Learn More