C_EHSTaskMonitoring

@AbapCatalog.sqlViewName: 'CEHSTASKMON'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType:{ serviceQuality: #D,        // < 100 msec

                         sizeCategory:  #XL,         // < 10.000.000

                         dataClass: #MIXED }
@AccessControl: {
  authorizationCheck: #MANDATORY
}

// #NOT_REQUIRED as a start

@AccessControl.personalData.blocking: #NOT_REQUIRED

@EndUserText.label: 'Monitor Tasks'

@Consumption.semanticObject: 'EHSTask'
@ObjectModel.semanticKey: [ 'EHSPlannedTaskID' ]
@ObjectModel.representativeKey: 'WorkflowTaskInternalID'
@Metadata.allowExtensions: true



define view C_EHSTaskMonitoring
  as select from C_EHSCombinedTaskDefAndInstce as CombinedTaskDefAndInstce
  association [0..*] to I_EHSSemanticObjectText  as _SemanticObjectText on $projection.EHSTaskHostSemanticObject = _SemanticObjectText.EHSSemanticObject
  association [1..1] to E_EHSTaskDefinition      as _Extension          on $projection.EHSTaskDefinitionUUID = _Extension.EHSTaskDefinitionUUID
  association [1..1] to E_EHSTaskPlannedInstance as _ExtensionInstance  on $projection.EHSPlannedTaskUUID = _ExtensionInstance.EHSPlannedTaskUUID
  association [0..1] to I_CalendarDate           as _CalendarDate       on  $projection.EHSTaskDueDate = _CalendarDate.CalendarDate
{
  key EHSTaskDefinitionUUID,
  key WorkflowTaskInternalID,
  key EHSPlannedTaskUUID,

      // Task Type:

      @Consumption.valueHelpDefinition: [{ entity: {
        name: 'C_EHSTaskDefinitionTypeVH',
        element: 'EHSTaskDefinitionType'
      } }]
      @ObjectModel.text.element: [ 'EHSTaskDefinitionTypeName' ]
      EHSTaskDefinitionType,

      @Consumption.filter.hidden: true
      @Semantics.text: true
      cast( _EHSTaskDefinitionTypeText[1: Language = $session.system_language].EHSTaskDefinitionTypeName as ehfnd_task_type_descr preserving type ) as EHSTaskDefinitionTypeName,

      // Task Title:

      EHSTaskTitle,

      cast(EHSPlannedTaskID as ehfnd_task_planned_id)                                                                                               as EHSPlannedTaskID,

      // Task Status:

      @ObjectModel.sort.enabled: true
      EHSTaskStatusValueForSorting,
      @ObjectModel.sort.enabled: true
      @ObjectModel.filter.enabled: false
      @Consumption.filter.hidden: true
      EHSTaskStatusName,
      EHSTaskDefinitionIsPaused,
      EHSTaskDefinitionStatus,
      WorkflowTaskStatus,
      WrkflwTskCompletionUTCDateTime,
      @Consumption.valueHelpDefinition: [{ entity: {
        name: 'I_Indicator',
        element: 'IndicatorValue'
      } }]
      EHSTaskHasWorkflow,

      // Task Due Date:

      EHSTaskDueDate,

      // Task Start Date:

      EHSTaskStartDate,
      @ObjectModel.text.element: [ 'CalendarMonthName' ]
      @UI.textArrangement: #TEXT_ONLY
      _CalendarDate.CalendarMonth as EHSTaskMonth,  
      @UI.hidden: true
      _CalendarDate._CalendarMonth._Text[ 1: Language = $session.system_language ].CalendarMonthName,
      
      _CalendarDate.CalendarYear as EHSTaskYear,

      // Task Completion Date:

      EHSTaskInstceCompletionDate,

      // Task Recurrence:

      EHSTaskIsRecurrent,

      // Task Priority:

      @ObjectModel.text.element: ['EHSTaskPriorityName']
      EHSTaskPriority,

      @Semantics.text:true
      cast( EHSTaskPriorityName as ehfnd_task_def_priority_name preserving type )                                                                   as EHSTaskPriorityName,

      EHSTaskStatusCriticality,

      @Consumption.valueHelpDefinition: [{ entity: {
        name: 'C_EHSTaskSemanticObjValueHelp',
        element: 'EHSSemanticObject'
      } }]
      @ObjectModel.text.association: '_SemanticObjectText'
      EHSTaskHostSemanticObject,

      EHSTaskHostObjectInstance,

      @UI.hidden: true
      EHSTaskHostObjectInstanceUUID,

      @ObjectModel.foreignKey.association: '_BusinessPartner'
      @Consumption.valueHelpDefinition: [{
      entity: {
        name: 'C_EHSTaskUserValueHelp',
        element: 'BusinessPartner'
      } }]
      @ObjectModel.text.element: ['EHSTaskUserName']
      EHSTaskUser,

      @Semantics.text:true
      EHSTaskUserName,

      // Task Current Processor:

      @ObjectModel.foreignKey.association: '_EHSTaskInstanceProcessorUser'
      @Consumption.valueHelpDefinition: [{
          entity: {
          name: 'C_EHSTaskProcessorValueHelp',
          element: 'BusinessPartner'
          } }]
      @ObjectModel.text.element: ['EHSTaskInstanceProcessorName']
      EHSTaskInstanceProcessorBP,

      EHSTaskInstanceProcessorUser,

      @Semantics.text:true
      @Consumption.filter.hidden: true
      EHSTaskInstanceProcessorName,

      // Task Owner:

      EHSTaskOwnerUser,

      @ObjectModel.foreignKey.association: '_EHSTaskOwnerUser'
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_EHSTaskOwnerValueHelp',
          element: 'BusinessPartner'
        } }]
      @ObjectModel.text.element: ['EHSTaskOwnerUserName']
      EHSTaskOwnerBP,
      
      @Consumption.filter.hidden: true
      @Semantics.text: true
      EHSTaskOwnerUserName,

      _EHSTaskAssigneeUser.UserID                                                                                                                   as EHSTaskAssignedUser,

      @ObjectModel.foreignKey.association: '_EHSTaskAssigneeUser'
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_EHSTaskAssignedUserVH',
          element: 'BusinessPartner'
        } }]
      @ObjectModel.text.element: ['EHSTaskAssignedUserName']
      EHSTaskAssignedBP,

      @Semantics.text:true
      @Consumption.filter.hidden: true
      EHSTaskAssignedUserName,

      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_EHSLocationPersnRespRoleVH',
          element: 'EHSLocationPersonRespRole'
        } }]
      @ObjectModel.text.element: ['EHSTaskAssignedLocRoleName']
      EHSTaskAssignedLocRole,

      EHSTaskAssignedLocRoleName,

      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_EHSTaskApprovingUserVH',
          element: 'BusinessPartner'
        } }]
      @ObjectModel.text.element: ['EHSTaskApprovingUserName']
      EHSTaskApprovingBP,

      @Semantics.text:true
      @Consumption.filter.hidden: true
      EHSTaskApprovingUserName,

      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'C_EHSLocationPersnRespRoleVH',
          element: 'EHSLocationPersonRespRole'
        } }]
      @ObjectModel.text.element: ['EHSTaskApproverLocRoleName']
      EHSTaskApproverLocRole,

      EHSTaskApproverLocRoleName,

      EHSTaskDefinitionManageAction,
      EHSTaskInstanceDisplayAction,

      // Task Date - for sorting:

      EHSTaskDateForSorting,

      EHSTaskHostObjectAdapterClass,

      @ObjectModel: {
               readOnly: true,
               virtualElement: true,
               virtualElementCalculatedBy: 'ABAP:CL_EHFND_TASK_MON_EXIT'
      }
      cast('' as text240)                                                                                                                           as EHSTskRelatedObjectDescription,

      @ObjectModel: {
               readOnly: true,
               virtualElement: true,
               virtualElementCalculatedBy: 'ABAP:CL_EHFND_TASK_MON_EXIT'
      }
      cast('' as text1024)                                                                                                                          as EHSTaskRelatedObjectURL,

      @ObjectModel.text.element: ['EHSLocationIDAndName']
      @ObjectModel.sort.enabled: false
      EHSLocationUUID,
      EHSLocationName,
      EHSLocationID,
      @Consumption.filter.hidden: true
      EHSLocationIDAndName,
      EHSTaskTimeZone,

      @UI.textArrangement: #TEXT_ONLY
      @UI.hidden: true
      IsDraftEntity,

      // Draft Administrative Data

      @UI.hidden: true
      DraftEntityLastChangeDateTime,
      @UI.hidden: true
      @UI.textArrangement: #TEXT_ONLY
      DraftIsLastChangedByMe,
      @UI.hidden: true
      LastChangedByUserDescription,
      @UI.hidden: true
      DraftIsProcessedByMe,
      @UI.hidden: true
      InProcessByUserDescription,
      @UI.hidden: true
      InProcessByUser,

      @UI.hidden: true
      @Semantics.booleanIndicator: true
      HasActiveEntity,

      @UI.hidden: true
      DraftUUID,

      // associations exposure:

      @Consumption.hidden: true
      _SemanticObjectText,
      @Consumption.hidden: true
      _EHSTaskDefinition,
      _EHSTaskDefinitionTypeText,
      _TernaryLogicalStateText,
      _EHSTaskOwnerUser,
      _EHSTaskAssigneeUser,
      _EHSTaskApprovingUser,
      _EHSTaskSortingStatus,
      _EHSTaskPriority,
      _EHSTaskInstanceProcessorUser,
      _BusinessPartner,

      // Associations for Authorization Check of Host BO

      _EHSTaskAdapterClass,
      _IncidentAuthorizationFields,
      _EHSCtrlImplmtnAuthznFields,
      _EHSRskAssessmentAuthznFields,
      _EHSRskAssmt2RskCtrlAuthznFld,
      _EHSCmplncScenAuthznFields,
      _CmplncRqmtAuthznFields,
      IncidentHasAccessRestriction
}