C_FinInvoiceItemFDP

@VDM.viewType: #CONSUMPTION

@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.supportedCapabilities: [ #OUTPUT_FORM_DATA_PROVIDER ]

@EndUserText.label: 'Corr Type SAP21 Invc itm'

define view entity C_FinInvoiceItemFDP

  as select from I_OperationalAcctgDocItem as Item

  association [0..1] to C_FinInvoiceBillToPartyFDP     as _BillToParty                on  $projection.Customer = _BillToParty.Customer

  association [0..*] to C_FinInvcWithholdingTaxItemFDP as _WithholdingTaxItem         on  $projection.CompanyCode            = _WithholdingTaxItem.CompanyCode
                                                                                      and $projection.FiscalYear             = _WithholdingTaxItem.FiscalYear
                                                                                      and $projection.AccountingDocument     = _WithholdingTaxItem.AccountingDocument
                                                                                      and $projection.AccountingDocumentItem = _WithholdingTaxItem.AccountingDocumentItem

  association [0..*] to C_FinInvoiceSEPAMandateFDP     as _SEPAMandate                on  $projection.Customer = _SEPAMandate.SEPAMandateSender

  association [0..1] to C_FinInvoiceOneTimeAccountFDP  as _OneTimeAccount             on  $projection.CompanyCode            = _OneTimeAccount.CompanyCode
                                                                                      and $projection.FiscalYear             = _OneTimeAccount.FiscalYear
                                                                                      and $projection.AccountingDocument     = _OneTimeAccount.AccountingDocument
                                                                                      and $projection.AccountingDocumentItem = _OneTimeAccount.AccountingDocumentItem
                                                                                      and $projection.AddressAndBankIsSetManually = 'X'
    
  association [0..1] to C_FinInvcBillToPartyCompanyFDP as _BillToPartyCompany         on  $projection.Customer        = _BillToPartyCompany.Customer
                                                                                      and $projection.CompanyCode     = _BillToPartyCompany.CompanyCode
                                                                                      
  association [0..*] to C_FinInvoiceItemNoteFDP        as _ItemNote                   on  $projection.CompanyCode            = _ItemNote.CompanyCode
                                                                                      and $projection.FiscalYear             = _ItemNote.FiscalYear
                                                                                      and $projection.AccountingDocument     = _ItemNote.AccountingDocument
                                                                                      and $projection.AccountingDocumentItem = _ItemNote.AccountingDocumentItem                                                                                    
  
  association [*]    to I_PostingKeyWthSpclGLCodeTxt   as _PostingKeyWthSpclGLCodeTxt on  $projection.PostingKey    =_PostingKeyWthSpclGLCodeTxt.PostingKey  
                                                                                      and $projection.SpecialGLCode = _PostingKeyWthSpclGLCodeTxt.SpecialGLCode

  association [*]    to I_GLAccountText                as _GLAccountText              on  $projection.ChartOfAccounts = _GLAccountText.ChartOfAccounts 
                                                                                      and $projection.GLAccount       = _GLAccountText.GLAccount   
                                                                                        
  association [0..1] to I_PaymentTerms                 as _PaymentTerm                on  $projection.PaymentTerms    = _PaymentTerm.PaymentTerms
  
  association [*]    to I_PaymentTermsText             as _PaymentTermText            on  $projection.PaymentTerms    = _PaymentTermText.PaymentTerms
  
  association [1]    to E_OperationalAcctgDocItem      as _Extension                  on  $projection.CompanyCode            = _Extension.CompanyCode 
                                                                                      and $projection.FiscalYear             = _Extension.FiscalYear 
                                                                                      and $projection.AccountingDocument     = _Extension.AccountingDocument 
                                                                                      and $projection.AccountingDocumentItem = _Extension.AccountingDocumentItem

{
  key Item.CompanyCode,
  key Item.FiscalYear,
  key Item.AccountingDocument,
  key Item.AccountingDocumentItem,

      Item.AccountingDocumentItemType,
      Item.PostingKey,
      _PostingKeyWthSpclGLCodeTxt[1:Language = $session.system_language].PostingKeyName,

      Item.GLAccount,
      _GLAccountText[1:Language = $session.system_language].GLAccountName,
      _GLAccountText[1:Language = $session.system_language].GLAccountLongName,

      Item.Customer,
      _Customer.CustomerName,
      _Customer.CustomerFullName,
      _Customer.IsOneTimeAccount,
      _Customer.AlternativePayeeIsAllowed,
      _Customer.AlternativePayerAccount,
      
      Item.Supplier,
      _Supplier.SupplierName,
      _Supplier.SupplierFullName,

      Item.ClearingDate,
//      Item.ClearingAccountingDocument,

      Item.ClearingDocFiscalYear,
      Item.ClearingJournalEntry,

      Item.FinancialAccountType,
      //    UMSKZ

      Item.SpecialGLCode,
      //    UMSKS

      Item.SpecialGLTransactionType,

      Item.BaseUnit,
      Item.Quantity,
      cast('' as mseh3 ) as UnitOfMeasure_E,

      Item.DebitCreditCode,
      Item.FiscalPeriod,
      Item.TransactionTypeDetermination,
      Item.DocumentItemText,
      Item.Product,
      Item.Plant,
      Item.ValuationArea,
      Item.InventoryValuationType,
      Item.DueCalculationBaseDate,
      Item.PaymentTerms,
      _PaymentTerm.PaymentIsInstallment,
      _PaymentTermText[1:Language = $session.system_language].PaymentTermsName,
      _PaymentTermText[1:Language = $session.system_language].PaymentTermsDescription,
      Item.CashDiscount1Days,
      Item.CashDiscount2Days,
      cast( '00000000' as farp_sk1dt ) as CashDiscount1DueDate,
      cast( '00000000' as farp_sk2dt ) as CashDiscount2DueDate,
      Item.NetPaymentDays,
      cast( '00000000' as farp_netdt ) as NetDueDate,
      Item.CashDiscount1Percent,
      Item.CashDiscount2Percent,
      Item.VATRegistration,
      Item.InvoiceReference,
      Item.InvoiceReferenceFiscalYear,
      Item.FollowOnDocumentType,
      Item.InvoiceItemReference,

      Item.GoodsMovementEntryUnit,
      @Semantics: { quantity : {unitOfMeasure: 'GoodsMovementEntryUnit'} }
      Item.QuantityInEntryUnit,
      Item.DelivOfGoodsDestCountry,
      Item.DelivOfGoodsOriginCountry,

      Item.TaxCountry,
      Item.TaxCode,
      Item.TaxType,
      Item.TaxItemGroup,
      Item.TaxRateValidityStartDate,
      Item.TaxDeterminationDate,
      Item.WithholdingTaxCode,

      Item.TransactionCurrency,
      Item.AmountInTransactionCurrency,

      Item.CompanyCodeCurrency,
      Item.AmountInCompanyCodeCurrency,

      Item.BalanceTransactionCurrency,
      Item.AmountInBalanceTransacCrcy,

      Item.OriglTaxBaseAmountInCoCodeCrcy,
      Item.OriginalTaxBaseAmount,

      Item.TaxAmountInCoCodeCrcy,
      Item.TaxAmount,
      Item.TaxBaseAmountInCoCodeCrcy,
      Item.TaxBaseAmountInTransCrcy,
      Item.WithholdingTaxBaseAmount,
      Item.ChartOfAccounts,
      Item.ServiceDocumentType,
      Item.MasterFixedAsset,
      Item.AccountingDocumentType,
      Item.IsSalesRelated,
      Item.IsOpenItemManaged,
      Item.AddressAndBankIsSetManually,
      
      
      /* Access Control */
      Item.ServiceDocument,
      Item.FixedAsset,
      Item.PostingDate,
      Item.OrderID,
      Item.SalesDocument,
      Item.FunctionalArea,
      Item.CostCenter,
      Item.ControllingArea,
      Item.Segment,
      Item.ProfitCenter,


      /* Associations */
      Item._Customer,
      Item._Supplier,
      _BillToParty,
      _WithholdingTaxItem,
      _SEPAMandate,
      _OneTimeAccount,
      _BillToPartyCompany,
      _ItemNote,

      /*For Access Control*/
      Item._GLAccountInCompanyCode,
      Item._ServiceDocument,
      Item._SalesDoc,
      Item._FixedAsset,
      Item._Order,
      Item._CurrentCostCenter,
      Item._CurrentProfitCenter,
      Item._AccountingDocumentType
//      @ObjectModel.filter.enabled: false

//      _CorrespondenceItemNote


}