C_FinanceNotificationTP

DDL: C_FINANCENOTIFICATIONTP Type: view_entity CONSUMPTION Package: FBTI_FIN_NOTIFICATION_EXT

Finance Notification

C_FinanceNotificationTP is a Consumption CDS View that provides data about "Finance Notification" in SAP S/4HANA. It reads from 1 data source (R_FinanceNotificationTP) and exposes 39 fields with key field FinanceNotificationUUID. It is exposed through 1 OData service (UI_FINANCENOTIFICATION). Part of development package FBTI_FIN_NOTIFICATION_EXT.

1 data source(s) Exposed by 1 service(s) 39 fields

Data Sources (1)

SourceAliasJoin Type
R_FinanceNotificationTP R_FinanceNotificationTP projection

Annotations (12)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Finance Notification view
VDM.viewType #CONSUMPTION view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.sapObjectNodeType.name FinanceNotification view
AbapCatalog.extensibility.extensible true view
AbapCatalog.extensibility.allowNewCompositions true view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
Search.searchable true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_FINANCENOTIFICATION UI_FINANCENOTIFICATION V4 C1 NOT_RELEASED

Fields (39)

KeyFieldSource TableSource FieldDescription
KEY FinanceNotificationUUID FinanceNotificationUUID
FinanceNotificationType FinanceNotificationType
ReferenceDocumentType ReferenceDocumentType
ReferenceDocumentOID ReferenceDocumentOID
ReferenceDocumentDisplayID ReferenceDocumentDisplayID
ReferenceDocumentEventOID ReferenceDocumentEventOID
RefDocumentEventDisplayID RefDocumentEventDisplayID
ReferenceDocumentLogicalSystem ReferenceDocumentLogicalSystem
CompanyCode CompanyCode
PostingDate PostingDate
FinanceNotifProcessingStatus FinanceNotifProcessingStatus
IsReversal IsReversal
CreatedByUser CreatedByUser
CreationDateTime CreationDateTime
LocalInstanceLastChangedByUser LocalInstanceLastChangedByUser
LoclInstanceLastChangeDateTime LoclInstanceLastChangeDateTime
LastChangedByUser LastChangedByUser
LastChangeDateTime LastChangeDateTime
LogMessageText LogMessageText
ApplicationLogHandle ApplicationLogHandle
LatestMessageClass LatestMessageClass
LatestMessageNumber LatestMessageNumber
LatestMessageSeverity LatestMessageSeverity
LatestMessageVariable1Text LatestMessageVariable1Text
LatestMessageVariable2Text LatestMessageVariable2Text
LatestMessageVariable3Text LatestMessageVariable3Text
LatestMessageVariable4Text LatestMessageVariable4Text
StatusCriticality StatusCriticality
FinanceNotificationTypeText
ReferenceDocumentTypeName
CompanyCodeName _CompanyCode CompanyCodeName
FinanceNotifProcgStatusText
_CreatedByUser _CreatedByUser
_ChangedByUser _ChangedByUser
_LocalChangedByUser _LocalChangedByUser
_CompanyCode _CompanyCode
_NotificationType _NotificationType
_ReferenceDocumentType _ReferenceDocumentType
_ProcessingStatus _ProcessingStatus 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Finance Notification'
@VDM.viewType:#CONSUMPTION
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.sapObjectNodeType.name:'FinanceNotification'
@AbapCatalog.extensibility: {
  extensible: true,
  allowNewCompositions: true
}
@Metadata: {
  ignorePropagatedAnnotations: true,
  allowExtensions: true
}
@Search.searchable: true
@AccessControl.privilegedAssociations: ['_ChangedByUser','_LocalChangedByUser','_CreatedByUser']
define root view entity C_FinanceNotificationTP
  provider contract transactional_query
  as projection on R_FinanceNotificationTP  
{
  key FinanceNotificationUUID,
      @ObjectModel.foreignKey.association: '_NotificationType'
      @ObjectModel.text.element:['FinanceNotificationTypeText'] 
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      @EndUserText.quickInfo: 'Finance Notification Object Type'
      FinanceNotificationType,
      @ObjectModel.foreignKey.association: '_ReferenceDocumentType'
      @ObjectModel.text.element:['ReferenceDocumentTypeName'] 
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      ReferenceDocumentType,
      ReferenceDocumentOID,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      @EndUserText.quickInfo: 'Reference Document Display ID'
      ReferenceDocumentDisplayID,
      @EndUserText.quickInfo: 'Reference Document Event OID'
      ReferenceDocumentEventOID,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      @EndUserText.quickInfo: 'Reference Document Event Display ID'
      RefDocumentEventDisplayID,
      @EndUserText.quickInfo: 'Reference Document Logical System'     
      ReferenceDocumentLogicalSystem,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @ObjectModel.text.element:['CompanyCodeName'] 
      CompanyCode,
      @Consumption.filter.selectionType:#INTERVAL
      PostingDate,
      @ObjectModel.foreignKey.association: '_ProcessingStatus'
      @ObjectModel.text.element:['FinanceNotifProcgStatusText'] 
      FinanceNotifProcessingStatus,
      IsReversal,
      @UI.hidden: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      CreatedByUser,
      @Consumption.filter.selectionType:#INTERVAL
      CreationDateTime,
      @UI.hidden: true
      LocalInstanceLastChangedByUser,
      @UI.hidden: true
      @Consumption.filter.selectionType:#INTERVAL
      LoclInstanceLastChangeDateTime,
      @UI.hidden: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      LastChangedByUser,
      @Consumption.filter.selectionType:#INTERVAL
      LastChangeDateTime,   
      @UI.hidden: true  
      LogMessageText,
      @UI.hidden: true
      ApplicationLogHandle,
      @UI.hidden: true
      LatestMessageClass,
      @UI.hidden: true
      LatestMessageNumber,
      @UI.hidden: true
      LatestMessageSeverity,
      @UI.hidden: true
      LatestMessageVariable1Text,
      @UI.hidden: true
      LatestMessageVariable2Text,
      @UI.hidden: true
      LatestMessageVariable3Text,
      @UI.hidden: true
      LatestMessageVariable4Text,
      
      @UI.hidden: true
      StatusCriticality,
      @Semantics.text: true   
      @UI.hidden: true 
      _NotificationType._Text[1:Language=$session.system_language].FinanceNotificationTypeText,
      @Semantics.text: true   
      @UI.hidden: true 
      _ReferenceDocumentType._ReferenceDocumentTypeText[1:Language=$session.system_language].ReferenceDocumentTypeName,
      @Semantics.text: true   
      @UI.hidden: true 
      _CompanyCode.CompanyCodeName,
      @Semantics.text: true   
      @UI.hidden: true 
      _ProcessingStatus._Text[1:Language=$session.system_language].FinanceNotifProcgStatusText,
      /* Associations */
      _CreatedByUser,
      _ChangedByUser,
      _LocalChangedByUser,
      _CompanyCode,
      _NotificationType,
      _ReferenceDocumentType,
      _ProcessingStatus,
      _ProcessStep : redirected to composition child C_FinanceNotifProcessStepTP
}

Learn More