C_EHSLocationClassifierDEX

DDL: C_EHSLOCATIONCLASSIFIERDEX Type: view_entity CONSUMPTION Package: EHFND_CNS_LOCATION

EHS Location Classifier

C_EHSLocationClassifierDEX is a Consumption CDS View (Dimension) that provides data about "EHS Location Classifier" in SAP S/4HANA. It reads from 1 data source (I_EHSLocClassifier) and exposes 7 fields with key field EHSLocClassifierUUID. It has 1 association to related views. Part of development package EHFND_CNS_LOCATION.

1 data source(s) 7 fields

Data Sources (1)

SourceAliasJoin Type
I_EHSLocClassifier EHSLocClassifier from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_EHSLocationRevisionBasic _EHSLocationRevisionBasic $projection.EHSLocationUUID = _EHSLocationRevisionBasic.EHSLocationUUID

Annotations (13)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label EHS Location Classifier view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.modelingPattern #NONE view
ObjectModel.sapObjectNodeType.name EHSLocationClassifier view
VDM.viewType #CONSUMPTION view
Analytics.dataCategory #DIMENSION view
Analytics.internalName #LOCAL view
Analytics.dataExtraction.enabled true view
Metadata.allowExtensions true view

Fields (7)

KeyFieldSource TableSource FieldDescription
KEY EHSLocClassifierUUID I_EHSLocClassifier EHSLocClassifierUUID Location Classifier Key
EHSLocationID EHSLocationRoot EHSLocationID
EHSLocClassifierID EHSClassifierRoot EHSLocClassifierID Location Classifier Identifier
EHSLocClassifierCentralID EHSClassifierRoot EHSLocClassifierCentralID Location Classifier Character Key
EHSLocationUUID EHSLocationRoot EHSLocationUUID Location Key
LocationMigrationSource EHSLocationRoot LocationMigrationSource Migration Source
_EHSLocationRevisionBasic _EHSLocationRevisionBasic 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'EHS Location Classifier'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MIXED
}
@ObjectModel: { modelingPattern: #NONE,
                supportedCapabilities: [ #EXTRACTION_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION ] }
@ObjectModel.sapObjectNodeType.name: 'EHSLocationClassifier'
@VDM.viewType: #CONSUMPTION
@Analytics: {
  dataCategory: #DIMENSION,
  internalName: #LOCAL,
  dataExtraction: {
    enabled: true,
    delta.changeDataCapture: {
      mapping: [{
        table: 'ehfndd_loc_clsf',
        role: #MAIN,
        viewElement: ['EHSLocClassifierUUID'],
        tableElement: ['db_key']
      }, {
        table: 'ehfndd_clsf_rt',
        role: #LEFT_OUTER_TO_ONE_JOIN,
        viewElement: ['EHSLocClassifierID', 'EHSLocClassifierCentralID'],
        tableElement: ['bco_id', 'bco_key']
      }, {
        table: 'ehfndd_loc_root',
        role: #LEFT_OUTER_TO_ONE_JOIN,
        viewElement: ['EHSLocationUUID'],
        tableElement: ['db_key']
      }]
    }
  }
}
@Metadata.allowExtensions: true
define view entity C_EHSLocationClassifierDEX
  as select from           I_EHSLocClassifier  as EHSLocClassifier
    left outer to one join I_EHSClassifierRoot as EHSClassifierRoot on EHSLocClassifier.EHSLocClassifierRefUUID = EHSClassifierRoot.EHSClassifierUUID
    left outer to one join I_EHSLocationRoot   as EHSLocationRoot   on EHSLocClassifier.EHSLocationUUID = EHSLocationRoot.EHSLocationUUID
  association [0..*] to I_EHSLocationRevisionBasic as _EHSLocationRevisionBasic on $projection.EHSLocationUUID = _EHSLocationRevisionBasic.EHSLocationUUID
{
      @EndUserText.label: 'Location Classifier Key'
  key EHSLocClassifier.EHSLocClassifierUUID,
      EHSLocationRoot.EHSLocationID,
      @EndUserText.label: 'Location Classifier Identifier'
      EHSClassifierRoot.EHSLocClassifierID,
      @EndUserText.label: 'Location Classifier Character Key'
      EHSClassifierRoot.EHSLocClassifierCentralID,
      @EndUserText.label: 'Location Key'
      EHSLocationRoot.EHSLocationUUID,
      @EndUserText.label: 'Migration Source'
      EHSLocationRoot.LocationMigrationSource,

      // Needed for DCL

      _EHSLocationRevisionBasic
}

Learn More