C_ExtResourceBusinessUserTP

@AbapCatalog.sqlViewName: 'CEXTRESBUSUSERTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.personalData.blocking: #REQUIRED

@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'External Resource Business User TP - Consumption View'

@VDM.viewType: #CONSUMPTION

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions
@Search.searchable: true
@ObjectModel: {
    transactionalProcessingDelegated: true,
    compositionRoot: true,
    draftEnabled: true,

    createEnabled: true,
    deleteEnabled: 'EXTERNAL_CALCULATION',
    updateEnabled: 'EXTERNAL_CALCULATION',
    semanticKey: ['BusinessPartner']
}
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view C_ExtResourceBusinessUserTP
  as select from I_BusinessUserTP
  association [1..1] to C_BPUsrChangeDocument as _ChangeDoc on $projection.BusinessPartnerUUID = _ChangeDoc.BusinessPartnerUUID
{
  key BusinessPartnerUUID,

      @Consumption.semanticObject: 'BusinessUser'
      BusinessPartner,

      BusinessPartnerRoleCategory,

      BusinessPartnerRole,

      PersonNumber,

      // Basic Data //

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      @EndUserText: { label: 'External Resource ID', quickInfo: 'External Resource ID' }
      PersonExternalID                           as ExternalResourceID,

      @Consumption.valueHelpDefinition.entity : {name: 'C_BPUSRFormOfAddressVH', element: 'FormOfAddress'}
      @Consumption.filter: {hidden: true}
      @ObjectModel.text.element: ['FormOfAddressName']
      FormOfAddress,

      @Semantics.text: true
      @ObjectModel.readOnly: true
      _FormOfAddressText.FormOfAddressName,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      FirstName,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.85}
      LastName,

      // Validity Period //

      @Consumption.filter: {hidden: true}
      ValidityStartDate,

      @Consumption.filter: {hidden: true}
      ValidityEndDate,

      @EndUserText: { label: 'Selected for Archiving', quickInfo: 'Selected for Archiving' }
      @Consumption: {filter: {selectionType: #SINGLE, defaultValue: ' ' }}
      IsMarkedForArchiving,

      // Business User //

      @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.85}
      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'User ID', quickInfo: 'User ID' }
      @Consumption.valueHelpDefinition.entity : {name: 'C_BPUsrAssignmentVH', element: 'UserID'}
      UserID,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'User Name', quickInfo: 'User Name' }
      UserName,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'User Description', quickInfo: 'User Description' }
      UserDescription,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Is External Resource of', quickInfo: 'Is External Resource of' }
      @Consumption.valueHelpDefinition.entity : {name: 'C_BPUsrRelshpBPOrgVH', element: 'BusinessPartner'}
      BusinessPartnerCompanyBUR025,

      // Contact //

      @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.85}
      @Semantics.eMail.type:  #WORK
      @Semantics.eMail.address: true
      EmailAddress,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Correspondence Language', quickInfo: 'Correspondence Language' }
      @Consumption.valueHelpDefinition.entity : {name: 'I_Language', element: 'Language'}
      @ObjectModel.text.element: ['CorrespondenceLanguageName']
      CorrespondenceLanguage,

      @Semantics.text: true
      @ObjectModel.readOnly: true
      _CorrespondenceLanguage.LanguageName       as CorrespondenceLanguageName,

      // Telephone //

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Country/Region Code', quickInfo: 'Country/Region Code' }
      @Consumption.valueHelpDefinition.entity : {name: 'I_CountryVH', element: 'Country'}
      @ObjectModel.text.element: ['DestinationLocationCountryName']
      DestinationLocationCountry,

      @Semantics.text: true
      @ObjectModel.readOnly: true
      _DestinationLocationCountry.CountryName    as DestinationLocationCountryName,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Phone', quickInfo: 'Phone' }
      PhoneNumber,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Phone Extension', quickInfo: 'Phone Extension' }
      PhoneNumberExtension,

      // Mobile Phone //

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Country/Region Code', quickInfo: 'Country/Region Code' }
      @Consumption.valueHelpDefinition.entity : {name: 'I_CountryVH', element: 'Country'}
      @ObjectModel.text.element: ['MblPhoneDestinationCountryName']
      MblPhoneDestinationLocCountry,

      @Semantics.text: true
      @ObjectModel.readOnly: true
      _MblPhoneDestinationLocCountry.CountryName as MblPhoneDestinationCountryName,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Mobile', quickInfo: 'Mobile' }
      MobilePhoneNumber,

      // Fax //

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Country/Region Code', quickInfo: 'Country/Region Code' }
      @Consumption.valueHelpDefinition.entity : {name: 'I_CountryVH', element: 'Country'}
      FaxNumberCountry,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Fax', quickInfo: 'Fax' }
      FaxAreaCodeSubscriberNumber,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Fax Extension', quickInfo: 'Fax Extension' }
      FaxExtensionNumber,

      // WorkPlace Data //

      @Consumption.filter: {hidden: true}
      Building,

      @Consumption.filter: {hidden: true}
      RoomNumber,

      @Consumption.filter: {hidden: true}
      Department,

      @Consumption.filter: {hidden: true}
      FunctionalTitleName,

      // Name Data //

      @Consumption.filter: {hidden: true}
      AdditionalLastName,

      @Consumption.filter: {hidden: true}
      @Consumption.valueHelpDefinition.entity: {name: 'I_BusPartPrefixName', element: 'LastNamePrefix' }
      LastNamePrefix,

      @Consumption.filter: {hidden: true}
      @Consumption.valueHelpDefinition.entity: {name: 'I_BusPartPrefixName', element: 'LastNamePrefix' }
      LastNameSecondPrefix,

      @Consumption.filter: {hidden: true}
      BirthName,

      @Consumption.filter: {hidden: true}
      NickName,

      @Consumption.filter: {hidden: true}
      MiddleName,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Academic Title', quickInfo: 'Academic Title' }
      @Consumption.valueHelpDefinition.entity : {name: 'I_AcademicTitleVH', element: 'AcademicTitle'}
      @ObjectModel.text.element: ['AcademicTitleName']
      AcademicTitle,

      @Semantics.text: true
      @ObjectModel.readOnly: true
      _AcademicTitle1.AcademicTitleName          as AcademicTitleName,

      @Consumption.filter: {hidden: true}
      @EndUserText: { label: 'Academic Second Title', quickInfo: 'Academic Second Title' }
      @Consumption.valueHelpDefinition.entity : {name: 'I_AcademicTitleVH', element: 'AcademicTitle'}
      @ObjectModel.text.element: ['AcademicTitle2Name']
      AcademicSecondTitle,

      @Semantics.text: true
      @ObjectModel.readOnly: true
      _AcademicTitle2.AcademicTitleName          as AcademicTitle2Name,

      @Consumption.filter: {hidden: true}
      @Consumption.valueHelpDefinition.entity: {name: 'I_BusPartSupplementName', element: 'BusinessPartnerSupplementName' }
      NameSupplement,

      @Consumption.filter: {hidden: true}
      Initials,

      @Consumption.filter: {hidden: true}
      @Semantics.name.fullName: true
      PersonFullName,

      @Consumption.filter: {hidden: true}
      @ObjectModel.text.element: ['NameFormatDescription']
      NameFormat,
      @ObjectModel.readOnly: true
      _NameFormatText.NameFormatDescription      as NameFormatDescription,

      @Consumption.filter: {hidden: true}
      @ObjectModel.text.element: ['CountryFreeText']
      NameCountry,
      @ObjectModel.readOnly: true
      _NameCountryText.CountryName               as CountryFreeText,

      @Consumption.filter: {hidden: true}
      SearchTerm1,

      @Consumption.filter: {hidden: true}
      SearchTerm2,

      // Other hidden fields //

      AuthorizationGroup,

      CreationDateTime,

      CreatedByUser,

      LastChangeDateTime,

      LastChangedByUser,

      IsBusinessPurposeCompleted,

      @Consumption.hidden:true
      DataControllerSet,

      @ObjectModel.readOnly: true
      _ChangeDoc.BPAddressChangeDocObject        as BPAddressChangeDocObject,

      _BPUsrRelShpBUR025
}
where
  BusinessPartnerRoleCategory = 'BBP005'