C_JITBusinessPartnerVH

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@Consumption.ranked: true
@EndUserText.label                          : 'Business Partner'
@Metadata.ignorePropagatedAnnotations       : true
@ObjectModel    :{ dataCategory             : #VALUE_HELP,
                   usageType                : { dataClass               : #MASTER,
                                                serviceQuality          : #B,
                                                sizeCategory            : #XL
                                              }
                 }
@Search.searchable: true
@VDM.viewType: #CONSUMPTION

define view entity C_JITBusinessPartnerVH
  as select from I_Customer as Customer
{
      /* start suppress warning shlporigin_not_inherited */

      /*====================================================================*/
      //*Technical Key //

      //*--------------------------------------------------------------------*//

      @ObjectModel.text.element: ['CustomerName']
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key cast( Customer.Customer as kunum preserving type ) as Customer,

      @UI.hidden: true
  key AddressID,

      /*==========================================================================================*/
      // Fields

      /*------------------------------------------------------------------------------------------*/
      Customer._StandardAddress.FullName                 as CustomerName,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @UI.hidden: true
      Customer._StandardAddress.BusinessPartnerName1,

      @UI.hidden: true
      @Search.ranking: #LOW
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      Customer._StandardAddress.BusinessPartnerName2,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      Customer._StandardAddress.StreetName               as StreetName,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      Customer._StandardAddress.PostalCode               as PostalCode,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      Customer._StandardAddress.CityName                 as CityName,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      Customer._StandardAddress.Country                  as Country,

      @UI.hidden: true
      @Consumption.filter.hidden: true
      @EndUserText.label: 'Purpose Complete Flag'
      @Semantics.booleanIndicator: true
      Customer.IsBusinessPurposeCompleted,

      // Hardening CDS DCL

      @UI.hidden: true
      AuthorizationGroup,

      CustomerAccountGroup
      /* end suppress warning shlporigin_not_inherited */

}