@AbapCatalog.sqlViewName: 'CENTPROJMCHG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Enterprise Project for Mass Change'
@AccessControl: {
authorizationCheck: #CHECK,
personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
semanticKey: [ 'Project' ],
representativeKey: 'ProjectUUID',
usageType: {
serviceQuality: #D,
dataClass: #MIXED,
sizeCategory: #L
},
updateEnabled: true
}
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions: true
define view C_EntProjectMassChange
as select from I_PPM_Project
association [0..1] to C_PPM_ProjectMemberContactCard as _Manager on _Manager.BusinessPartnerUUID = $projection.ProjectManagerUUID
association [0..*] to I_CostCenterText as _ResponsibleCostCenterText on _ResponsibleCostCenterText.CostCenter = $projection.ResponsibleCostCenter
and _ResponsibleCostCenterText.ControllingArea = $projection.ControllingArea
and _ResponsibleCostCenterText.ValidityEndDate > $session.system_date
and _ResponsibleCostCenterText.ValidityStartDate < $session.system_date
association [0..1] to I_UserContactCard as _CreatedByUser on _CreatedByUser.ContactCardID = $projection.CreatedByUser
association [1..1] to E_PPM_Project as _ProjectHeaderExtension on $projection.ProjectUUID = _ProjectHeaderExtension.ProjectUUID
association [0..1] to C_PPM_TeamMemberSearchHelp as _TeamMember on _TeamMember.BusinessPartnerUUID = $projection.ProjectManagerUUID
association [0..*] to I_FixedAsset as _FixedAsset on _FixedAsset.InvestmentProjectWBSElement = $projection.WBSElementInternalID
and $projection.WBSElementInternalID <> '00000000'
association [0..*] to I_ProfitCenterText as _ProfitCenterText on _ProfitCenterText.ProfitCenter = $projection.ProfitCenter
and _ProfitCenterText.ControllingArea = $projection.ControllingArea
and _ProfitCenterText.ValidityEndDate > $session.system_date
and _ProfitCenterText.ValidityStartDate < $session.system_date
association [0..*] to I_InvestmentProfileText as _InvestmentProfileText on $projection.InvestmentProfile = _InvestmentProfileText.InvestmentProfile
association [0..*] to I_FactoryCalendarText as _FactoryCalendarText on $projection.FactoryCalendar = _FactoryCalendarText.FactoryCalendar
association [0..*] to I_CostingSheetProcedureText as _CostingSheetProcedureText on _CostingSheetProcedureText.CostingSheetProcedure = $projection.CostingSheet
{
@ObjectModel.readOnly: true
key ProjectUUID,
@ObjectModel.virtualElement
@ObjectModel.filter.transformedBy: 'CL_PPM_PRO_MASS_CHANGE_SADL_EX'
@ObjectModel: { readOnly: true }
@UI.hidden: true
hextobin( '00000000000000000000000000000000' ) as EntProjMassChangeRequestUUID,
@ObjectModel.readOnly: true
WBSElementInternalID,
@ObjectModel.readOnly: true
ProjectSummaryTaskUUID,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'C_EnterpriseProjectVH',
element: 'Project' }
}]
@ObjectModel: {
text: {
element: [ 'ProjectName' ]
}
}
Project,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'C_EnterpriseProjectVH',
element: 'Project' }
}]
ProjectName,
@Consumption.valueHelpDefinition: [
{ entity: { name: 'C_PPM_ProjectProfileVH',
element: 'ProjectProfileCode' }
}]
@ObjectModel: {
text: {
element: [ 'ProjectProfileCodeText' ]
}
}
ProjectProfileCode,
@Consumption.filter.hidden: true
@ObjectModel.readOnly: true
@EndUserText.label: 'Project Profile Code Text'
_ProjectProfileCode._Text[1: Language = $session.system_language].ProjectProfileCodeText as ProjectProfileCodeText,
/*@ObjectModel: {
foreignKey.association: '',
text.association: ''
}*/
@UI.hidden: true
ProjectManagerUUID,
@ObjectModel: {
readOnly: true,
text: {
association: [ '_ProcessingStatusText' ]
}
}
ProcessingStatus,
@Consumption.valueHelpDefinition: [{ entity :{
name : 'I_CostCenterStdVH',
element : 'CostCenter'
}}]
@ObjectModel: {
text: {
element: [ 'ResponsibleCostCenterName' ]
}
}
ResponsibleCostCenter,
@Consumption.filter.hidden: true
@EndUserText.label: 'Responsible Cost Center Name'
@ObjectModel.readOnly: true
_ResponsibleCostCenterText[1: Language = $session.system_language].CostCenterName as ResponsibleCostCenterName,
@ObjectModel: {
text: {
element: [ 'ProfitCenterName' ]
}
}
ProfitCenter,
_ProfitCenterText[1: Language = $session.system_language].ProfitCenterName,
@Consumption.valueHelpDefinition: [{ entity :{
name : 'C_ControllingAreaVH',
element : 'ControllingArea'
}}]
@ObjectModel: {
text: {
element: [ 'ControllingAreaName' ]
}
}
ControllingArea,
@Consumption.filter.hidden: true
@ObjectModel.readOnly: true
_ControllingArea.ControllingAreaName,
@Consumption.filter.hidden: true
@ObjectModel: {
text: {
element: [ 'CreatedByUserName' ]
},
foreignKey: {
association: '_CreatedByUser'
}
}
CreatedByUser,
@Consumption.filter.hidden: true
@Semantics.text: true
_CreatedByUser.FullName as CreatedByUserName,
@Consumption.filter.hidden: true
CreationDateTime,
@Consumption.filter.hidden: true
@EndUserText.label: 'Changed By'
LastChangedByUser,
@Consumption.filter.hidden: true
@EndUserText.label: 'Last Changed On'
cast(LastChangeDateTime as /s4ppm/tv_changed_on preserving type) as LastChangeDateTime,
@Consumption.valueHelpDefinition: [{ entity :{
name : 'I_PlantStdVH',
element : 'Plant'
}}]
@ObjectModel: {
text: {
element: [ 'PlantName' ]
}
}
Plant,
@Consumption.filter.hidden: true
@ObjectModel.readOnly: true
_Plant[1: Language = $session.system_language].PlantName,
//@Consumption.filter.hidden: true
ProjectStartDate as PlannedStartDate,
//@Consumption.filter.hidden: true
ProjectEndDate as PlannedEndDate,
//CE2011 ACTUAL DATES
//@Consumption.filter.hidden: true
@Consumption.filter: { selectionType: #INTERVAL, multipleSelections: false }
ActualStartDate,
//@Consumption.filter.hidden: true
@Consumption.filter: { selectionType: #INTERVAL, multipleSelections: false }
ActualEndDate,
//CE2011 ACTUAL DATES
@Consumption.filter.hidden: true
@ObjectModel.readOnly: true
_InvestmentProfileText[1: Language = $session.system_language].InvestmentProfileName,
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_InvestmentProfile', element: 'InvestmentProfile' } }]
@ObjectModel: {
foreignKey: {
association: '_InvestmentProfVH'
},
text: {
element: [ 'InvestmentProfileName' ]
}
}
InvestmentProfile,
@Consumption.filter.hidden: true
@ObjectModel: {
text: {
element: [ 'CompanyCodeName' ]
}
}
CompanyCode,
_CompanyCode[1: Language = $session.system_language].CompanyCodeName,
@Consumption.filter.hidden: true
@EndUserText.label: 'Default Cost Center for Postings'
CostCenter,
@Consumption.filter.hidden: true
@ObjectModel: {
text: {
element: [ 'CostingSheetProcedureDesc' ]
}
}
CostingSheet,
@Consumption.filter.hidden: true
@ObjectModel.readOnly: true
@EndUserText.label: 'Costing Sheet Procedure Description'
_CostingSheetProcedureText[1: Language = $session.system_language].CostingSheetProcedureDesc as CostingSheetProcedureDesc,
@Consumption.filter.hidden: true
@ObjectModel: {
text: {
element: [ 'FactoryCalendarName' ]
}
}
FactoryCalendar,
@Consumption.filter.hidden: true
@ObjectModel.readOnly: true
_FactoryCalendarText[1: Language = $session.system_language].FactoryCalendarName,
@Consumption.filter.hidden: true
@ObjectModel: {
text: {
element: [ 'FunctionalAreaName' ]
}
}
FunctionalArea,
@Consumption.filter.hidden: true
@ObjectModel.readOnly: true
_FunctionalArea._Text[1:Language = $session.system_language].FunctionalAreaName as FunctionalAreaName,
@Consumption.valueHelpDefinition: [{ entity : {name: 'C_EnterpriseProjectPriorityVH', element: 'PriorityCode' }}]
@ObjectModel.text.control: #('ASSOCIATED_TEXT_UI_HIDDEN')
PriorityCode,
//@Consumption.filter.hidden: true
IsBillingRelevant,
@ObjectModel: {
text: {
element: [ 'ProjectTypeName' ]
}
}
@Consumption.valueHelpDefinition: [{ entity : {name: 'I_Projecttype', element: 'ProjectType' } }]
@UI.textArrangement: #TEXT_ONLY
@EndUserText.label: 'Project Type'
EnterpriseProjectType,
@EndUserText.label: 'Project Type Description'
_EnterpriseProjectTypeText[1:Language = $session.system_language].ProjectTypeName as ProjectTypeName,
@EndUserText: {
label: 'Asset Under Construction ID'
}
@ObjectModel.readOnly: true
_FixedAsset.FixedAssetExternalID,
@Consumption.filter.hidden: true
_FactoryCalendarText,
@Consumption.filter.hidden: true
_ControllingArea,
@Consumption.filter.hidden: true
_CostingSheetProcedureText,
@Consumption.filter.hidden: true
_FunctionalArea,
@Consumption.filter.hidden: true
_Plant,
@Consumption.filter.hidden: true
_ProjectProfileCode,
@Consumption.filter.hidden: true
_EnterpriseProjectType,
@Consumption.filter.hidden: true
_ResponsibleCostCenterText,
@Consumption.filter.hidden: true
_ProjObjRoot,
@Consumption.filter.hidden: true
_ProcessingStatus,
@Consumption.filter.hidden: true
_ProcessingStatusText,
@Consumption.filter.hidden: true
_Manager,
@Consumption.filter.hidden: true
_CreatedByUser,
@Consumption.filter.hidden: true
_AuthUser,
@Consumption.filter.hidden: true
_AuthSubst,
@Consumption.filter.hidden: true
_AuthRole,
@Consumption.filter.hidden: true
_AuthGroup,
@Consumption.filter.hidden: true
_ProfitCenterText,
_TeamMember,
_Priority,
@Consumption.filter.hidden: true
_PriorityText,
@Consumption.filter.hidden: true
_InvestmentProfileText
}