C_FunctionalLocation

@ObjectModel.representativeKey: 'FunctionalLocation'
@EndUserText.label: 'Functional Location'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CFUNCTLLOCATION'
@AccessControl.authorizationCheck:#CHECK
@AbapCatalog.compiler.compareFilter: true

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MASTER 
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L


define view C_FunctionalLocation
with parameters
@Consumption.hidden: true
@Environment.systemField: #SYSTEM_LANGUAGE
P_Language : sylangu
as select from I_FunctionalLocation
association[0..1] to I_FunctionalLocationLabel as _FunctionalLocationLabel  on $projection.FunctionalLocation = _FunctionalLocationLabel.FunctionalLocation
association[0..1] to I_FunclocationLabelInternal as _PrimaryLabel on $projection.FunctionalLocation = _PrimaryLabel.FunctionalLocation
                                                                  and _PrimaryLabel.FunctionalLocLabelIsActive = 'X'
                                                                  and _PrimaryLabel.FuncnlLocLabelIsPrimaryLabel = 'X'    
{
    key FunctionalLocation, 
    
    // Select User Label if available, if not then primary label

    cast( _FunctionalLocationLabel.FunctionalLocationLabelName as ilom_strno ) as FunctionalLocationLabelName,
    
    _PrimaryLabel.FunctionalLocationLabelName as FuncnlLocPrimaryLabelName,
           
    _FunctionalLocationText[1: Language = $parameters.P_Language ].FunctionalLocationName,
    
    FunctionalLocationCategory, 
    _FunctionalLocationCategory._Text[1: Language = $parameters.P_Language ].FunctionalLocationCategoryDesc,
     
    WorkCenterInternalID, 
    WorkCenterTypeCode, 
    
    TechnicalObjectType, 
    _TechnicalObjectType._Text[1: Language = $parameters.P_Language ].TechnicalObjectTypeDesc,
    
    
    CreatedByUser, 
    CreationDate, 
    LastChangedByUser, 
    LastChangeDate,
    AssetManufacturerName,
    ManufacturerPartTypeName, 
    AuthorizationGroup,

    
    // Location data      

    _LocationAccountAssignment._WorkCenter.WorkCenter as MaintenanceWorkCenter, 
    _LocationAccountAssignment.MaintenancePlant,  
    _LocationAccountAssignment.PlantSection, 
    _LocationAccountAssignment.AssetLocation, 
    _LocationAccountAssignment.AssetRoom,
    _LocationAccountAssignment.MaintObjectFreeDefinedAttrib, 
    _LocationAccountAssignment.ABCIndicator, 
       
    // Organization

    _LocationAccountAssignment.BusinessArea, 
    _LocationAccountAssignment.ControllingArea, 
    _LocationAccountAssignment.CostCenter, 
    _LocationAccountAssignment.CompanyCode, 
    _LocationAccountAssignment.Division, 
    
    // Responsibilities

    _WorkCenter.WorkCenter as MainWorkCenter,    
    _WorkCenter.Plant as MainWorkCenterPlant, 
    
    MaintenancePlanningPlant,  
    MaintenancePlannerGroup,
    CatalogProfile, 
    
    //Sales Org Data

    _LocationAccountAssignment.SalesOrganization,
    _LocationAccountAssignment.DistributionChannel,
    _LocationAccountAssignment.SalesOffice,
    _LocationAccountAssignment.OrganizationDivision,
    _LocationAccountAssignment.SalesGroup,
    
    MaintObjectInternalID,
    
    _Status,

    // Propagate associations

    _FunctionalLocationCategory, 
    _FunctionalLocationText, 
    _TechnicalObjectType, 
    _WorkCenter

}