C_GeneralLedgerAccount

DDL: C_GENERALLEDGERACCOUNT SQL: CFIGENLDGRACCT Type: view CONSUMPTION Package: FINS_FIS_GRC_APPS

General Ledger Account

C_GeneralLedgerAccount is a Consumption CDS View that provides data about "General Ledger Account" in SAP S/4HANA. It reads from 1 data source (I_GLAccount) and exposes 12 fields with key fields GLAccount, CompanyCode. It has 1 association to related views. Part of development package FINS_FIS_GRC_APPS.

1 data source(s) 12 fields

Data Sources (1)

SourceAliasJoin Type
I_GLAccount I_GLAccount from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_UserContactCard _UserContactCard $projection.CreatedByUser = _UserContactCard.ContactCardID

Annotations (16)

NameValueLevelField
AbapCatalog.sqlViewName CFIGENLDGRACCT view
EndUserText.label General Ledger Account view
VDM.viewType #CONSUMPTION view
OData.publish true view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AbapCatalog.buffering.status #NOT_ALLOWED view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #REQUIRED view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
ObjectModel.representativeKey GLAccount view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #MIXED view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY GLAccount GLAccount
KEY CompanyCode CompanyCode
CompanyCodeName _CompanyCode CompanyCodeName
ChartOfAccounts ChartOfAccounts
CreationDate CreationDate
CreatedByUser CreatedByUser
FullName _UserContactCard FullName
_Text _Text
_CompanyCode _CompanyCode
_ChartOfAccounts _ChartOfAccounts
_ChartOfAccountsText _ChartOfAccountsText
_UserContactCard _UserContactCard 
@AbapCatalog.sqlViewName: 'CFIGENLDGRACCT'
@EndUserText.label: 'General Ledger Account'
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations:  [ '_UserContactCard' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions: true }
@ObjectModel.representativeKey: 'GLAccount'
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED

define view C_GeneralLedgerAccount as select from I_GLAccount

association [0..1] to I_UserContactCard as _UserContactCard on $projection.CreatedByUser = _UserContactCard.ContactCardID
                                                                
{
    @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_GLAccountStdVH', element:'GLAccount' }, 
                   additionalBinding: [{ localElement: 'CompanyCode', element: 'CompanyCode' }]    
                                      }]
    @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }
    @ObjectModel.text.association: '_Text'
    key GLAccount,

    @Consumption.valueHelpDefinition: [{ entity:{ name: 'I_CompanyCodeVH', element:'CompanyCode' } }]
    @Consumption.filter: { selectionType: #SINGLE, multipleSelections: true, mandatory: false }
    @ObjectModel.foreignKey.association: '_CompanyCode'
    key CompanyCode,
    _CompanyCode.CompanyCodeName,
  
    @ObjectModel.text.association: '_ChartOfAccountsText'
    @ObjectModel.foreignKey.association: '_ChartOfAccounts'
    ChartOfAccounts,
    
    @Consumption.filter: { selectionType: #INTERVAL, multipleSelections: true, mandatory: false }
    @Semantics.systemDate.createdAt: true
    CreationDate,
    
    @ObjectModel.foreignKey.association: '_UserContactCard'
    @Consumption.semanticObject: 'User'
    CreatedByUser,
    @Semantics.name.fullName: true 
    _UserContactCard.FullName,
    
    _Text,
    _CompanyCode,
    _ChartOfAccounts,
    _ChartOfAccountsText,
    _UserContactCard
         
}

Learn More