C_FSItemMappedHeader

@EndUserText.label: 'Financial Statement Item Mapped Header'
@AbapCatalog.sqlViewName: 'CFSMMAPPEDHDR'
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@AccessControl.authorizationCheck: #CHECK

@ObjectModel.usageType: {
  dataClass: #MIXED,
  serviceQuality: #C,
  sizeCategory: #M
}
//

//STS - CLARIFY IF VIEW CAN BE DELETED: no, cannot be deleted, used for metadata in F3335

//

define view C_FSItemMappedHeader
  as select from I_FSItemMappingRevision

  //STS - clarify if standard value help should be used

  association [1..1] to C_FSItemMappedCnsldtnChtAccts as _ChartOfAccountsVH   on  $projection.ConsolidationChartOfAccounts = _ChartOfAccountsVH.ConsolidationChartOfAccounts

  //STS - clarify if standard value help should be used

  association [1..1] to C_FSItemMappedGLChtAccts      as _GLChartOfAccountsVH on  $projection.ConsolidationChartOfAccounts = _GLChartOfAccountsVH.ConsolidationChartOfAccounts
                                                                              and $projection.ChartOfAccounts              = _GLChartOfAccountsVH.ChartOfAccounts

  association [1..1] to C_FSItemMappedMappingID       as _MappingVH           on  $projection.ConsolidationChartOfAccounts = _MappingVH.ConsolidationChartOfAccounts
                                                                              and $projection.ChartOfAccounts              = _MappingVH.ChartOfAccounts
                                                                              and $projection.FSItemMappingID              = _MappingVH.FSItemMappingID

  association [1..1] to C_FSItemMappingRevision       as _MappingRevisionVH   on  $projection.ConsolidationChartOfAccounts = _MappingRevisionVH.ConsolidationChartOfAccounts
                                                                              and $projection.FSItemMappingID              = _MappingRevisionVH.FSItemMappingID
                                                                              and $projection.ChartOfAccounts              = _MappingRevisionVH.ChartOfAccounts
                                                                              and $projection.FSItemMappingRevision        = _MappingRevisionVH.FSItemMappingRevision
{

  key cast(concat(concat(concat(FSItemMappingID,FSItemMappingRevision),ChartOfAccounts),ConsolidationChartOfAccounts) as fincs_md_record_id) as AdditionalMasterDataCode,

      @Consumption.valueHelpDefinition.association: '_ChartOfAccountsVH'
      @ObjectModel.foreignKey.association: '_ChartOfAccountsVH'
      @ObjectModel.text.element:  [ 'ConsolidationChartOfAcctsText' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      ConsolidationChartOfAccounts,

      _ChartOfAccountsVH.ConsolidationChartOfAcctsText,


      @Consumption.valueHelpDefinition.association: '_GLChartOfAccountsVH'
      @ObjectModel.foreignKey.association: '_GLChartOfAccountsVH'
      @ObjectModel.text.element:  [ 'ChartOfAccountsName' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      ChartOfAccounts,

      _GLChartOfAccountsVH.ChartOfAccountsName,

      @ObjectModel.foreignKey.association: '_MappingVH'
      @Consumption.valueHelpDefinition.association: '_MappingVH'
      @ObjectModel.text.element:  [ 'FSItemMappingName' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      FSItemMappingID,

      _MappingVH.FSItemMappingName,

      @ObjectModel.foreignKey.association: '_MappingRevisionVH'
      @Consumption.valueHelpDefinition.association: '_MappingRevisionVH'
      @ObjectModel.text.element:  [ 'FSItemMappingRevisionText' ]
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      FSItemMappingRevision,

      _MappingRevisionVH.FSItemMappingRevisionText,


      _MappingVH,
      _MappingRevisionVH,
      _GLChartOfAccountsVH,
      _ChartOfAccountsVH
}