C_EntProjDmndRsceAssignment

@AccessControl: {
    authorizationCheck:     #MANDATORY,
    personalData.blocking:  #REQUIRED
}
@VDM: {
    viewType: #CONSUMPTION
}

@ObjectModel: {

    usageType: {
      dataClass:       #TRANSACTIONAL,
      serviceQuality:  #C, 
      sizeCategory:    #L
    }


}
@EndUserText.label: 'Project Demand Resource Assignment Data'
@Metadata.allowExtensions: true
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]    

define view entity C_EntProjDmndRsceAssignment
  as select from           I_ProjDmndResourceAssignmentTP as AssignmentHdr
    inner join             R_ProjDmndRsceAssgmtDistrTP    as AssignmentDistr on  AssignmentDistr.ProjDmndRsceAssgmtUUID = AssignmentHdr.ProjDmndRsceAssgmtUUID
                                                                             and AssignmentDistr.ProjectUUID            = AssignmentHdr.ProjectUUID
                                                                             and AssignmentDistr.ProjectDemandUUID      = AssignmentHdr.ProjectDemandUUID

    left outer to one join R_WorkAssignmentKeyMap         as Worker          on Worker.WorkforceAssignment = AssignmentHdr.ProjDmndRsceAssgmt
    
    left outer to one join I_BusinessPartner              as Person          on Person.BusinessPartner = Worker.BusinessPartner

  association [1..1] to C_EntProjSrvcOrgCntctCard      as _SuppDeliveryOrganization     on _SuppDeliveryOrganization.EnterpriseProjectServiceOrg = $projection.ProjectDemandSupplyDeliveryOrg
  association [1..1] to I_EngagementProjectSrvcOrgText as _SuppDeliveryOrganizationText on $projection.ProjectDemandSupplyDeliveryOrg = _SuppDeliveryOrganizationText.EngagementProjectServiceOrg
  association [0..1] to C_EntProjMemberContactCard     as _WorkerContactCard            on _WorkerContactCard.BusinessPartnerUUID = $projection.BusinessPartnerUUID
  association [1..1] to I_EnterpriseProject            as _EnterpriseProject            on _EnterpriseProject.ProjectUUID = $projection.ProjectUUID
 {
  key AssignmentHdr.ProjectUUID                                                  as ProjectUUID,
  key AssignmentHdr.ProjectDemandUUID                                            as ProjectDemandUUID,
  key AssignmentHdr.ProjDmndRsceAssgmtUUID                                       as ProjDmndRsceAssgmtUUID,
  key AssignmentHdr.ProjDmndRsceAssgmt                                           as ProjDmndRsceAssgmt,

      @ObjectModel.text.element: [ 'PersonFullName' ]
      @ObjectModel.foreignKey.association: '_WorkerContactCard'
      Person.BusinessPartnerUUID                                                 as BusinessPartnerUUID,
      
      Worker.WorkforcePersonExternalID                                           as WorkforcePersonExternalID,

      //For DCL

      Worker.IsBlocked,
      Person.IsBusinessPurposeCompleted,
      
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy:'ABAP:CL_EPPM_PROJ_CTRL_PROFNL_SRVC'
      cast( '' as bu_name1tx )                                                   as PersonFullName,
      
      @ObjectModel:{
        text.association: '_SuppDeliveryOrganizationText',
        foreignKey.association: '_SuppDeliveryOrganization'
      }
      AssignmentHdr.ProjectDemandSupplyDeliveryOrg                               as ProjectDemandSupplyDeliveryOrg,
      AssignmentDistr.ProjDmndRsceAssgmtDistrQtyUnit                             as ProjDmndRsceAssgmtDistrQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'ProjDmndRsceAssgmtDistrQtyUnit'
      cast( sum(AssignmentDistr.ProjDmndRsceAssgmtDistrQty) as abap.quan(20,3) ) as ProjDmndStaffedEffortQty,
      AssignmentDistr.ProjDmndRsceDistrPerdAmtCur                                as ProjDmndRsceDistrPerdAmtCur,
      @Semantics.amount.currencyCode: 'ProjDmndRsceDistrPerdAmtCur'
      cast( sum(AssignmentDistr.ProjDmndRsceDistrPerdAmt)   as abap.curr(24,2) ) as PrjDmndStaffedEffortCostAmount,
      _WorkerContactCard,
      _SuppDeliveryOrganization,
      _EnterpriseProject,
      _SuppDeliveryOrganizationText
}

where
      AssignmentHdr.ProjDmndRsceAssgmt               is not initial
  and AssignmentDistr.ProjDmndRsceDistrIsNotSupplied is initial //Where Clause to fetch data for Supplied lines of a 0ACT Demand

group by
  AssignmentHdr.ProjDmndRsceAssgmtUUID,
  AssignmentHdr.ProjectUUID,
  AssignmentHdr.ProjectDemandUUID,
  AssignmentHdr.ReferencedObjectUUID,
  AssignmentHdr.ProjDmndRsceAssgmt,
  Person.BusinessPartnerUUID,
  Worker.WorkforcePersonExternalID,
  Worker.IsBlocked,
  Person.IsBusinessPurposeCompleted,
  AssignmentHdr.ProjectDemandSupplyDeliveryOrg,
  AssignmentDistr.ProjDmndRsceDistrPerdAmtCur,
  AssignmentDistr.ProjDmndRsceAssgmtDistrQtyUnit