C_EHSBusinessPartnerAddressVH

DDL: C_EHSBUSINESSPARTNERADDRESSVH SQL: CEHSBPADDRVH Type: view CONSUMPTION Package: EHENV_CNS_CMPLRQ_PERMIT

CmplRq Permit Issuing Authority

C_EHSBusinessPartnerAddressVH is a Consumption CDS View that provides data about "CmplRq Permit Issuing Authority" in SAP S/4HANA. It reads from 1 data source (I_BusinessPartner) and exposes 25 fields with key fields BusinessPartner, AddressNumber. It has 1 association to related views. Part of development package EHENV_CNS_CMPLRQ_PERMIT.

1 data source(s) 25 fields

Data Sources (1)

SourceAliasJoin Type
I_BusinessPartner I_BusinessPartner from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_BusinessPartnerAddress _BusinessPartnerAddress $projection.BusinessPartner = _BusinessPartnerAddress.BusinessPartner

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName CEHSBPADDRVH view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #REQUIRED view
EndUserText.label CmplRq Permit Issuing Authority view
ClientHandling.algorithm #SESSION_VARIABLE view
VDM.viewType #CONSUMPTION view
ObjectModel.representativeKey BusinessPartner view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.dataCategory #VALUE_HELP view
Search.searchable true view

Fields (25)

KeyFieldSource TableSource FieldDescription
KEY BusinessPartner BusinessPartner
BusinessPartnerRoleasBusinessPartnerRole
KEY AddressNumber _BusinessPartnerAddress AddressNumber
BusinessPartnerName BusinessPartnerName
AuthorizationGroup _BusinessPartnerRole AuthorizationGroup
HouseNumber _BusinessPartnerAddress HouseNumber House Number
StreetName _BusinessPartnerAddress StreetName Street
CityName _BusinessPartnerAddress CityName City
Country _BusinessPartnerAddress Country Country/Region
Region _BusinessPartnerAddress Region
PostalCode _BusinessPartnerAddress PostalCode Postal Code
PostalCode11endasCompleteAddress Address
IsBusinessPurposeCompleted IsBusinessPurposeCompleted
DataControllerSet DataControllerSet
DataController1 DataController1
DataController2 DataController2
DataController3 DataController3
DataController4 DataController4
DataController5 DataController5
DataController6 DataController6
DataController7 DataController7
DataController8 DataController8
DataController9 DataController9
DataController10 DataController10
_BusinessPartnerAddress _BusinessPartnerAddress 
@AbapCatalog.sqlViewName: 'CEHSBPADDRVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'CmplRq Permit Issuing Authority'

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION

@ObjectModel: { semanticKey: [ 'BusinessPartner' ],
                representativeKey: 'BusinessPartner',
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #XL,
                usageType.dataClass: #MASTER,
                dataCategory: #VALUE_HELP
                }

@Search.searchable: true
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view C_EHSBusinessPartnerAddressVH
  as select from I_BusinessPartner
  association [0..*] to I_BusinessPartnerAddress as _BusinessPartnerAddress on $projection.BusinessPartner = _BusinessPartnerAddress.BusinessPartner
{
            @Search.defaultSearchElement: true
            @Search.fuzzinessThreshold: 0.7
            @Search.ranking: #HIGH
  key       BusinessPartner,

            --Issuing Authority search help (BUPA) is defaulted to BP role AUT001
            @Consumption.filter.defaultValue: 'AUT001'
  key       _BusinessPartnerRole.BusinessPartnerRole as BusinessPartnerRole,

  key       _BusinessPartnerAddress.AddressNumber    as AddressNumber,

            @ObjectModel.text.element: [ 'BusinessPartnerName' ]
            BusinessPartnerName,

            _BusinessPartnerRole.AuthorizationGroup  as AuthorizationGroup,
            @EndUserText.label: 'House Number'
            @Search.defaultSearchElement: true
            @Search.fuzzinessThreshold: 0.7
            @Search.ranking: #HIGH
            _BusinessPartnerAddress.HouseNumber,

            @EndUserText.label: 'Street'
            @Search.defaultSearchElement: true
            @Search.fuzzinessThreshold: 0.7
            @Search.ranking: #HIGH
            _BusinessPartnerAddress.StreetName,

            @EndUserText.label: 'City'
            @Search.defaultSearchElement: true
            @Search.fuzzinessThreshold: 0.7
            @Search.ranking: #HIGH
            _BusinessPartnerAddress.CityName,

            @EndUserText.label: 'Country/Region'
            @Search.defaultSearchElement: true
            @Search.fuzzinessThreshold: 0.7
            @Search.ranking: #HIGH
            _BusinessPartnerAddress.Country          as Country,

            _BusinessPartnerAddress.Region           as Region,

            @EndUserText.label: 'Postal Code'
            @Search.defaultSearchElement: true
            @Search.fuzzinessThreshold: 0.7
            @Search.ranking: #HIGH
            _BusinessPartnerAddress.PostalCode,


            @Consumption.filter.hidden: true
            @EndUserText.label: 'Address'
            case
              when _BusinessPartnerAddress.HouseNumber = '' and _BusinessPartnerAddress.StreetName = '' and _BusinessPartnerAddress.CityName = ''
                then concat_with_space(_BusinessPartnerAddress.Country,_BusinessPartnerAddress.PostalCode,1)
              when _BusinessPartnerAddress.HouseNumber = '' and _BusinessPartnerAddress.StreetName = ''
                then concat_with_space(concat(_BusinessPartnerAddress.CityName, ','), concat_with_space(_BusinessPartnerAddress.Country,_BusinessPartnerAddress.PostalCode,1), 1)
              else
                concat_with_space(concat(concat_with_space(concat_with_space(concat_with_space(_BusinessPartnerAddress.HouseNumber,_BusinessPartnerAddress.StreetName,1),',',1),_BusinessPartnerAddress.CityName,1),','),concat_with_space(_BusinessPartnerAddress.Country,_BusinessPartnerAddress.PostalCode,1),1)
            end                                      as CompleteAddress,

            // Needed for authorization check           

            @Consumption.hidden: true
            IsBusinessPurposeCompleted,

            @Consumption.hidden: true
            DataControllerSet,

            @Consumption.hidden: true
            DataController1,

            @Consumption.hidden: true
            DataController2,

            @Consumption.hidden: true
            DataController3,

            @Consumption.hidden: true
            DataController4,

            @Consumption.hidden: true
            DataController5,

            @Consumption.hidden: true
            DataController6,

            @Consumption.hidden: true
            DataController7,

            @Consumption.hidden: true
            DataController8,

            @Consumption.hidden: true
            DataController9,

            @Consumption.hidden: true
            DataController10,

            _BusinessPartnerAddress

}

Learn More