C_FMEATaskFDP

DDL: C_FMEATASKFDP Type: view_entity CONSUMPTION Package: ODATA_QM_FMEA

Action of FMEA Cause

C_FMEATaskFDP is a Consumption CDS View that provides data about "Action of FMEA Cause" in SAP S/4HANA. It reads from 1 data source (I_FMEATask) and exposes 42 fields with key field FMEATaskUUID. It has 2 associations to related views. Part of development package ODATA_QM_FMEA.

1 data source(s) 42 fields

Data Sources (1)

SourceAliasJoin Type
I_FMEATask I_FMEATask from

Associations (2)

CardinalityTargetAliasCondition
[0..1] I_QltyMgmtSystAndUsrTmeZn _QltyMgmtSystAndUsrTmeZn 1 = 1
[0..*] C_FMEATaskPartnerFDP _FMEATaskPartnerFDP $projection.FMEATaskUUID = _FMEATaskPartnerFDP.FMEATaskUUID and _FMEATaskPartnerFDP.FMEAPartnerRole = '60'

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
EndUserText.label Action of FMEA Cause view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.modelingPattern #OUTPUT_FORM_DATA_PROVIDER view
VDM.viewType #CONSUMPTION view

Fields (42)

KeyFieldSource TableSource FieldDescription
KEY FMEATaskUUID FMEATaskUUID
FMEAParentNodeUUID FMEAParentNodeUUID
FMEAAuthorizationGroup FMEAAuthorizationGroup
FMEATaskStatus FMEATaskStatus
FMEAStatusDescription
FMEATaskActionStatus _FMEATaskActionStatus FMEATaskActionStatus
FMEATaskActionStatusDesc
FMEATaskCompletionRate FMEATaskCompletionRate
FMEAValuationProfile FMEAValuationProfile
FMEAHasTargetValuation FMEAHasTargetValuation
FMEAValnPrflTargetValuation FMEAValnPrflTargetValuation
FMEATargetValuationScoreValue FMEATargetValuationScoreValue
FMEATargetValnResultValue FMEATargetValnResultValue
FMEAValnProfileValuation FMEAValnProfileValuation
FMEAValuationScoreValue FMEAValuationScoreValue
FMEAValuationResultValue FMEAValuationResultValue
FMEATaskConfirmationDateTime FMEATaskConfirmationDateTime
QualityTaskCodeCatalog QualityTaskCodeCatalog
QualityTaskCodeGroup QualityTaskCodeGroup
QualityTaskCode QualityTaskCode
FMEATaskIsCancelled FMEATaskIsCancelled
FMEATaskIsStartAction FMEATaskIsStartAction
ChangedDateTime ChangedDateTime
FMEATaskGroup FMEATaskGroup
FMEATaskType FMEATaskType
FMEATask _FMEATaskAssignment FMEATask
FMEATaskDescription
FMEATaskLongText
CreationDate _FMEATaskAssignment CreationDate
FMEATaskActionPriorityValue
FMEATaskRiskPrioNumberValue
FMEATaskProbltyOfDtctnVal
FMEATaskProbltyOfOccrenVal
FMEATaskSeverityValue
FMEAPartnerRole _FMEATaskPartnerFDP FMEAPartnerRole
BusinessPartnerName
_FMEATaskPartnerFDP _FMEATaskPartnerFDP
_FMEAAuthorizationGroup _FMEAAuthorizationGroup
_FMEATaskActionStatus _FMEATaskActionStatus
_FMEATaskAssignment _FMEATaskAssignment
_FMEATaskType _FMEATaskType
_ParentNodeAssignment _ParentNodeAssignment 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: { authorizationCheck: #MANDATORY, personalData.blocking: #BLOCKED_DATA_EXCLUDED }
@EndUserText.label: 'Action of FMEA Cause'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #TRANSACTIONAL
}
@ObjectModel.modelingPattern:           #OUTPUT_FORM_DATA_PROVIDER
@ObjectModel.supportedCapabilities:  [  #OUTPUT_FORM_DATA_PROVIDER   ]
@VDM: { viewType: #CONSUMPTION }

define view entity C_FMEATaskFDP
  as select from I_FMEATask

  association [0..1] to I_QltyMgmtSystAndUsrTmeZn as _QltyMgmtSystAndUsrTmeZn on  1 = 1
  association [0..*] to C_FMEATaskPartnerFDP      as _FMEATaskPartnerFDP      on  $projection.FMEATaskUUID            = _FMEATaskPartnerFDP.FMEATaskUUID
                                                                              and _FMEATaskPartnerFDP.FMEAPartnerRole = '60'

{
  key FMEATaskUUID,
      FMEAParentNodeUUID,
      FMEAAuthorizationGroup,
      FMEATaskStatus,
      _FMEATaskStatus._Text[ 1:Language = $session.system_language ].FMEAStatusDescription,
      _FMEATaskActionStatus.FMEATaskActionStatus,
      _FMEATaskActionStatus._Text[ 1:Language = $session.system_language ].FMEATaskActionStatusDesc,
      FMEATaskCompletionRate,
      FMEAValuationProfile,
      FMEAHasTargetValuation,
      FMEAValnPrflTargetValuation,
      FMEATargetValuationScoreValue,
      FMEATargetValnResultValue,
      FMEAValnProfileValuation,
      FMEAValuationScoreValue,
      FMEAValuationResultValue,
      FMEATaskConfirmationDateTime,
      QualityTaskCodeCatalog,
      QualityTaskCodeGroup,
      QualityTaskCode,
      @Semantics.booleanIndicator: true
      FMEATaskIsCancelled,
      @Semantics.booleanIndicator: true
      FMEATaskIsStartAction,
      ChangedDateTime,
      FMEATaskGroup,
      FMEATaskType,
      _FMEATaskAssignment.FMEATask,
      _FMEATaskText[ 1:Language = $session.system_language ].FMEATaskDescription,
      _FMEATaskLongText[ 1:Language = $session.system_language ].FMEALongText                   as FMEATaskLongText,

      cast( tstmp_to_dats( _FMEATaskAssignment.FMEATaskPlannedFinishDateTime,
                           _QltyMgmtSystAndUsrTmeZn.QltyMgmtUserTimeZone,
                           $session.client, 'NULL' ) as plmt_audit_date_final preserving type ) as FMEATaskPlannedFinishDate,
      _FMEATaskAssignment.CreationDate,

      // to be filled in ABAP

      @ObjectModel: { readOnly: true, virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_QM_TASK_FDP_EXIT_HELPER' }
      cast( '' as abap.char(2))                                                                 as FMEATaskActionPriorityValue,
      @ObjectModel: { readOnly: true, virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_QM_TASK_FDP_EXIT_HELPER' }
      cast( '' as abap.char(6))                                                                 as FMEATaskRiskPrioNumberValue,
      @ObjectModel: { readOnly: true, virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_QM_TASK_FDP_EXIT_HELPER' }
      cast( '' as abap.char(2) )                                                                as FMEATaskProbltyOfDtctnVal,
      @ObjectModel: { readOnly: true, virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_QM_TASK_FDP_EXIT_HELPER' }
      cast( '' as abap.char(2) )                                                                as FMEATaskProbltyOfOccrenVal,
      @ObjectModel: { readOnly: true, virtualElement: true, virtualElementCalculatedBy: 'ABAP:CL_QM_TASK_FDP_EXIT_HELPER' }
      cast( '' as abap.char(2) )                                                                as FMEATaskSeverityValue,

      _FMEATaskPartnerFDP.FMEAPartnerRole,
      _FMEATaskPartnerFDP._BusinessPartner.BusinessPartnerName,

      /* Associations */
      _FMEATaskPartnerFDP,
      @Consumption.hidden
      _FMEAAuthorizationGroup,
      _FMEATaskActionStatus,
      @Consumption.hidden
      _FMEATaskAssignment,
//      _FMEATaskLongText,

//      _FMEATaskStatus,

//      _FMEATaskText,

      _FMEATaskType,
//      _FMEAValnProfileTargetValn,

//      _FMEAValnProfileValuation,

//      _FMEAValuationProfile,

      _ParentNodeAssignment
}
where
  FMEATaskIsCancelled is initial

Learn More