C_MaintNotificationItemTP_3

DDL: C_MAINTNOTIFICATIONITEMTP_3 Type: view_entity CONSUMPTION Package: VDM_EAM_MAINTJOB_MANAGE_OPRTN

Maintenance Notification Item

C_MaintNotificationItemTP_3 is a Consumption CDS View that provides data about "Maintenance Notification Item" in SAP S/4HANA. It reads from 1 data source (R_MaintNotificationItemTP) and exposes 19 fields with key fields MaintenanceNotification, MaintenanceNotificationItem. It is exposed through 1 OData service (UI_MAINTENANCEJOB_MANAGE). It is used in 1 Fiori application: Perform Maintenance Jobs. Part of development package VDM_EAM_MAINTJOB_MANAGE_OPRTN.

1 data source(s) Exposed by 1 service(s) Used in 1 Fiori app(s) 19 fields

Data Sources (1)

SourceAliasJoin Type
R_MaintNotificationItemTP R_MaintNotificationItemTP from

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #NOT_REQUIRED view
EndUserText.label Maintenance Notification Item view
VDM.viewType #CONSUMPTION view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view

OData Services (1)

ServiceBindingVersionContractRelease
UI_MAINTENANCEJOB_MANAGE UI_MAINTENANCEJOB_MANAGE V2 C1 NOT_RELEASED

Fiori Apps (1)

App IDApp NameTypeDescription
F5104A Perform Maintenance Jobs Transactional Perform Maintenance Jobs app will help Maintenance Technician to see the list with all work items assigned to the him/her or to his/her team, several features like Assignment of an operation, Time recording for the Operations, create partial or final confirmations and the ability to display and change the malfunction information are possible with the app. The maintenance technician can post and return the planned components and can also record the measurement document.

Perform Maintenance Jobs

Business Role: Maintenance Technician

Technician records actual work, remaining work, confirmation text, and final confirmation for self as well as for team members working on the job.

Fields (19)

KeyFieldSource TableSource FieldDescription
KEY MaintenanceNotification MaintenanceNotification Maintenance Notification
KEY MaintenanceNotificationItem MaintenanceNotificationItem Maintenance Notification Item
MaintNotifItemText MaintNotifItemText Damage Description
MaintNotifDamageCodeGroup MaintNotifDamageCodeGroup Damage Code Group
MaintNotifDamageCodeGroupName Damage Code Group Text
MaintNotificationDamageCode MaintNotificationDamageCode Damage Code
MaintNotifDamageCodeName Damage Code Description
MaintNotifDamageCodeCatalog MaintNotifDamageCodeCatalog
MaintNotifObjPrtCodeGroup MaintNotifObjPrtCodeGroup Object Part Code Group
MaintNotifObjPrtCodeGroupName Object Part Code Group Text
MaintNotifObjPrtCode MaintNotifObjPrtCode Object Part Code
MaintNotifObjPrtCodeName Object Part Code Description
MaintNotifObjPrtCodeCatalog MaintNotifObjPrtCodeCatalog
NumberOfMaintNotifCauses Cause
NumberOfMaintNotifActivities Activity
IsDeleted IsDeleted
_MaintenanceNotification _MaintenanceNotification
_ItemCause _ItemCause
_ItemActivity _ItemActivity 
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Maintenance Notification Item'
@VDM: {
    viewType: #CONSUMPTION
}
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
define view entity C_MaintNotificationItemTP_3
  as select from R_MaintNotificationItemTP

{
      @EndUserText.label: 'Maintenance Notification'
  key MaintenanceNotification,

      @EndUserText.label: 'Maintenance Notification Item'
  key MaintenanceNotificationItem,

      //   Damage Description

      @UI.lineItem: [{position: 50 }]
      @EndUserText.label: 'Damage Description'
      MaintNotifItemText,

      // Damage Code Group

      @EndUserText.label: 'Damage Code Group'
      @Consumption.valueHelpDefinition: [
            { entity:  { name:    'I_InspectionCodeGroup',
                         element: 'InspectionCodeGroup' },
              additionalBinding: [{  localElement: 'MaintNotifDamageCodeCatalog', element: 'InspectionCatalog'}]
            }]
      MaintNotifDamageCodeGroup,

      // Damage Code Group Short text

      @EndUserText.label: 'Damage Code Group Text'
      _MaintNotifDamageCodeGroup._Text[1:Language=$session.system_language].InspSpecAddlCodeGroupText as MaintNotifDamageCodeGroupName,

      // Damage Code

      @EndUserText.label: 'Damage Code'
      @Consumption.valueHelpDefinition: [
            { entity:  { name:    'I_InspectionCode',
                         element: 'InspectionCode' },
              additionalBinding: [{  localElement: 'MaintNotifDamageCodeCatalog', element: 'InspectionCatalog'}]
            }]
      MaintNotificationDamageCode,

      // Damage Code Short text

      @UI.lineItem: [{position: 10 }]
      @EndUserText.label: 'Damage Code Description'
      _MaintNotificationDamageCode._Text[1:Language=$session.system_language].InspectionCodeText      as MaintNotifDamageCodeName,

      @Consumption: { hidden: true }
      //  Damage Code Catalog

      MaintNotifDamageCodeCatalog,

      // Object Part Code Group

      @EndUserText.label: 'Object Part Code Group'
      @Consumption.valueHelpDefinition: [
            { entity:  { name:    'I_InspectionCodeGroup',
                         element: 'InspectionCodeGroup' },
              additionalBinding: [{  localElement: 'MaintNotifObjPrtCodeCatalog', element: 'InspectionCatalog'}]
            }]
      MaintNotifObjPrtCodeGroup,

      // Object Part Code Group Short Text

      @EndUserText.label: 'Object Part Code Group Text'
      _MaintNotifObjPrtCodeGroup._Text[1:Language=$session.system_language].InspSpecAddlCodeGroupText as MaintNotifObjPrtCodeGroupName,

      // Object Part Code

      @EndUserText.label: 'Object Part Code'
      @Consumption.valueHelpDefinition: [
            { entity:  { name:    'I_InspectionCode',
                         element: 'InspectionCode' },
              additionalBinding: [{  localElement: 'MaintNotifObjPrtCodeCatalog', element: 'InspectionCatalog'}]
            }]
      MaintNotifObjPrtCode,

      // Object Part Code Short Text

      @UI.lineItem: [{position: 20 }]
      @EndUserText.label: 'Object Part Code Description'
      _MaintNotifObjPrtCode._Text[1:Language=$session.system_language].InspectionCodeText             as MaintNotifObjPrtCodeName,

      // Object Part Code Catalog

      @Consumption: { hidden: true }
      MaintNotifObjPrtCodeCatalog,

      @EndUserText.label: 'Cause'
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_MALFUNC_COUNT_EXIT'
      @UI.lineItem: [{position: 30 }]
      cast(0 as abap.int4 )                                                                           as NumberOfMaintNotifCauses,
      
      @EndUserText.label: 'Activity'
      @UI.lineItem: [{position: 40 }]
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EAM_MALFUNC_COUNT_EXIT'
      cast(0 as abap.int4 )                                                                           as NumberOfMaintNotifActivities,
      
      @Consumption.hidden: true
      IsDeleted,
      
      @Consumption.hidden: true
      _MaintenanceNotification,

      _ItemCause,
      _ItemActivity

} where IsDeleted = ''

Learn More