C_LegalTransactionIntContact

DDL: C_LEGALTRANSACTIONINTCONTACT SQL: CLEGTRANSINTC Type: view CONSUMPTION Package: ODATA_LCM_LT

Legal Transaction Internal Contacts

C_LegalTransactionIntContact is a Consumption CDS View that provides data about "Legal Transaction Internal Contacts" in SAP S/4HANA. It reads from 1 data source (I_LegalTransactionIntContact) and exposes 18 fields with key field LegalTransactionIntCntctUUID. It has 4 associations to related views. Part of development package ODATA_LCM_LT.

1 data source(s) 18 fields

Data Sources (1)

SourceAliasJoin Type
I_LegalTransactionIntContact I_LegalTransactionIntContact from

Associations (4)

CardinalityTargetAliasCondition
[0..1] C_LCMIntContactTypeValueHelp _LCMIntContactTypeValueHelp $projection.LglCntntMIntCntctType = _LCMIntContactTypeValueHelp.LglCntntMIntCntctType
[0..1] C_LCMUserValueHelp _LCMUserValueHelp _LCMUserValueHelp.UserID = $projection.LglCntntMIntCntctUser
[0..1] C_LglCntntMIntContactTeamVH _LglCntntMIntContactTeamVH $projection.LglCntntMIntContactTeam = _LglCntntMIntContactTeamVH.LglCntntMIntContactTeam
[0..1] C_LglCntntMIntCntctUserTypeVH _LglCntntMIntCntctUserTypeVH $projection.LglCntntMIntContactUserType = _LglCntntMIntCntctUserTypeVH.LglCntntMIntContactUserType

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName CLEGTRANSINTC view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.semanticKey LglCntntMIntCntctUser view
ObjectModel.representativeKey LegalTransactionIntCntctUUID view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Legal Transaction Internal Contacts view

Fields (18)

KeyFieldSource TableSource FieldDescription
KEY LegalTransactionIntCntctUUID LegalTransactionIntCntctUUID
LglCntntMRank LglCntntMRank Rank
LglCntntMIntCntctType LglCntntMIntCntctType
LglCntntMIntCntctTypeName _LCMIntContactTypeValueHelp LglCntntMIntCntctTypeName
LglCntntMIntContactUserType LglCntntMIntContactUserType Assignment Type
LglCntntMIntCntctUserTypeName
LglCntntMIntCntctUser LglCntntMIntCntctUser Name
FullName _LCMUserValueHelp FullName
LglCntntMIntContactTeam LglCntntMIntContactTeam Team
LglCntntMIntContactTeamName _LglCntntMIntContactTeamVH LglCntntMIntContactTeamName
LegalTransactionMandatoryFlag LegalTransactionMandatoryFlag
LglCntntMIsMandatory Required
LegalTransactionUUID LegalTransactionUUID
_LCMIntContactTypeValueHelp _LCMIntContactTypeValueHelp
_LCMUserValueHelp _LCMUserValueHelp
_LegalTransaction _LegalTransaction
_LglCntntMIntCntctUserTypeVH _LglCntntMIntCntctUserTypeVH
_LglCntntMIntContactTeamVH _LglCntntMIntContactTeamVH 
@AbapCatalog.sqlViewName: 'CLEGTRANSINTC'

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: { createEnabled,
                updateEnabled,
                deleteEnabled,
                semanticKey: 'LglCntntMIntCntctUser',
                representativeKey: 'LegalTransactionIntCntctUUID',
                usageType.dataClass: #MIXED,
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #L
                }

@VDM.viewType: #CONSUMPTION
//TODO

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Legal Transaction Internal Contacts'
define view C_LegalTransactionIntContact
  as select from I_LegalTransactionIntContact

  //Value Helps

  association [0..1] to C_LCMIntContactTypeValueHelp as _LCMIntContactTypeValueHelp on $projection.LglCntntMIntCntctType = _LCMIntContactTypeValueHelp.LglCntntMIntCntctType
  
  association [0..1] to C_LCMUserValueHelp           as _LCMUserValueHelp           on _LCMUserValueHelp.UserID = $projection.LglCntntMIntCntctUser
  association [0..1] to C_LglCntntMIntContactTeamVH  as _LglCntntMIntContactTeamVH  on  $projection.LglCntntMIntContactTeam = _LglCntntMIntContactTeamVH.LglCntntMIntContactTeam
  association [0..1] to C_LglCntntMIntCntctUserTypeVH as _LglCntntMIntCntctUserTypeVH on $projection.LglCntntMIntContactUserType = _LglCntntMIntCntctUserTypeVH.LglCntntMIntContactUserType
{
      @UI.hidden: true
  key LegalTransactionIntCntctUUID,

      @EndUserText.label: 'Rank'
      @EndUserText.quickInfo: 'Rank'
      LglCntntMRank,

      @ObjectModel.mandatory: true
      @ObjectModel: { text.element: 'LglCntntMIntCntctTypeName' }
      @Consumption.valueHelp: '_LCMIntContactTypeValueHelp'
      @UI.textArrangement: #TEXT_ONLY
      LglCntntMIntCntctType,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      @Semantics.text: true
      _LCMIntContactTypeValueHelp.LglCntntMIntCntctTypeName as LglCntntMIntCntctTypeName,
      
      @UI.textArrangement: #TEXT_ONLY
      @Consumption.valueHelpDefinition: [
                                                 {
                                                     entity: {
                                                               name: 'C_LglCntntMIntCntctUserTypeVH',
                                                               element: 'LglCntntMIntContactUserType'
                                                              }
                                                  }
                                               ]
      @EndUserText.label: 'Assignment Type'
      @ObjectModel.text.element: ['LglCntntMIntCntctUserTypeName']
      LglCntntMIntContactUserType,
      
      @ObjectModel.readOnly: true
      @UI.hidden: true
      _LglCntntMIntCntctUsrTypeText[ 1: Language = $session.system_language].LglCntntMIntCntctUserTypeName as LglCntntMIntCntctUserTypeName,            

      @Consumption.valueHelp: '_LCMUserValueHelp'
      @ObjectModel.text.element:   'FullName'
      @UI.textArrangement: #TEXT_FIRST
      @EndUserText.label: 'Name'
      LglCntntMIntCntctUser,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      @Semantics.text: true
      _LCMUserValueHelp.FullName                            as FullName,
      
      @UI.textArrangement: #TEXT_ONLY
      @EndUserText.label: 'Team'
      @ObjectModel.text.element: 'LglCntntMIntContactTeamName'
      @Consumption.valueHelpDefinition: [
                                           {
                                               entity: {
                                                         name: 'C_LglCntntMIntContactTeamVH',
                                                         element: 'LglCntntMIntContactTeam'
                                                        }
                                            }
                                         ]
      LglCntntMIntContactTeam,    
      
      @UI.hidden: true
      @ObjectModel.readOnly: true
      @Semantics.text: true
      _LglCntntMIntContactTeamVH.LglCntntMIntContactTeamName                                               as LglCntntMIntContactTeamName,        

      @UI.hidden: true
      LegalTransactionMandatoryFlag,


      @EndUserText.label: 'Required'
      //cast( LegalTransactionMandatoryFlag as lcm_lt_mandatory_ctrl_to_bool preserving type )  as LglCntntMIsMandatory,

      cast ( '' as lcm_is_mandatory preserving type )       as LglCntntMIsMandatory,

      @UI.hidden: true
      LegalTransactionUUID,


      _LCMIntContactTypeValueHelp,

      _LCMUserValueHelp,

      _LegalTransaction,
      
      _LglCntntMIntCntctUserTypeVH,
      
      _LglCntntMIntContactTeamVH

}

Learn More