C_EHSSamplingHeaderDEX

DDL: C_EHSSAMPLINGHEADERDEX Type: view_entity CONSUMPTION Package: EHENV_CNS_EMISSION_INVENTORY

EHS Sampling Definition Header

C_EHSSamplingHeaderDEX is a Consumption CDS View (Dimension) that provides data about "EHS Sampling Definition Header" in SAP S/4HANA. It reads from 1 data source (I_SamplingHeader) and exposes 12 fields with key field SamplingHeaderUUID. It has 1 association to related views. Part of development package EHENV_CNS_EMISSION_INVENTORY.

1 data source(s) 12 fields

Data Sources (1)

SourceAliasJoin Type
I_SamplingHeader SamplingHeader from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_EHSLocationRevisionBasic _EHSLocationRevisionBasic $projection.EHSLocationUUID = _EHSLocationRevisionBasic.EHSLocationUUID

Annotations (12)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label EHS Sampling Definition Header view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.sapObjectNodeType.name EHSSamplingDefinitionHeader view
VDM.viewType #CONSUMPTION view
Analytics.dataCategory #DIMENSION view
Analytics.internalName #LOCAL view
Analytics.dataExtraction.enabled true view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY SamplingHeaderUUID I_SamplingHeader SamplingHeaderUUID Sampling Header Key
SamplingDefinitionUUID SamplingDefinitionRoot SamplingDefinitionUUID Sampling Definition Key
EHSSamplingHeaderID I_SamplingHeader EHSSamplingHeaderID Sampling Definition Header ID
EHSSamplingHeaderTitle I_SamplingHeader SamplingHeaderTitle Sampling Definition Title
SamplingDefinitionName SamplingDefinitionRoot SamplingDefinitionName Sampling Definition Name
EHSLocationUUID SamplingDefinitionRoot EHSLocationUUID Location Key
SamplingAnalyteType I_SamplingHeader SamplingAnalyteType
SamplingAnalyteUUID Subject Identifier
EHSSubjectType SamplingDefinitionRoot EHSSubjectType
EHSSubjectUUID SamplingDefinitionRoot EHSSubjectUUID Subject Key
SamplingDefMigrationSource SamplingDefinitionRoot SamplingDefMigrationSource Migration Source
_EHSLocationRevisionBasic _EHSLocationRevisionBasic 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'EHS Sampling Definition Header'
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MIXED
}
@ObjectModel.supportedCapabilities: [ #EXTRACTION_DATA_SOURCE ]
@ObjectModel.sapObjectNodeType.name: 'EHSSamplingDefinitionHeader'
@VDM.viewType: #CONSUMPTION
@Analytics: {
  dataCategory: #DIMENSION,
  internalName: #LOCAL,
  dataExtraction: {
    enabled: true,
    delta.changeDataCapture: {
      mapping: [{
        table: 'ehenvd_sdef_head',
        role: #MAIN,
        viewElement: ['SamplingHeaderUUID'],
        tableElement: ['db_key']
      }, {
        table: 'ehenvd_sdef_root',
        role: #LEFT_OUTER_TO_ONE_JOIN,
        viewElement: ['SamplingDefinitionUUID'],
        tableElement: ['db_key']
      }]
    }
  }
}
define view entity C_EHSSamplingHeaderDEX
  as select from           I_SamplingHeader         as SamplingHeader
    left outer to one join I_SamplingDefinitionRoot as SamplingDefinitionRoot on SamplingHeader.SamplingDefinitionUUID = SamplingDefinitionRoot.SamplingDefinitionUUID
  association [0..*] to I_EHSLocationRevisionBasic as _EHSLocationRevisionBasic on $projection.EHSLocationUUID = _EHSLocationRevisionBasic.EHSLocationUUID
{
      @EndUserText.label: 'Sampling Header Key'
  key SamplingHeader.SamplingHeaderUUID,
      @EndUserText.label: 'Sampling Definition Key'
      SamplingDefinitionRoot.SamplingDefinitionUUID,
      @EndUserText.label: 'Sampling Definition Header ID'
      SamplingHeader.EHSSamplingHeaderID,
      @EndUserText.label: 'Sampling Definition Title'
      SamplingHeader.SamplingHeaderTitle                                                             as EHSSamplingHeaderTitle,
      @EndUserText.label: 'Sampling Definition Name'
      SamplingDefinitionRoot.SamplingDefinitionName,
      @EndUserText.label: 'Location Key'
      SamplingDefinitionRoot.EHSLocationUUID,
      SamplingHeader.SamplingAnalyteType,
      @EndUserText.label: 'Subject Identifier'
      cast( SamplingHeader.SamplingAnalyteUUID as ehfnd_sbj_key_ref preserving type )                as SamplingAnalyteUUID,
      SamplingDefinitionRoot.EHSSubjectType,
      @EndUserText.label: 'Subject Key'
      SamplingDefinitionRoot.EHSSubjectUUID,
      @EndUserText.label: 'Migration Source'
      SamplingDefinitionRoot.SamplingDefMigrationSource,

      // Required for DCL

      _EHSLocationRevisionBasic
}

Learn More