C_MRPChangeRequestList

@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'List of MRP Change Requests'
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions: true
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@Search.searchable: true
define view entity C_MRPChangeRequestList
  as select from I_MRPChangeRequestList    as MRPChangeRequestList
    inner join   I_SDMAreaOfResponsibility as SDMAreaOfResponsibility on  MRPChangeRequestList.MRPController = SDMAreaOfResponsibility.MRPController
                                                                      and MRPChangeRequestList.MRPPlant      = SDMAreaOfResponsibility.Plant
                                                                      and SDMAreaOfResponsibility.UserID     = $session.user
  association [0..1] to I_MRPChangeRequestCalcValue as _ChangeRequestHistory on  MRPChangeRequestList.MRPElement             = _ChangeRequestHistory.MRPElement
                                                                             and MRPChangeRequestList.MRPElementItem         = _ChangeRequestHistory.MRPElementItem
                                                                             and MRPChangeRequestList.MRPElementScheduleLine = _ChangeRequestHistory.MRPElementScheduleLine
                                                                             and MRPChangeRequestList.Material               = _ChangeRequestHistory.Material
                                                                             and _ChangeRequestHistory.SolutionRequestStatus = '03'
  association [0..1] to I_UnitOfMeasure             as _BaseUnit             on  $projection.QuantityUnit = _BaseUnit.UnitOfMeasure

  association [1]    to E_MRPRequestNote            as _MrpRqNoteExtension   on  $projection.ChangeRequestUUID = _MrpRqNoteExtension.ChangeRequestUUID
{

      @Consumption.semanticObject: 'PurchaseOrder'
      @Consumption.semanticObjectMapping:{ additionalBinding: [{element: 'PurchaseOrder' ,localElement: 'MRPElement'}, {element: 'PurchaseOrderItem' ,localElement: 'MRPElementItem'}]}
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MRPPurchaseOrderVH', element: 'MRPElement' } } ]
  key MRPChangeRequestList.MRPElement,
  key MRPChangeRequestList.MRPElementItem,
      @Consumption.filter.hidden: true
  key MRPChangeRequestList.MRPElementScheduleLine,
      @ObjectModel.text.element: [ 'MaterialName' ]
      @Consumption.semanticObject: 'Material'
      @UI.lineItem: [{position: 2 ,semanticObjectAction: 'display' }]
  key MRPChangeRequestList.Material,
  key MRPChangeRequestList.MRPPlant,
      @EndUserText:{label: 'MRP Controller', quickInfo: 'MRP Controller'}
      MRPChangeRequestList.MRPController,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlndIndepRqmtMRPArea', element: 'MRPArea' } } ]
      MRPChangeRequestList.MRPArea,
      @ObjectModel.text.element: [ 'SenderCompanyCodeName' ]
      MRPChangeRequestList.CompanyCode,
      MRPChangeRequestList.ChangeRequestUUID,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      MRPChangeRequestList.OrderOpenQuantity,
      MRPChangeRequestList.QuantityUnit,
      @Semantics.text:true
      MRPChangeRequestList.MaterialName,
      @Semantics.systemDate.createdAt: true
      @Consumption.filter.selectionType: #INTERVAL
      MRPChangeRequestList.ChangeRequestProposedDate,
      MRPChangeRequestList.ExceptionMessageID,
      MRPChangeRequestList.ExceptionMessageText,
      @Semantics.systemDate.createdAt: true
      @Consumption.filter.selectionType: #INTERVAL
      @EndUserText.label : 'Delivery Date'
      MRPChangeRequestList.DeliveryDate,
      @Semantics.systemDate.createdAt: true
      @Consumption.filter.selectionType: #INTERVAL
      MRPChangeRequestList.MRPElementChgAvailyOrRqmtDate,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      MRPChangeRequestList.ChangeRequestProposedQty,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      MRPChangeRequestList.TotalQuantity,
      _ChangeRequestHistory.NmbrOfDiscardedChangeRequests,
      @EndUserText:{label: 'Request Response', quickInfo: 'Request Response'}
      MRPChangeRequestList.MRPRequestSupplierResponse,
      MRPChangeRequestList.MRPRequestSupplierResponseText,
      coalesce(MRPChangeRequestList.SolutionRequestStatus ,'') as SolutionRequestStatus,
      MRPChangeRequestList.SolutionRequestStatusName,
      MRPChangeRequestList.MRPExcptnPrpslDataSource,
      MRPChangeRequestList.MRPPlanningSegment,
      @ObjectModel.text.element: [ 'SupplierName' ]
      MRPChangeRequestList.Supplier,
      @Semantics.text:true
      MRPChangeRequestList.SupplierName,
      @Semantics.text:true
      MRPChangeRequestList.SenderCompanyCodeName,
      MRPChangeRequestList.SupplierPlant,
      MRPChangeRequestList.GoodsReceiptDurationInDays,
      @Consumption.filter.hidden: true
      MRPChangeRequestList.ChangeRequestNote,
      @ObjectModel.text.element: [ 'MRPRequestPriorityName']
      MRPChangeRequestList.MRPRequestPriority,
      @Semantics.text:true
      MRPChangeRequestList.MRPRequestPriorityName,
      @ObjectModel.text.element: [ 'MRPRequestReasonName']
      MRPChangeRequestList.MRPRequestReason,
      @Semantics.text:true
      MRPChangeRequestList.MRPRequestReasonName,
      @ObjectModel.text.element: [ 'MRPRequestRejectionName']
      MRPChangeRequestList.MRPRequestRejection,
      @Semantics.text:true
      MRPChangeRequestList.MRPRequestRejectionName,
      @Semantics.amount.currencyCode: 'Currency'
      MRPChangeRequestList.MRPRequestCostOfChangeAmount,
      MRPChangeRequestList.Currency,
      _BaseUnit.UnitOfMeasureNumberOfDecimals,
      _BaseUnit.UnitOfMeasureDspNmbrOfDcmls,
      @ObjectModel.text.element: [ 'MRPChangeReqSendingStatusName']
      MRPChangeRequestList.MRPChangeReqSendingStatus,
      @Semantics.text:true
      MRPChangeRequestList. MRPChangeReqSendingStatusName,
      MRPChangeRequestList.CreationDateTime,
      MRPChangeRequestList.ChangedDateTime,
      MRPChangeRequestList.MRPChangeReqSendingDateTime,
      MRPChangeRequestList._PurchaseOrderQuantityUnit,
      MRPChangeRequestList.AuthorizationGroup,
//      MRPChangeRequestList._CompanyCode,

      MRPChangeRequestList._Supplier
}