C_MaintOrderOperationTP

@AbapCatalog.sqlViewName: 'CMAINTORDOPERTP'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Order Operation with Draft'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@ObjectModel: {
  representativeKey : 'MaintenanceOrderOperation',
  semanticKey: ['MaintenanceOrderOperation', 'MaintenanceOrder'],
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  transactionalProcessingDelegated: true
}

@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@UI: {
    headerInfo: {
      description: {
          value: 'OperationDescription',
          type: #STANDARD
      },
      title: {
          value: 'MaintenanceOrderOperation',
          type: #STANDARD
      },
      typeName: 'Maintenance Order Operation',
      typeNamePlural: 'Maintenance Order Operations'
    }
}

@AccessControl.privilegedAssociations: ['_QuickView']

define view C_MaintOrderOperationTP
  as select from I_MaintOrderOperationTP as I_MaintOrderOperationTP
  association [0..1] to C_PMWorkCenterVH              as _WorkCenterVH             on  $projection.OperationWorkCenter = _WorkCenterVH.WorkCenter
                                                                                   and $projection.Plant               = _WorkCenterVH.Plant
  association [1..1] to C_MaintOrderTP                as _MaintOrderTP             on  $projection.MaintenanceOrder = _MaintOrderTP.MaintenanceOrder
  association [0..*] to C_MaintOrderComponentTP       as _MaintOrderComponentTP    on  $projection.MaintenanceOrder          = _MaintOrderComponentTP.MaintenanceOrder
                                                                                   and $projection.MaintenanceOrderOperation = _MaintOrderComponentTP.MaintenanceOrderOperation
  association [0..1] to I_PMTimeUnitVH                as _PlannedWorkUnitOfMeasure on  $projection.OperationPlannedWorkUnit = _PlannedWorkUnitOfMeasure.UnitOfMeasure
  association [0..1] to I_PMTimeUnitVH                as _DurationUnitOfMeasure    on  $projection.OperationDurationUnit = _DurationUnitOfMeasure.UnitOfMeasure
  association [0..1] to I_PMContactCardEmployee       as _PersonResponsible        on  $projection.OperationPersonResponsible = _PersonResponsible.PersonnelNumber
  association [0..*] to I_WorkCenterText              as _WorkCenterText           on  _WorkCenterText.WorkCenterInternalID = $projection.OperationWorkCenterInternalID
                                                                                   and _WorkCenterText.WorkCenterTypeCode   = 'A'
  association [0..1] to C_MaintOrdOperationQuickVw    as _QuickView                on  _QuickView.MaintenanceOrder             = $projection.MaintenanceOrder
                                                                                   and _QuickView.MaintenanceOrderOperation    = $projection.MaintenanceOrderOperation
                                                                                   and _QuickView.MaintenanceOrderSubOperation = '    '
  association [0..1] to I_MaintOperationExecStageCode as _MaintOpExecStageCode     on  $projection.MaintOperationExecStageCode = _MaintOpExecStageCode.MaintOperationExecStageCode

  association [0..*] to I_MaintOpExecStageCodeText    as _MaintOpExecStageCodeText on  _MaintOpExecStageCodeText.MaintOperationExecStageCode = $projection.MaintOperationExecStageCode
  association [0..*] to C_MaintOrderSubOperationTP    as _MaintOrderSubOperationTP on  $projection.MaintenanceOrder          = _MaintOrderSubOperationTP.MaintenanceOrder
                                                                                   and $projection.MaintenanceOrderOperation = _MaintOrderSubOperationTP.MaintenanceOrderOperation
{
        @ObjectModel.foreignKey.association: '_MaintOrderTP'
  key   I_MaintOrderOperationTP.MaintenanceOrder,
        @ObjectModel.text.element:  [ 'OperationDescription' ]
        @UI: {
          fieldGroup: { qualifier:'MalfunctionReportWorkItem', position:10, label: 'Work Item', importance: #HIGH },
          lineItem: { position: 10, importance: #HIGH}
        }
        @EndUserText.label: 'Work Item'
        @EndUserText.quickInfo: 'Work Item'
        @Consumption.semanticObject: 'MaintenanceOrderOperation'
  key   I_MaintOrderOperationTP.MaintenanceOrderOperation,

        @EndUserText.label: 'Suboperation'
        MaintenanceOrderSubOperation,

        @UI.hidden
        I_MaintOrderOperationTP.MaintOrderOperationForEdit,

        @ObjectModel.foreignKey.association: '_EAMProcessPhase'
        I_MaintOrderOperationTP.MaintOrdOpProcessPhaseCode,

        @ObjectModel.foreignKey.association: '_EAMProcessSubPhase'
        @EndUserText.label: 'Subphase'
        I_MaintOrderOperationTP.MaintOrdOpProcessSubPhaseCode,

        I_MaintOrderOperationTP.TechnicalObject,
        I_MaintOrderOperationTP.TechObjIsEquipOrFuncnlLoc,
        @UI.hidden: true
        I_MaintOrderOperationTP.MaintOrderRoutingNumber,
        @UI.hidden: true
        I_MaintOrderOperationTP.MaintOrderOperationCounter,

        @EndUserText.label: 'Description'
        I_MaintOrderOperationTP.OperationDescription,

        I_MaintOrderOperationTP.Equipment,
        I_MaintOrderOperationTP.FunctionalLocation,
        I_MaintOrderOperationTP.Plant,
        @UI.hidden: true
        I_MaintOrderOperationTP.OperationWorkCenterInternalID,

        @UI.lineItem: [ { position: 20 } ]
        @Consumption.valueHelp: '_WorkCenterVH'
        @Consumption.valueHelpDefinition: null
        @ObjectModel.text.association: '_WorkCenterText'
        I_MaintOrderOperationTP.OperationWorkCenter,
        @Consumption.hidden: true
        I_MaintOrderOperationTP.OperationWorkCenterTypeCode,

        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'I_PersWrkAgrmtSrchHelp',
                       element: 'PersonWorkAgreement' }
          }]
        @UI.lineItem: [ { position: 30 } ]
        @EndUserText.label: 'Assigned To'
        @UI.textArrangement: #TEXT_ONLY
        @ObjectModel.foreignKey.association: '_PersonResponsible'
        cast ( I_MaintOrderOperationTP.OperationPersonResponsible as eam_person_responsible  ) as OperationPersonResponsible,

        @ObjectModel.virtualElement
        @ObjectModel.readOnly: true
        @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_MALFUNC_PERSRESP_EXIT'
        @UI.hidden: true
        cast( '' as xfeld )                                                                    as UserIsPersonResponsible,

        @UI.lineItem: [ { position: 40, importance: #LOW } ]
        @Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'
        @EndUserText.label: 'Planned Effort'
        I_MaintOrderOperationTP.OperationPlannedWork,
        @ObjectModel.foreignKey.association: '_PlannedWorkUnitOfMeasure'
        @Consumption.valueHelpDefinition.association: '_PlannedWorkUnitOfMeasure'
        I_MaintOrderOperationTP.OperationPlannedWorkUnit,
        I_MaintOrderOperationTP.OperationDuration,
        @Consumption.valueHelp: '_DurationUnitOfMeasure'
        I_MaintOrderOperationTP.OperationDurationUnit,
        @ObjectModel.foreignKey.association: '_OperationCalculationControl'
        I_MaintOrderOperationTP.OperationCalculationControl,
        @UI.hidden: true
        I_MaintOrderOperationTP.MaintOrderOperationInternalID,
        @UI.lineItem: [ { position: 50 } ]
        @Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'
        @EndUserText.label: 'Actual Effort'
        I_MaintOrderOperationTP.ConfirmationTotalQuantity,

        @EndUserText.label: 'Forecasted Efforts'
        @Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'
        @ObjectModel.readOnly: true
        I_MaintOrderOperationTP._OperationPlanningValues.ForecastedWorkQty,

        @EndUserText.label: 'Execution Stage Code'
        MaintOperationExecStageCode,

        @EndUserText.label: 'Execution Stage'
        @ObjectModel.text.association: '_MaintOpExecStageCodeText'
        @UI.textArrangement: #TEXT_ONLY
        @ObjectModel.readOnly: true
        _MaintOpExecStageCode.MaintOpExecStageGroupCode,

        @UI.hidden: true
        I_MaintOrderOperationTP.EAMOverallObjectStatusProfile,
        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'I_EAMOverallStatusStdVH',
                       element: 'EAMOverallStatus' },
            additionalBinding: [{ localElement: 'EAMOverallObjectStatusProfile',
                                  element: 'EAMOverallStatusProfile' }]
          }]
        @UI.lineItem: [ { position: 70 } ]
        @UI.textArrangement: #TEXT_ONLY
        @EndUserText.quickInfo: 'Status'
        @EndUserText.label: 'Status'
        I_MaintOrderOperationTP.EAMOverallObjectStatus,

        @ObjectModel.readOnly: true
        @UI.hidden: true
        _OperationControlKey.ConfirmationIsNotPossible,

        @UI.lineItem: [ { position: 60 } ]
        @ObjectModel.readOnly: true
        I_MaintOrderOperationTP.IsFinallyConfirmed,

        //        @EndUserText.label: 'Remaining Efforts'

        //        @Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'

        //        @ObjectModel.readOnly: true

        //        _OperationPlanningValues.ForecastedWorkQty - ConfirmationTotalQuantity as RemainingWorkQuantity,



        @Consumption.valueHelpDefinition: [
          { entity:  { name:    'I_Supplier_Vh',
                       element: 'Supplier' }
          }]
        @Consumption.hidden: true
        OperationSupplier,
        @Consumption.hidden: true
        _Supplier,

        /* Associations */
        @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
        _MaintOrderComponentTP,
        @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _MaintOrderTP,
        @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
        _MaintOrderSubOperationTP,
        I_MaintOrderOperationTP._TechnicalObject,
        I_MaintOrderOperationTP._TechObjIsEquipOrFuncnlLoc,
        _PlannedWorkUnitOfMeasure,
        I_MaintOrderOperationTP._WorkCenter,
        _WorkCenterText,
        _WorkCenterVH,
        _PersonResponsible,
        _OperationPlanningValues,
        _QuickView,
        I_MaintOrderOperationTP._StatusObjectActiveStatus,
        I_MaintOrderOperationTP._OverallStatus,
        I_MaintOrderOperationTP._OperationCalculationControl,
        _DurationUnitOfMeasure,
        _MaintOpExecStageCodeText,
        I_MaintOrderOperationTP._EAMProcessPhase,
        I_MaintOrderOperationTP._EAMProcessSubPhase,
        I_MaintOrderOperationTP._MaintOperationExecStageCode
}
where
  I_MaintOrderOperationTP.IsDeleted = ''