C_FinInvcRelatedAcctgDocItmFDP

@VDM.viewType: #CONSUMPTION

@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.supportedCapabilities: [ #OUTPUT_FORM_DATA_PROVIDER ]
@EndUserText.label: 'FI Invoice Related Acctg Doc Item'

define view entity C_FinInvcRelatedAcctgDocItmFDP as select from I_OperationalAcctgDocItem
  association [*]    to I_PostingKeyWthSpclGLCodeTxt   as _PostingKeyWthSpclGLCodeTxt on  $projection.PostingKey    =_PostingKeyWthSpclGLCodeTxt.PostingKey  
                                                                                      and $projection.SpecialGLCode = _PostingKeyWthSpclGLCodeTxt.SpecialGLCode
  association [*]    to I_GLAccountText                as _GLAccountText              on  $projection.ChartOfAccounts = _GLAccountText.ChartOfAccounts 
                                                                                      and $projection.GLAccount       = _GLAccountText.GLAccount     

{
  key CompanyCode,
  key FiscalYear,
  key AccountingDocument,
  key AccountingDocumentItem,

      AccountingDocumentItemType,
      PostingKey,
      _PostingKeyWthSpclGLCodeTxt[1:Language = $session.system_language].PostingKeyName,

      GLAccount,
      _GLAccountText[1:Language = $session.system_language].GLAccountName,
      _GLAccountText[1:Language = $session.system_language].GLAccountLongName,

      Customer,
      _Customer.CustomerName,
      _Customer.CustomerFullName,

      Supplier,
      _Supplier.SupplierName,
      _Supplier.SupplierFullName,

      ClearingDate,
//      ClearingAccountingDocument,

      ClearingDocFiscalYear,
      ClearingJournalEntry,

      FinancialAccountType,
      //    UMSKZ

      SpecialGLCode,
      //    UMSKS

      SpecialGLTransactionType,

      BaseUnit,
      Quantity,

      DebitCreditCode,
      FiscalPeriod,
      TransactionTypeDetermination,
      DocumentItemText,
      Product,
      Plant,
      ValuationArea,
      InventoryValuationType,
      DueCalculationBaseDate,
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      NetPaymentDays,
      CashDiscount1Percent,
      CashDiscount2Percent,
      VATRegistration,
      InvoiceReference,
      InvoiceReferenceFiscalYear,
      FollowOnDocumentType,
      InvoiceItemReference,

      GoodsMovementEntryUnit,
      @Semantics: { quantity : {unitOfMeasure: 'GoodsMovementEntryUnit'} }
      QuantityInEntryUnit,
      DelivOfGoodsDestCountry,
      DelivOfGoodsOriginCountry,

      TaxCountry,
      TaxCode,
      TaxType,
      TaxItemGroup,
      TaxRateValidityStartDate,
      TaxDeterminationDate,
      WithholdingTaxCode,

      TransactionCurrency,
      AmountInTransactionCurrency,

      CompanyCodeCurrency,
      AmountInCompanyCodeCurrency,

      BalanceTransactionCurrency,
      AmountInBalanceTransacCrcy,

      OriglTaxBaseAmountInCoCodeCrcy,
      OriginalTaxBaseAmount,

      TaxAmountInCoCodeCrcy,
      TaxAmount,
      TaxBaseAmountInCoCodeCrcy,
      TaxBaseAmountInTransCrcy,
      WithholdingTaxBaseAmount,
      ChartOfAccounts,
      ServiceDocumentType,
      MasterFixedAsset,
      AccountingDocumentType,
      IsSalesRelated,
      IsOpenItemManaged,
      
      /* Access Control */
      ServiceDocument,
      FixedAsset,
      PostingDate,
      OrderID,
      SalesDocument,
      FunctionalArea,
      CostCenter,
      ControllingArea,
      Segment,
      ProfitCenter,
      
      /* Associations */
      _Customer,
      _Supplier,


      /*For Access Control*/
      _GLAccountInCompanyCode,
      _ServiceDocument,
      _SalesDoc,
      _FixedAsset,
      _Order,
      _CurrentCostCenter,
      _CurrentProfitCenter,
      _AccountingDocumentType  
}