C_InboundDeliveryObjPg

@AbapCatalog.sqlViewName: 'CINBDELIVOBJPG'
@ClientHandling.algorithm:#SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED,
  privilegedAssociations: [ '_Partner' ]
}

@ObjectModel: {
   compositionRoot: true,
   semanticKey: ['InboundDelivery'],
   representativeKey: 'InboundDelivery',
   usageType.dataClass: #MIXED,
   usageType.serviceQuality: #D,
   usageType.sizeCategory: #XL
}

@Consumption.semanticObject: 'InboundDelivery'

@Search.searchable: true

@Metadata.allowExtensions: true

// Needed on CDS View level for the extensibility registry:

@EndUserText.label: 'Inbound Delivery Object Page'
 
define view C_InboundDeliveryObjPg
  as select from I_InboundDelivery as InboundDelivery
  association [0..*] to C_SDDocumentPartnerCard    as _Partner                  on  $projection.InboundDelivery = _Partner.SDDocument
                                                                                and _Partner.SDDocumentItem     = '000000'
  association [0..*] to C_InboundDeliveryItemObjPg as _InboundDeliveryItemObjPg on  $projection.InboundDelivery = _InboundDeliveryItemObjPg.InboundDelivery
  association [1]    to E_DeliveryDocument         as _Extension                on  $projection.InboundDelivery = _Extension.DeliveryDocument
{

      //Header

      //**********************************************************************************************


      @Consumption.semanticObject: 'InboundDelivery'
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
  key InboundDelivery,

      cast( InboundDelivery._DeliveryDocumentType._Text[1: Language=$session.system_language].DeliveryDocumentTypeName as bezei20) as DeliveryDocumentTypeName,

      @Consumption.semanticObject: 'Supplier'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_Supplier_VH', element: 'Supplier' } } ]
      Supplier,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ShippingPointStdVH', element: 'ShippingPoint' } } ]
      ShippingPoint,

      cast(_OverallSDProcessStatus._Text[1: Language=$session.system_language].OverallSDProcessStatusDesc as gbstk_name)           as OverallSDProcessStatusDesc,

      cast(
          case OverallSDProcessStatus
            when '' then 0
            when 'A' then 2
            when 'B' then 2
            when 'C' then 3
            else 0
         end as abap.int1
      )                                                                                                                            as OvrlSDProcessStatusCriticality,

      DeliveryDate,


      //General Information

      //**********************************************************************************************


      @Semantics.quantity: { unitOfMeasure: 'HeaderWeightUnit'}
      @Consumption.filter.hidden: true
      cast(HeaderGrossWeight as le_brgew)                                                                                          as HeaderGrossWeight,

      @Semantics.quantity: { unitOfMeasure: 'HeaderWeightUnit'}
      @Consumption.filter.hidden: true
      HeaderNetWeight,

      @Semantics.unitOfMeasure: true
      @Consumption.filter.hidden: true
      HeaderWeightUnit,

      @Semantics.quantity: { unitOfMeasure: 'HeaderVolumeUnit'}
      @Consumption.filter.hidden: true
      HeaderVolume,

      @Semantics.unitOfMeasure: true
      @Consumption.filter.hidden: true
      HeaderVolumeUnit,

      @Consumption.filter.hidden: true
      TotalNumberOfPackage,

      DocumentDate,

      @ObjectModel.text.element: ['DeliveryDocumentTypeName']
      InboundDelivery._DeliveryDocumentType.DeliveryDocumentType                                                                   as DeliveryDocumentType,

      cast(PlannedGoodsIssueDate as wadak_plan)                                                                                    as PlannedGoodsIssueDate,

      cast(ActualGoodsMovementDate as vdm_actualgmdate)                                                                            as ActualGoodsMovementDate,

      Warehouse,


      //Warehouse

      //**********************************************************************************************

      @Consumption.filter.hidden: true
      OverallPutawayStatus,

      OverallPickingConfStatus,

      @Consumption.filter.hidden: true
      OverallWarehouseActivityStatus,

      OverallGoodsMovementStatus,

      cast(
          case OverallGoodsMovementStatus
            when '' then 0
            when 'A' then 2
            when 'B' then 2
            when 'C' then 3
            else 0
          end as abap.int1
      )                                                                                                                            as OvrlGdsMovementStsCriticality,

  
      @ObjectModel.foreignKey.association: '_DelivAdvncdShipgRcvgRlvnce'
      DelivAdvncdShipgRcvgRlvnce,
      
      @Consumption.filter.hidden: true
      @Semantics.booleanIndicator: true
      cast(
          case DelivAdvncdShipgRcvgRlvnce
            when '1' then ''
            else 'X'
          end as boole_d
      ) as AdvncdShipgRcvgIsInactive,

      @ObjectModel.foreignKey.association: '_WarehouseExecutionStatus'
      ReadyForWarehouseExecStatus,
      
      DelivIsQtyCrrtnAdvncShipgRcvg,


      @Consumption.filter.hidden: true
      _Partner,
      @Consumption.filter.hidden: true
      _Supplier,
      @Consumption.filter.hidden: true
      _ShippingPoint,
      @Consumption.filter.hidden: true
      _OverallPutawayStatus,
      @Consumption.filter.hidden: true
      _OvrlWarehouseActyStatus,
      @Consumption.filter.hidden: true
      _OverallPickingConfStatus,
      @Consumption.filter.hidden: true
      _OverallGoodsMovementStatus,
      @Consumption.filter.hidden: true
      _InboundDeliveryItemObjPg,
      @Consumption.filter.hidden: true
      _WarehouseExecutionStatus,
      @Consumption.filter.hidden: true
      _DelivAdvncdShipgRcvgRlvnce
} where 
DeletionIndicator = ' ';