C_GLAcctInChtOfAcctsChgLog

@AbapCatalog.sqlViewName: 'CGRCGLACCTCOACHG'
@EndUserText.label: 'GL account in CoA change log'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #CONSUMPTION
@OData.publish: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
define view C_GLAcctInChtOfAcctsChgLog
  as select from I_ChangeDocumentItem
    inner join   I_GLAccountInChartOfAccounts on I_ChangeDocumentItem.ChangeDocObject = concat(
      I_GLAccountInChartOfAccounts.ChartOfAccounts, I_GLAccountInChartOfAccounts.GLAccount
    )
{
      @Consumption.valueHelpDefinition: [
           { entity:  { name:    'I_ChartOfAccountsStdVH',
                        element: 'ChartOfAccounts' }
           }]
      @ObjectModel.text.association: '_ChartOfAccountsText'
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
  key I_GLAccountInChartOfAccounts.ChartOfAccounts,
  key I_GLAccountInChartOfAccounts.GLAccount,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key I_ChangeDocumentItem.ChangeDocItemChangeType,

      cast (I_ChangeDocumentItem._ChangeDocument.CreationDate as fis_udate)      as ChangeDocCreationDate,
      cast(I_ChangeDocumentItem._ChangeDocument.CreatedByUser as lcm_changed_by) as LastChangedByUser,
      @EndUserText.label: 'New Field Value'
      I_ChangeDocumentItem.ChangeDocNewFieldValue,
      @EndUserText.label: 'Old Field Value'
      I_ChangeDocumentItem.ChangeDocPreviousFieldValue,
      @EndUserText.label: 'New Unit'
      I_ChangeDocumentItem.ChangeDocNewUnit,
      @EndUserText.label: 'Old Unit'
      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      @EndUserText.label: 'New Currency'
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      @EndUserText.label: 'Old Currency'
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,

      I_GLAccountInChartOfAccounts.IsBalanceSheetAccount,
      @ObjectModel.foreignKey.association: '_GLAccountGroup'
      I_GLAccountInChartOfAccounts.GLAccountGroup,
      @ObjectModel.foreignKey.association: '_CorporateGroupChartOfAccounts'
      I_GLAccountInChartOfAccounts.CorporateGroupChartOfAccounts,
      @ObjectModel.foreignKey.association: '_CorporateGroupAccount'
      I_GLAccountInChartOfAccounts.CorporateGroupAccount,
      I_GLAccountInChartOfAccounts.ProfitLossAccountType,
      I_GLAccountInChartOfAccounts.SampleGLAccount,
      I_GLAccountInChartOfAccounts.AccountIsMarkedForDeletion,
      I_GLAccountInChartOfAccounts.AccountIsBlockedForCreation,
      I_GLAccountInChartOfAccounts.AccountIsBlockedForPosting,
      I_GLAccountInChartOfAccounts.AccountIsBlockedForPlanning,
      @ObjectModel.foreignKey.association: '_GlobalCompany'
      I_GLAccountInChartOfAccounts.PartnerCompany,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      I_GLAccountInChartOfAccounts.FunctionalArea,
      I_GLAccountInChartOfAccounts.CreationDate,
      I_GLAccountInChartOfAccounts.CreatedByUser,
      @ObjectModel.foreignKey.association: '_Glaccounttype'
      I_GLAccountInChartOfAccounts.GLAccountType,
      @ObjectModel.foreignKey.association: '_GLAccountSubtype'
      I_GLAccountInChartOfAccounts.GLAccountSubtype,
      I_GLAccountInChartOfAccounts.GLAccountExternal,
      I_GLAccountInChartOfAccounts.BankReconciliationAccount,

      I_GLAccountInChartOfAccounts._ChartOfAccounts,
      I_GLAccountInChartOfAccounts._ChartOfAccountsText,
      I_GLAccountInChartOfAccounts._GLAccountGroup,
      I_GLAccountInChartOfAccounts._CorporateGroupChartOfAccounts,
      I_GLAccountInChartOfAccounts._CorporateGroupAccount,
      I_GLAccountInChartOfAccounts._GlobalCompany,
      I_GLAccountInChartOfAccounts._FunctionalArea,
      I_GLAccountInChartOfAccounts._GLAccountType,
      I_GLAccountInChartOfAccounts._GLAccountSubtype,

      I_ChangeDocumentItem.ChangeDocObjectClass,
      I_ChangeDocumentItem.DatabaseTable

}
where
      I_ChangeDocumentItem.ChangeDocObjectClass = 'SACH'
  and I_ChangeDocumentItem.DatabaseTable        = 'SKA1'