C_EmailDunningEntryData

// data source for dunning email template FIN_FO_DUNN_NOTE_EMAIL

// see the email template in Maintain Email Template app (Administrator)


@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED /* FI_DUNNING_DESTRUCTION */

@EndUserText.label: 'Email Data For Dunning Entry'

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M

@VDM.viewType: #CONSUMPTION
define view entity C_EmailDunningEntryData
  as select from    I_DunningEntry    as Dunning
    left outer join I_AccountingClerk as _AccountingClerk on  Dunning.DunningClerk = _AccountingClerk.AccountingClerk
                                                          and Dunning.CompanyCode  = _AccountingClerk.CompanyCode
    inner join      I_UserContactCard as _UserData        on _UserData.ContactCardID = $session.user

{
  key Dunning.DunningRunDate                                                                 as DunningRunDate,
  key Dunning.DunningRun                                                                     as DunningRun,
  key Dunning.FinancialAccountType                                                           as FinancialAccountType,
  key Dunning.CompanyCode                                                                    as CompanyCode,
  key Dunning.Customer,
  key Dunning.Supplier,
  key Dunning.OneTimeAcctBankAccount,
  key Dunning.CustomerHeadOffice,
  key Dunning.GroupingDunningArea                                                            as GroupingDunningArea,
  key Dunning.GroupingDunningLevel,
  key Dunning.DunningClerk,

      cast (_AccountingClerk.UserID as farp_mydunnproposal_userid preserving type)           as UserID,
      Dunning._CompanyCode.CompanyCodeName                                                   as CompanyCodeName, //cannot be dimension nor measure

      _UserData.FirstName,
      _UserData.LastName,
      _UserData.FullName,
      Dunning._Customer.CustomerName                                                         as CustomerName, //cannot be dimension nor measure

      cast (Dunning.DunningProcedure as farp_mydunningproposal_mahna preserving type)        as DunningProcedure,
      Dunning.DunningLevel,
      @Semantics.amount.currencyCode: 'DunningCurrency'
      cast (Dunning.DueLineItemsTotalInDunCrcy as farp_mydunnproposal_faebt preserving type) as DueLineItemsTotalInDunCrcy,
      Dunning.DunningCurrency,
      Dunning.DunningNoticeIsToBeSent                                                        as PrintIsReal,

      Dunning._Customer
}