C_InsurPlcyCoverage

@AbapCatalog.viewEnhancementCategory    : [#NONE]
@AccessControl.authorizationCheck       : #CHECK
@EndUserText.label                      : 'Coverage'
@VDM.viewType                           : #CONSUMPTION
@Metadata.ignorePropagatedAnnotations   : true
@Metadata.allowExtensions               : true
@ObjectModel.usageType                  : {
  serviceQuality                        : #C,
  sizeCategory                          : #XL,
  dataClass                             : #TRANSACTIONAL }

define view entity C_InsurPlcyCoverage
  as select from I_InsurancePolicyContrCoverage

  association [1..*] to C_InsurPlcyDeductible as _InsurPlcyDeductible on  $projection.InsurPlcyUUID              = _InsurPlcyDeductible.InsurPlcyUUID
                                                                      and $projection.InsurPlcyInsurContr        = _InsurPlcyDeductible.InsurPlcyInsurContr
                                                                      and $projection.InsurPlcyCoveragePackageID = _InsurPlcyDeductible.InsurPlcyCoveragePackageID
                                                                      and $projection.InsurPlcyCoverageID        = _InsurPlcyDeductible.InsurPlcyCoverageID

  association [1..*] to C_InsurPlcyLimitAmt   as _InsurPlcyLimitAmt   on  $projection.InsurPlcyUUID              = _InsurPlcyLimitAmt.InsurPlcyUUID
                                                                      and $projection.InsurPlcyInsurContr        = _InsurPlcyLimitAmt.InsurPlcyInsurContr
                                                                      and $projection.InsurPlcyCoveragePackageID = _InsurPlcyLimitAmt.InsurPlcyCoveragePackageID
                                                                      and $projection.InsurPlcyCoverageID        = _InsurPlcyLimitAmt.InsurPlcyCoverageID

{
  key InsurPlcyUUID,
  key InsurPlcyInsurContr,
  key InsurPlcyCoveragePackageID,
  key InsurPlcyCoverageID,
      InsurPlcyJrnlNmbr,
      InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      InsurPlcyProductPackageID,
      InsurPlcyInsuranceCoverage,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      InsurPlcyElementaryProdTmpl,
      _InsurPlcyTemplateT [Language = $session.system_language].InsurPlcyTemplateLongName,
      @Semantics.dateTime:true
      InsurPlcyCoverageStartDateTime,
      @Semantics.dateTime:true
      InsurPlcyCoverageEndDateTime,
      @ObjectModel.text.element: ['InsurPlcyCvrgPremExmpRsnName']
      @UI.textArrangement: #TEXT_ONLY      
      InsurPlcyCvrgPremExmpReason,
      @Semantics.text: true
      _InsurPlcyCvrgPremExmpRsn._Text[Language = $session.system_language].InsurPlcyCvrgPremExmpRsnName as InsurPlcyCvrgPremExmpRsnName,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgLifeCycSts'
      @ObjectModel.text.element: ['InsurPlcyCvrgLifeCycleStsName']
      @UI.textArrangement: #TEXT_ONLY
      InsurPlcyCvrgLifeCycleStatus,
      @Semantics.text: true
      _InsurPlcyCvrgLifeCycSts._Text[Language = $session.system_language].InsurPlcyCvrgLifeCycleStsName as InsurPlcyCvrgLifeCycleStsName,      
     
      case
      when InsurPlcyCvrgLifeCycleStatus = '001' then 3
      else 1
      end                                                                                                                                                                            as InsurContrStatusColorCode,
       @ObjectModel.foreignKey.association: '_InsurContrCanclnReason'
      InsurContrCanclnRsn,
      @Semantics.dateTime:true
      InsurPlcyCvrgCanclnDateTime,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgSuspension'
      InsurPlcyCoverageSuspension,
      @Semantics.dateTime:true
      InsurPlcyCvrgSuspnStrtDateTime,
      @Semantics.dateTime:true
      InsurPlcyCvrgSuspnEndDateTime,
      @Semantics.amount.currencyCode: 'InsurPlcyCoverageCurrency'
      InsurPlcyCvrgInsuredSumAmount,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgInsrdSumCalc'
      InsurPlcyCvrgInsrdSumCalcMeth,
      InsurPlcyCvrgInsuredSumPercent,
      @ObjectModel.foreignKey.association: '_CoverageCurrency'
      @UI.hidden: true
      InsurPlcyCoverageCurrency,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,

      InsurancePolicyPremium,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      InsurPerdPremBfrTaxPaytAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      InsurPerdPremAftTaxPaytAmt,
      InsurPremType,
      @Semantics.booleanIndicator:true
      InsurPlcyCvrgIsPremiumExempt,
      InsurPlcyCvrgPremExmpEndDate,
      @ObjectModel.foreignKey.association: '_PremiumCurrency'
      InsurPlcyPremiumCurrency,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      InsurPlcyTotAnnPremAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      InsurPlcyPerdPremBfrTxPaytAmt,

      cast( '3' as abap.int1 )                      as InsurPlcyChartColorCode,

      @UI.hidden: true
      _InsuranceContract._InsurancePolicy.InsrrIDByInsrr,
      @UI.hidden: true
      _InsuranceContract._InsurancePolicy.InsurPlcyAuthznSlsProductGroup,

      /* Associations */
      _CoverageCurrency,
      _InsuranceContract,
      _InsurContrCanclnReason,
      _InsurPlcyContrCvrgClause,
      _InsurPlcyContrCvrgDeductible,
      _InsurPlcyContrCvrgInsrdObj,
      _InsurPlcyContrCvrgLimit,
      _InsurPlcyContrCvrgSubCvrg,
      _InsurPlcyContrCvrgSurcharge,
      _InsurPlcyCvrgInsrdSumCalc,
      _InsurPlcyCvrgLifeCycSts,
      _InsurPlcyCvrgSuspension,
      _InsurPlcyTemplateT,
      _PremiumCurrency,
      _InsurPlcyDeductible,
      _InsurPlcyLimitAmt

}