C_IncidentTaskDefAndInstance

@AbapCatalog.sqlViewName: 'CINCDEFINST'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType:{ serviceQuality: #D,        // < 100 msec

                         sizeCategory:  #XL,         // < 10.000.000

                         dataClass: #MIXED }

@AccessControl.authorizationCheck: #CHECK
// #NOT_REQUIRED as a start

@AccessControl.personalData.blocking: #NOT_REQUIRED

@EndUserText.label: 'Incident Task Inst. and Future Defs.'

@Consumption.semanticObject: 'EHSTask'
@ObjectModel.semanticKey: 'EHSTaskDefinitionUUID'
@ObjectModel.representativeKey: 'EHSTaskDefinitionUUID'
@Metadata.allowExtensions: true

define view C_IncidentTaskDefAndInstance
  as select from C_EHSCombinedTaskDefAndInstce as CombinedTaskDefAndInstce
  association [1..1] to E_EHSTaskDefinition      as _Extension         on $projection.EHSTaskDefinitionUUID = _Extension.EHSTaskDefinitionUUID
  association [1..1] to E_EHSTaskPlannedInstance as _ExtensionInstance on $projection.EHSPlannedTaskUUID = _ExtensionInstance.EHSPlannedTaskUUID
  
{
      // keys and unique identifiers

  key EHSTaskDefinitionUUID,
  key WorkflowTaskInternalID,
  key EHSPlannedTaskUUID,

      // host.IncidentUUID,

      EHSTaskHostObjectInstance,
      @UI.hidden: true
      EHSTaskHostObjectInstanceUUID,
      EHSTaskHostObjectAdapterClass,
      EHSTaskHostSemanticObject,
      EHSTaskHasWorkflow,

      // fields on the List

      EHSTaskTitle,

      @ObjectModel.filter.enabled: true
      EHSPlannedTaskID,

      @ObjectModel.text.association: '_EHSTaskDefinitionTypeText'
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_IncidentTaskDefTypeVH',
          element: 'EHSTaskDefinitionType'
        }
      }]
      @UI.hidden: true
      EHSTaskDefinitionType,

      EHSTaskStatusName,
      EHSTaskStatusCriticality,

      EHSTaskDueDate,

      @Consumption.filter.hidden: false
      EHSTaskIsRecurrent,

      cast(EHSTaskInstanceProcessorName as ehfnd_current_processor_name) as EHSTaskInstanceProcessorName,

      @ObjectModel:{ readOnly: true, virtualElement, virtualElementCalculatedBy:  'ABAP:CL_EHHSS_IM_TASK_REFERENC_EXIT' }
      @ObjectModel.sort.enabled: false
      @ObjectModel.filter.enabled: false
      cast ( '' as ehfnd_task_reference_descr ) as EHSTskRelatedObjectDescription,

      EHSTaskStartDate,

      // fields fo sorting

      EHSTaskInstceCompletionDate,
      EHSTaskStatusValueForSorting,
      EHSTaskDateForSorting,

      // fields for status calculation

      EHSTaskDefinitionIsPaused,
      WorkflowTaskStatus,
      WrkflwTskCompletionUTCDateTime,
      EHSTaskDefinitionStatus,
      EHSTaskTimeZone,

      // navigation

      EHSTaskDefinitionManageAction,
      EHSTaskInstanceDisplayAction,

      EHSTaskOwnerUser,
      @ObjectModel.text.element: ['EHSTaskOwnerUserName']
      EHSTaskOwnerBP,
      // Begin correction 3372349 30.08.2023 ******************

      @UI.hidden:false
      @EndUserText.label: 'Owner'
      @Semantics.text: true
      // End correction 3372349 30.08.2023 ********************

      EHSTaskOwnerUserName,

      @ObjectModel.text.element: ['EHSTaskAssignedUserName']
      EHSTaskAssignedBP,
      // Begin correction 3372349 30.08.2023 ******************

      @UI.hidden:false
      @EndUserText.label: 'Assignee'
      @Semantics.text: true
      // End correction 3372349 30.08.2023 ********************

      EHSTaskAssignedUserName,
      EHSTaskAssignedLocRoleName,

      @ObjectModel.text.element: ['EHSTaskApprovingUserName']
      EHSTaskApprovingBP,
      // Begin correction 3372349 30.08.2023 ******************

      @UI.hidden:false
      @EndUserText.label: 'Approver'
      @Semantics.text: true
      // End correction 3372349 30.08.2023 ********************

      EHSTaskApprovingUserName,
      EHSTaskApproverLocRoleName,

      @Consumption.hidden: true
      EHSTaskInstanceProcessorUser,

      @UI.hidden: true
      @UI.textArrangement: #TEXT_ONLY
      IsDraftEntity,

      EditingStatusText,

       // Draft Administrative Data

      @UI.hidden: true
      DraftEntityLastChangeDateTime,
      @UI.hidden: true
      @UI.textArrangement: #TEXT_ONLY
      DraftIsLastChangedByMe,
      @UI.hidden: true
      LastChangedByUserDescription,
      @UI.hidden: true
      DraftIsProcessedByMe,
      @UI.hidden: true
      InProcessByUserDescription,
      @UI.hidden: true
      InProcessByUser,

      @UI.hidden: true
      @Semantics.booleanIndicator: true
      HasActiveEntity,

      @UI.hidden: true
      DraftUUID,
      
      @EndUserText.label: 'Type'
      _EHSTaskDefinitionTypeText[1:Language = $session.system_language ].EHSTaskDefinitionTypeName as EHSTaskDefinitionTypeName,

      _EHSTaskDefinitionTypeText,
      _TernaryLogicalStateText,
      // needed for create task navigation (Incident and Inv. Step are created with different adapter classes)

      _EHSTaskAdapterClass,
      // the association bellow is needed for the authority check


      _IncidentAuthorizationFields.IncidentUUID as IncidentUUID,

      // Associations for Authorization Check of Host BO

      _IncidentAuthorizationFields,

      _EHSCtrlImplmtnAuthznFields,
      _EHSRskAssessmentAuthznFields,
      _EHSCmplncScenAuthznFields,
      _CmplncRqmtAuthznFields,
      _EHSTaskDefinition,
      IncidentHasAccessRestriction

}
where
     EHSTaskHostSemanticObject = 'Incident'
  or EHSTaskHostSemanticObject = 'IncidentInvestigationStep'