C_EntProjProfnlSrvcTeamMbrVH

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Professional Service Project Members'
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
   semanticKey:       [ 'PersonFullName' ],
   representativeKey: 'BusinessPartner',
   usageType: {
     serviceQuality:  #C,
     dataClass:       #TRANSACTIONAL,
     sizeCategory:    #XL
   },
   dataCategory: #VALUE_HELP
}

@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@Consumption.ranked: true
@Metadata.allowExtensions: true

@Consumption.dbHints:[ 'USE_HEX_PLAN' ]

define view entity C_EntProjProfnlSrvcTeamMbrVH
  as select from           I_WorkforcePerson_1          as Worker
    inner join             I_BusinessPartner_to_BP_Role as BupaToBPRole      on BupaToBPRole.BusinessPartner       = Worker.BusinessPartner
                                                                             and(
                                                                               BupaToBPRole.BusinessPartnerRole    = 'BUP003' // Employee role

                                                                               or BupaToBPRole.BusinessPartnerRole = 'BBP005' // Contingent Worker

                                                                             )
    inner join             I_BusinessPartner            as BusinessPartner   on Worker.BusinessPartner = BusinessPartner.BusinessPartner

    left outer to one join I_WorkplaceAddress           as _WorkplaceAddress on BusinessPartner.BusinessPartnerUUID = _WorkplaceAddress.BusinessPartnerUUID
{
       @Search.defaultSearchElement: true
       @Search.ranking: #HIGH
       @Search.fuzzinessThreshold: 0.8
       @ObjectModel.text.element:  [ 'PersonFullName' ]
  key  Worker.BusinessPartner,
  key  BupaToBPRole.ValidTo,
       BupaToBPRole.ValidFrom,

       @Search.defaultSearchElement: true
       @Search.ranking: #LOW
       @Search.fuzzinessThreshold: 0.8
       @Semantics: { name: { fullName: true }, text: true }
       Worker.FullName                                                as PersonFullName,

       @Search.defaultSearchElement: true
       @Search.ranking: #LOW
       @Search.fuzzinessThreshold: 0.8
       Worker.FirstName,

       @Search.defaultSearchElement: true
       @Search.ranking: #LOW
       @Search.fuzzinessThreshold: 0.8
       Worker.LastName,

       cast (_WorkplaceAddress.Building as ad_bldng ) as Building,

       _WorkplaceAddress.RoomNumber,

       @Semantics: {telephone : { type: [ #WORK, #PREF ]}}
       _WorkplaceAddress.NormalizedPhoneNumber,

       @Semantics : {eMail.address: true}
       _WorkplaceAddress.DefaultEmailAddress,

       @Consumption.hidden: true
       Worker.AuthorizationGroup,

       @Consumption.hidden: true
       @Semantics.booleanIndicator
       Worker.IsBusinessPurposeCompleted,

       @Consumption.hidden: true
       Worker.DataControllerSet,

       @Consumption.hidden: true
       Worker.DataController1,

       @Consumption.hidden: true
       Worker.DataController2,

       @Consumption.hidden: true
       Worker.DataController3,

       @Consumption.hidden: true
       Worker.DataController4,

       @Consumption.hidden: true
       Worker.DataController5,

       @Consumption.hidden: true
       Worker.DataController6,

       @Consumption.hidden: true
       Worker.DataController7,

       @Consumption.hidden: true
       Worker.DataController8,

       @Consumption.hidden: true
       Worker.DataController9,

       @Consumption.hidden: true
       Worker.DataController10
}