C_LU_SAFTGenLedgerLine

@AbapCatalog.sqlViewName: 'CLUSAFTGENLDGRL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'SAFT LU General Ledger Lines'
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view C_LU_SAFTGenLedgerLine

  as select from           I_LU_SAFTJournalEntry        as JournalEntryItem
    inner join             P_LU_SAFTIsAlternateAccount  as AlternateAccount on AlternateAccount.CompanyCode = JournalEntryItem.CompanyCode

{
  key JournalEntryItem.CompanyCode                                   as CompanyCode,
  key JournalEntryItem.FiscalYear                                    as FiscalYear,
  key JournalEntryItem.AccountingDocument                            as AccountingDocument,
  key cast( '' as  opbel_kk)                                         as CADocumentNumber,
  key JournalEntryItem.LedgerGLLineItem                              as LedgerGLLineItem,
  key cast('' as opupk_kk )                                          as CAGLItemNumber,
  key JournalEntryItem.Ledger                                        as Ledger,
      cast( '' as  blart_kk )                                        as CADocumentType,
      cast('' as gpart_kk ) as BusinessPartnerCustomer,
      JournalEntryItem.AccountingDocumentItem,
      JournalEntryItem.ChartOfAccounts,
      JournalEntryItem.PostingDate,
      JournalEntryItem.FinancialAccountType,
      cast(case when AlternateAccount.IsAltAcct is not initial
      then concat(JournalEntryItem.CompanyCode, concat('_', JournalEntryItem.AlternativeGLAccount))
      else concat(JournalEntryItem.CompanyCode, concat('_', JournalEntryItem.GLAccount)) end as abap.char(70)) as SAFTGeneralLedgerAccountID,
      JournalEntryItem.GLAccount,
      JournalEntryItem.DocumentItemText,
      @Semantics.currencyCode: true
      JournalEntryItem.CompanyCodeCurrency,
      @Semantics.currencyCode: true
      case when (JournalEntryItem.DebitCreditCode = 'H' and ( JournalEntryItem.IsReversal is initial or JournalEntryItem.IsReversal = '' ) )
          or (JournalEntryItem.DebitCreditCode = 'S' and   JournalEntryItem.IsReversal = 'X' ) then
      case when JournalEntryItem.TransactionCurrency != JournalEntryItem.CompanyCodeCurrency then
      JournalEntryItem.TransactionCurrency end end                                                      as PurgDocTransactionCurrency,
      @Semantics.currencyCode: true
      case when (JournalEntryItem.DebitCreditCode = 'S' and ( JournalEntryItem.IsReversal is initial or JournalEntryItem.IsReversal = '' ) )
          or (JournalEntryItem.DebitCreditCode = 'H' and   JournalEntryItem.IsReversal = 'X' ) then
      case when JournalEntryItem.TransactionCurrency != JournalEntryItem.CompanyCodeCurrency then
      JournalEntryItem.TransactionCurrency end end                                                      as PurOrdTransactionCurrency,
      case when (JournalEntryItem.DebitCreditCode = 'H' and ( JournalEntryItem.IsReversal is initial or JournalEntryItem.IsReversal = '' ) )
          or (JournalEntryItem.DebitCreditCode = 'S' and   JournalEntryItem.IsReversal = 'X' ) then
      case when JournalEntryItem.TransactionCurrency != JournalEntryItem.CompanyCodeCurrency then
      abs(JournalEntryItem.ExchangeRate)  end end                                                       as CreditDataExchangeRate,
      case when (JournalEntryItem.DebitCreditCode = 'S' and ( JournalEntryItem.IsReversal is initial or JournalEntryItem.IsReversal = '' ) )
          or (JournalEntryItem.DebitCreditCode = 'H' and   JournalEntryItem.IsReversal = 'X' ) then
      case when JournalEntryItem.TransactionCurrency != JournalEntryItem.CompanyCodeCurrency then
      abs(JournalEntryItem.ExchangeRate)  end end                                                       as AccountingExchangeRate,

      @EndUserText.label: 'Amount Transaction'
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      case
        when (JournalEntryItem.DebitCreditCode = 'H' and JournalEntryItem.IsReversal = '') or
             (JournalEntryItem.DebitCreditCode = 'S' and JournalEntryItem.IsReversal = 'X')
          then cast(abs( JournalEntryItem.AmountInCompanyCodeCurrency) as fis_cr_hsl preserving type)
        else 0
      end                                                            as CreditAmountInCoCodeCrcy,

      @EndUserText.label: 'Amount Transaction'
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      case
        when (JournalEntryItem.DebitCreditCode = 'S' and JournalEntryItem.IsReversal = '') or
             (JournalEntryItem.DebitCreditCode = 'H' and JournalEntryItem.IsReversal = 'X')
          then cast(abs( JournalEntryItem.AmountInCompanyCodeCurrency ) as fis_cr_hsl preserving type)
        else 0
      end                                                            as DebitAmountInCoCodeCrcy,

      @EndUserText.label: 'Amount Transaction'
      @Semantics: { amount : {currencyCode: 'PurgDocTransactionCurrency'} }
      case when (JournalEntryItem.DebitCreditCode = 'H' and ( JournalEntryItem.IsReversal is initial or JournalEntryItem.IsReversal = '' ) )
          or (JournalEntryItem.DebitCreditCode = 'S' and   JournalEntryItem.IsReversal = 'X' ) then
      case when JournalEntryItem.TransactionCurrency != JournalEntryItem.CompanyCodeCurrency then
      abs(JournalEntryItem.AmountInTransactionCurrency) end end                                         as CreditAmountInTransCrcy,
      @EndUserText.label: 'Amount Transaction'
      @Semantics: { amount : {currencyCode: 'PurOrdTransactionCurrency'} }
      case when (JournalEntryItem.DebitCreditCode = 'S' and ( JournalEntryItem.IsReversal is initial or JournalEntryItem.IsReversal = '' ) )
          or (JournalEntryItem.DebitCreditCode = 'H' and   JournalEntryItem.IsReversal = 'X' ) then
      case when JournalEntryItem.TransactionCurrency != JournalEntryItem.CompanyCodeCurrency then
      abs(JournalEntryItem.AmountInTransactionCurrency) end end                                         as DebitAmountInTransCrcy,

      case
        when JournalEntryItem.DebitCreditCode = 'H'
          then 'C'
        else 'D'
      end                                                            as DebitCreditCode,

      case
        when JournalEntryItem.TransactionTypeDetermination = ' '
        and JournalEntryItem.FinancialAccountType = 'S'
          then JournalEntryItem.TaxCode
          else ' '
      end                                                            as TaxCode,

      cast( abs(round( JournalEntryItem.Quantity, 0)) as abap.int8 ) as Quantity,

      JournalEntryItem.ExchangeRate,
      ' '                                                            as CAIsDownPaymentRequest,

      JournalEntryItem.IsReversal,
      JournalEntryItem.AccountingDocumentItemType,
      JournalEntryItem.AccountingDocumentType,
      JournalEntryItem.AlternativeGLAccount,
      cast( '' as  ktosl_kk)                                         as  CATransactionKeyAccountDetn

}