C_JrnlEntrLdgrCoCodeCrcyRole

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Ledger Company Code Currency Role'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #L,
  dataClass: #MIXED
}
@VDM.viewType: #CONSUMPTION

@ObjectModel.query.implementedBy: 'ABAP:CL_MJE_LDGRCOCODECURRENCYROLE'

define view entity C_JrnlEntrLdgrCoCodeCrcyRole
  as select from R_JrnlEntrLdgrCoCodeCrcyRole  
  association [0..1] to I_Companycodecurrencyrole as _CurrencyRole on  $projection.CurrencyRole = _CurrencyRole.CurrencyRole
                                                                   and $projection.CompanyCode  = _CurrencyRole.CompanyCode
  association [0..*] to I_CurrencyRoleText        as _Text         on  $projection.CurrencyRole = _Text.CurrencyRole

{

  key Ledger,      
  key CompanyCode,
      @ObjectModel.text.element: ['CurrencyRoleName']
  key cast(CurrencyRole as fins_curtp preserving type ) as CurrencyRole,
      
  key CurrencyField,
      CurrencyFieldName,
      AmountFieldName,
      TaxBaseAmountFieldName,
      TaxAmountFieldName,
      TaxCurrencyFieldName,
      
      @Semantics.text: true
      cast( _Text[1: Language = $session.system_language].CurrencyRoleName as fac_crcyrole_txt ) as CurrencyRoleName,

      _CurrencyRole.Currency,
      _CurrencyRole._Currency.Decimals,
      // To get Trans. Currency we need following fields (see impl. class)

      cast( '0000' as gjahr) as FiscalYear,
      cast( '' as belnr_d) as  AccountingDocument,
      // Text shown on FE

      cast( '' as abap.char( 255 )) as CurrencyWithCurrencyRoleText,
      @Semantics.booleanIndicator
      cast( '' as abap.char( 1 )) as CurrencyIsRelevant
}