C_InternalContacts

DDL: C_INTERNALCONTACTS SQL: CINTCNTCS Type: view CONSUMPTION Package: ODATA_SD_RETURN_V2

Internal Contacts

C_InternalContacts is a Consumption CDS View that provides data about "Internal Contacts" in SAP S/4HANA. It reads from 2 data sources (I_CustomerReturn, I_SDDocumentPersonnel) and exposes 16 fields with key fields SDDocument, PartnerFunction. Part of development package ODATA_SD_RETURN_V2.

2 data source(s) 16 fields

Data Sources (2)

SourceAliasJoin Type
I_CustomerReturn CustomerReturn inner
I_SDDocumentPersonnel Partner from

Annotations (9)

NameValueLevelField
AbapCatalog.sqlViewName CINTCNTCS view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #MANDATORY view
VDM.viewType #CONSUMPTION view
ClientHandling.algorithm #SESSION_VARIABLE view
EndUserText.label Internal Contacts view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view

Fields (16)

KeyFieldSource TableSource FieldDescription
KEY SDDocument I_SDDocumentPersonnel SDDocument
KEY PartnerFunction I_SDDocumentPersonnel PartnerFunction
Personnel I_SDDocumentPersonnel Personnel
Person Employment Person
EmployeeFullName _Employee PersonFullName
JobName
CompanyCodeName
EmployeeImageURL _ImageURL WorkforcePersonImageURL
DefaultEmailAddress
NormalizedPhoneNumber
MblNormalizedPhoneNumber
CustomerReturnType I_CustomerReturn CustomerReturnType
SalesOrganization I_CustomerReturn SalesOrganization
DistributionChannel I_CustomerReturn DistributionChannel
OrganizationDivision I_CustomerReturn OrganizationDivision
_PartnerFunction I_SDDocumentPersonnel _PartnerFunction 
@AbapCatalog.sqlViewName: 'CINTCNTCS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Internal Contacts'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define view C_InternalContacts 
as select from I_SDDocumentPersonnel        as Partner
    inner join I_CustomerReturn             as CustomerReturn on CustomerReturn.CustomerReturn = Partner.SDDocument
left outer to one join I_PersonWorkAgreement_1       as Employment                  on Partner.Personnel = Employment.PersonWorkAgreement
  association[0..1] to I_WorkforcePerson             as _Employee                   on $projection.Person = _Employee.Person
  association[0..1] to I_WorkforcePersonImageURL     as _ImageURL                   on $projection.Person =_ImageURL.Person
  association[0..*] to I_PersonWorkAgrmtOrglDetails  as _PersonWorkAgrmtOrglDetails on $projection.Personnel = _PersonWorkAgrmtOrglDetails.PersonWorkAgreement
                                                                                    and _PersonWorkAgrmtOrglDetails.StartDate <= $session.system_date
                                                                                    and _PersonWorkAgrmtOrglDetails.EndDate >= $session.system_date
{
    key Partner.SDDocument,
    
    @ObjectModel.foreignKey.association: '_PartnerFunction'
    key Partner.PartnerFunction as PartnerFunction,
     
     Partner.Personnel,
     
     @Consumption.hidden: true
     @UI.hidden: true
     Employment.Person as Person,
    
     _Employee.PersonFullName as EmployeeFullName,
     
     _PersonWorkAgrmtOrglDetails._PersonWorkAgrmtJobText[1: Language=$session.system_language].JobName,
     _PersonWorkAgrmtOrglDetails._CompanyCode.CompanyCodeName,

      _ImageURL.WorkforcePersonImageURL as EmployeeImageURL,
      
      _Employee._WorkplaceAddress.DefaultEmailAddress,
      _Employee._WorkplaceAddress.NormalizedPhoneNumber,
      _Employee._WorkplaceAddress.MblNormalizedPhoneNumber,

      // For Access control

      @Consumption.hidden: true
      @UI.hidden: true
      CustomerReturn.CustomerReturnType,
      @Consumption.hidden: true
      @UI.hidden: true
      CustomerReturn.SalesOrganization,
      @Consumption.hidden: true
      @UI.hidden: true
      CustomerReturn.DistributionChannel,
      @Consumption.hidden: true
      @UI.hidden: true
      CustomerReturn.OrganizationDivision,
      
      //Association

      Partner._PartnerFunction      
}

Learn More