C_InspOperationHeader

@AbapCatalog.sqlViewName: 'CINSPOPHDR'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Header of Inspection Operation'
@Search.searchable: true
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #L, //expected number of rows < 10.000.000

    serviceQuality: #D 
}
define view C_InspOperationHeader 
as select from I_InspectionOperation as _InspOpHeader
    left outer to one join C_Inspoperation_Object as InspectionOperation
        on _InspOpHeader.InspectionLot        = InspectionOperation.InspectionLot    
        and _InspOpHeader.InspectionOperation = InspectionOperation.InspectionOperation
    //Retrieve Inspcetion Lot

    left outer to one join I_InspectionLot as InspectionLot
        on _InspOpHeader.InspectionLot = InspectionLot.InspectionLot    
    //Characteristic tab(no sample)

    association [1..*] to C_InspOperationChar as _InspOperationChar
        on $projection.InspectionLot        = _InspOperationChar.InspectionLot
        and $projection.InspectionOperation = _InspOperationChar.InspectionOperation 
    //Characteristic tab(sample)

    association [1..*] to C_InspSubsetChar as _InspSubsetChar
        on $projection.InspectionLot        = _InspSubsetChar.InspectionLot
        and $projection.InspectionOperation = _InspSubsetChar.InspectionOperation
    //Retrieve Operation UD valuation    

    association [1..1] to C_Inspoperation_Object as _InspectionOperation
        on $projection.InspectionLot        = _InspectionOperation.InspectionLot    
        and $projection.InspectionOperation = _InspectionOperation.InspectionOperation
    //Retrieve Inspcetion Lot

    association [1..1] to I_InspectionLot as _InspectionLot
        on $projection.InspectionLot = _InspectionLot.InspectionLot
{
      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_InspectionLotStdVH',
                     element: 'InspectionLot' }
        }]
      // ]--GENERATED

    key _InspOpHeader.InspectionLot,
    key _InspOpHeader.InspectionOperation,
    InspectionLot.InspectionLotType,
    _InspOpHeader.OperationText,
    _InspOpHeader._Plant.Plant,
    _InspOpHeader._Plant.PlantName,
    InspectionLot.Batch,
    InspectionLot.BatchBySupplier,//Vendor batch

    InspectionLot.MaterialIsBatchManaged,
    InspectionLot.Material,
    InspectionLot.InspectionLotObjectText,//Material description

    _InspOpHeader._WorkCenter.WorkCenter,
    _InspOpHeader._WorkCenter._Text[1:Language=$session.system_language].WorkCenterText,
    InspectionOperation.InspOpUsageDecisionValuation,
    //Visible controler of sample bar: when 0 no sample bar

    InspectionOperation.InspLotHasSubsets,

    //Total number of Sample

    InspectionOperation.MaterialSampleCount,
    
    //Characteristic counts for sample

    InspectionOperation.InspSubsetCharcOpenCount,
    InspectionOperation.InspSubsetCharcAcceptedCount,
    InspectionOperation.InspSubsetCharcRejectedCount,
    
    //Visible controler of characteristics bar: when 0 no characteristic

    InspectionOperation.InspOpHasCharc,
    //Characteristic counts for no sample

    InspectionOperation.InspCharOpenCount,
    InspectionOperation.InspCharAcceptedCount,
    InspectionOperation.InspCharRejectedCount,
    
    //Total number of Characteristics

    case InspectionOperation.InspLotHasSubsets
    when 1 then (InspectionOperation.InspSubsetCharcAcceptedCount +
    InspectionOperation.InspSubsetCharcRejectedCount +
    InspectionOperation.InspSubsetCharcOpenCount)
    else (InspectionOperation.InspCharOpenCount + 
    InspectionOperation.InspCharAcceptedCount + 
    InspectionOperation.InspCharRejectedCount)
    end as InspCharCount,
    @Consumption.hidden
    InspectionLot.MatlQualityAuthorizationGroup, 

    //Asscociations

    _InspOperationChar,
    _InspectionOperation,
    _InspSubsetChar,
    _InspectionLot
}