C_IntOrderSettlementRuleTP

@Metadata.allowExtensions:true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_LastChangedByUser','_CreatedByUser',  '_IntOrderLastChangedByUser']

@EndUserText.label: 'Internal Order Settlement Rule'

@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
  }
}
@VDM: {
  viewType: #CONSUMPTION,
  usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
}


define root view entity C_IntOrderSettlementRuleTP
  provider contract transactional_query
  as projection on R_IntOrderSettlementRuleTP
  association [0..*] to C_IntOrderActiveUserStatus   as _IntOrderActiveUserStatus   on $projection.ControllingObject = _IntOrderActiveUserStatus.StatusObject
  association [0..*] to C_IntOrderActiveSystemStatus as _IntOrderActiveSystemStatus on $projection.ControllingObject = _IntOrderActiveSystemStatus.StatusObject

{
  key     ControllingObject,
          CtrlgObjectSettlementRuleName,
          @ObjectModel.text.element: ['CtrlgSettlementProfileName']
          ControllingSettlementProfile,
          _ControllingSettlementProfile._Text.CtrlgSettlementProfileName    : localized,
          InternalOrder,
          InternalOrderDescription,
          @ObjectModel.text.element: ['OrderTypeName']
          OrderType,
          _InternalOrderTypeText.OrderTypeName                              : localized,
          InternalOrderLastChangedByUser,
          _IntOrderLastChangedByUser.FullName as IntOrderLastChangedByUserName,
          InternalOrderLastChangeDate,
          @ObjectModel.text.element: ['CreatedByUserName']
          @Semantics.contact.type: #PERSON
          CreatedByUser,
          _CreatedByUser.FullName             as CreatedByUserName,
          CreationDate,
          @ObjectModel.text.element: ['LastChangedByUserName']
          LastChangedByUser,
          _LastChangedByUser.FullName         as LastChangedByUserName,
          LastChangeDate,
          @ObjectModel.text.element: ['CompanyCodeName']
          CompanyCode,
          _CompanyCode.CompanyCodeName        as CompanyCodeName,
          @ObjectModel.text.element: ['ControllingAreaName']
          ControllingArea,
          _ControllingArea.ControllingAreaName,
          @ObjectModel.text.element: ['AllocationStructureText']
          AllocationStructure,
          _AllocationStructure._Text.AllocationStructureText                : localized,
          @ObjectModel.text.element: ['PrftbltyAcctgTransfStrucName']
          ProfitabilityAcctgTransfStruc,
          _PrftbltyAcctgTransfStructure._Text.PrftbltyAcctgTransfStrucName  : localized,
          AssetValueDate,
          @ObjectModel.text.element: ['SettlmtRuleGnrtnStrgySqncName']
          SettlmtRuleAutoGnrtnStrgySqnc,
          _SettlmtAutomGnrtnStrgySqnc._Text.SettlmtRuleGnrtnStrgySqncName   : localized,
          SettlmtRuleProcessingSequence,
          @ObjectModel.text.element: ['ControllingStructureName']
          SettlementSourceStructure,
          _SourceStructure._Text.ControllingStructureName                   : localized,
          @ObjectModel.text.element: ['SettlmtWithFreeDefinedCrcyName']
          SettlmtWithFreeDefinedCurrency,
          _SettlmtWithFreeDfndCurrency._Text.SettlmtWithFreeDefinedCrcyName : localized,
          SettlmtParlLedgersIsInactive,
          IntOrdSettlementRuleIsCreated,
          IntOrderSystemStatusShortName,
          InternalOrderSystemStatusName,
          InternalOrderControllingObject,
          IsStatisticalOrder,
          InternalOrderIsDeleted,
          InternalOrderDeletionFlagIsSet,
          InternalOrderIsLocked,
          ControllingObjectStatus,


          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IO_VE_OVERALLSYSTSTATUS'
          }

  virtual IntOrdOverallSystemStatusText  : fco_io_overallsystemstatus,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IO_VE_OVERALLUSERSTATUS'
          }
  virtual IntOrderOverallUserStatusText  : fco_io_overalluserstatus,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_MSGSTRIPISACTV'
           }
  virtual MessageStripIsActive           : xfeld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_MSGSTRIPRSNCODE'
           }
  virtual MessageStripReasonCode         : char20,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_GLACTISDSBLD'
          }
  virtual SettlmtPrflGLAccountIsDisabled : fco_iosr_sp_glactisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_CSCTRISDSBLD'
          }
  virtual SettlmtPrflCostCtrIsDisabled   : fco_iosr_sp_costctrisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_ORDERISDSBLD'
          }
  virtual SettlmtProfileOrderIsDisabled  : fco_iosr_sp_orderisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_WBSELISDSBLD'
          }
  virtual SettlmtPrflWBSElmntIsDisabled  : fco_iosr_sp_wbselmntisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_FXDASISDSBLD'
          }
  virtual SettlmtPrflFxdAssetIsDisabled  : fco_iosr_sp_fxdassetisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_NTWKISDSBLD'
          }
  virtual SettlmtPrflNetworkIsDisabled   : fco_iosr_sp_networkisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_PRFSGISDSBLD'
          }
  virtual SettlmtPrflPrftbltySgmtIsDsbld : fco_iosr_sp_prftbltysgmisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_SLSORISDSBLD'
          }
  virtual SettlmtPrflSlsOrderIsDisabled  : fco_iosr_sp_slsorderisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_CSOBJISDSBLD'
          }
  virtual SettlmtPrflCostObjIsDisabled   : fco_iosr_sp_costobjisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_BSPRCISDSBLD'
          }
  virtual SettlmtPrflBusProcIsDisabled   : fco_iosr_sp_busprocisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_REOBJISDSBLD'
          }
  virtual SettlmtPrflREObjectIsDisabled  : fco_iosr_sp_reobjectisdsbld,
          @ObjectModel: {
          virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_SP_SRVDCISDSBLD'
          }
  virtual SettlmtPrflSrvcDocIsDisabled   : fco_iosr_sp_srvcdocisdsbld,
          @ObjectModel: {
          virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_LDGRGRPISDSBLD'
          }
  virtual DistrRuleLedgerGroupIsDisabled : fco_iosr_dr_ldgrgrpisdsbld,
          @ObjectModel: {
             virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_BUSAR_IS_HIDDEN'
           }
  virtual BusinessAreaIsHidden           : fco_io_business_area_is_hidden,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_IDFRSETTLMTBY'
          }
  virtual SettlementPctgRateIsDisabled   : fco_iosr_pctgrateisdsbld,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_IDFRSETTLMTBY'
          }
  virtual SettlmtEquivalenceFctrIsDsbld  : fco_iosr_eqvlncfctrisdisabled,
          @ObjectModel: {
            virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_IDFRSETTLMTBY'
          }
  virtual SettlementAmountIsDisabled     : fco_iosr_settlmtamtisdisabled,
          @ObjectModel: {
          virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_IDFRSETTLMTBY'
          }
  virtual SettlmtDistrAmtRuleTypeIsDsbld : fco_iosr_amtruletypeisdisabled,
          @ObjectModel: {
          virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_IDFRSETTLMTBY'
          }
  virtual SettlmtDistrRuleRmngAmtIsDsbld : fco_iosr_rmngamountisdisabled,
          @ObjectModel: {
          virtualElementCalculatedBy: 'ABAP:CL_FCO_IOSR_VE_DISRLGRPISDSBLD'
          }
  virtual SettlmtDistrRuleGrpIsDisabled  : fco_iosr_setdisrulegrpisdsbld,

          _IntOrdSettlementDistrRuleTP  : redirected to composition child C_IntOrdSettlementDistrRuleTP,
          _IntOrdSettlmtHistPerLedgerTP : redirected to composition child C_IntOrdSettlmtHistPerLedgerTP,


          _CreatedByUser,
          _IntOrderLastChangedByUser,
          _LastChangedByUser,
          _IntOrderActiveUserStatus,
          _IntOrderActiveSystemStatus




}