C_GRC_CustomerChangeLog

@AbapCatalog.sqlViewName: 'CGRCCUSTMSTRCHG'
@EndUserText.label: 'Customer change log'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view C_GRC_CustomerChangeLog
  as select from I_ChangeDocumentItem
    inner join   I_Customer on I_ChangeDocumentItem.ChangeDocObject = I_Customer.Customer
{
  key I_Customer.Customer,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key I_ChangeDocumentItem.ChangeDocItemChangeType,

      cast (I_ChangeDocumentItem._ChangeDocument.CreationDate as fis_udate)      as ChangeDocCreationDate,
      cast(I_ChangeDocumentItem._ChangeDocument.CreatedByUser as lcm_changed_by) as LastChangedByUser,
      @EndUserText.label: 'New Field Value'
      I_ChangeDocumentItem.ChangeDocNewFieldValue,
      @EndUserText.label: 'Old Field Value'
      I_ChangeDocumentItem.ChangeDocPreviousFieldValue,
      @EndUserText.label: 'New Unit'
      I_ChangeDocumentItem.ChangeDocNewUnit,
      @EndUserText.label: 'Old Unit'
      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      @EndUserText.label: 'New Currency'
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      @EndUserText.label: 'Old Currency'
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,

      I_Customer.CustomerName,
      I_Customer.CustomerAccountGroup,
      I_Customer.CreatedByUser,
      I_Customer.CreationDate,
      I_Customer.DeliveryIsBlocked,
      I_Customer.PostingIsBlocked,
      I_Customer.BillingIsBlockedForCustomer,
      I_Customer.OrderIsBlockedForCustomer,
      I_Customer.IsBusinessPurposeCompleted,      
      I_Customer.IsOneTimeAccount,
      I_Customer.CityName,
      I_Customer.Country,
      I_Customer.AuthorizationGroup,
      I_Customer.DeletionIndicator,
      I_Customer.AlternativePayerAccount,
      I_Customer.AlternativePayeeIsAllowed,
      @ObjectModel.foreignKey.association:'_CustomerClassification'
      I_Customer.CustomerClassification,
            
      I_ChangeDocumentItem.ChangeDocObjectClass,
      I_ChangeDocumentItem.DatabaseTable,

      I_Customer._CustomerClassification,

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataControllerSet,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataController1,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataController2,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataController3,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataController4,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataController5,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataController6,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataController7,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataController8,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataController9,
      //added only for DCL check

      @UI.hidden: true
      @Consumption.filter.hidden: true
      I_Customer.DataController10      
}
where
      I_ChangeDocumentItem.ChangeDocObjectClass = 'DEBI'
  and I_ChangeDocumentItem.DatabaseTable        = 'KNA1'