C_EDCValidation

DDL: C_EDCVALIDATION Type: view_entity CONSUMPTION Package: APPL_GLO_EDC_ODATA

EDC Consistency Validation

C_EDCValidation is a Consumption CDS View that provides data about "EDC Consistency Validation" in SAP S/4HANA. It reads from 1 data source (I_EDCValidation) and exposes 22 fields with key fields EDCRecordUUID, EDCValidationType, EDCCheckID. It has 3 associations to related views. It is exposed through 2 OData services (EDC_CHECK, EDC_PROCESS). Part of development package APPL_GLO_EDC_ODATA.

1 data source(s) Exposed by 2 service(s) 22 fields

Data Sources (1)

SourceAliasJoin Type
I_EDCValidation I_EDCValidation from

Associations (3)

CardinalityTargetAliasCondition
[0..1] R_EDCValidationTypeText _EDCValidationTypeText $projection.EDCType = _EDCValidationTypeText.EDCType and $projection.EDCValidationType = _EDCValidationTypeText.EDCValidationType and _EDCValidationTypeText.Language = $session.system_language
[0..1] R_EDCCheckIDText _EDCCheckTypeText $projection.EDCCheckID = _EDCCheckTypeText.EDCCheckID and _EDCCheckTypeText.Language = $session.system_language
[1..1] R_EDCCheckIDPosition _EDCCheckIDPosition $projection.EDCCheckID = _EDCCheckIDPosition.EDCCheckID and _EDCCheckIDPosition.EDCType = $projection.EDCType and _EDCCheckIDPosition.EDCValidationType = $projection.EDCValidationType

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label EDC Consistency Validation view
VDM.viewType #CONSUMPTION view
ObjectModel.usageType.serviceQuality #X view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MIXED view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view

OData Services (2)

ServiceBindingVersionContractRelease
EDC_CHECK UI_EDC_CHECK_O2 V2 C1 NOT_RELEASED
EDC_PROCESS UI_EDC_PROCESS_O2 V2 C1 NOT_RELEASED

Fields (22)

KeyFieldSource TableSource FieldDescription
KEY EDCRecordUUID I_EDCValidation EDCRecordUUID
KEY EDCValidationType I_EDCValidation EDCValidationType
KEY EDCCheckID _EDCValidationCheck EDCCheckID
EDCValidationSqncNmbr I_EDCValidation EDCValidationSqncNmbr
EDCType I_EDCValidation EDCType
EDCValidationStatus I_EDCValidation EDCValidationStatus
EDCCheckStatus
EDCSqncNmbr I_EDCValidation EDCSqncNmbr
EDCCreatedByUser I_EDCValidation EDCCreatedByUser
EDCCreatedOnDateTime I_EDCValidation EDCCreatedOnDateTime
EDCChangedByUser I_EDCValidation EDCChangedByUser
EDCChangedOnDateTime I_EDCValidation EDCChangedOnDateTime
EDCOrganizationalUnit I_EDCValidation EDCOrganizationalUnit
EDCOrganizationalUnitValue I_EDCValidation EDCOrganizationalUnitValue
EDCCheckPositionNumber _EDCCheckIDPosition EDCCheckPositionNumber
EDCCheckExecutionSequence _EDCCheckIDPosition EDCCheckExecutionSequence
EDCCompany _EDCDocumentList EDCCompany
EDCValidationTypeText _EDCValidationTypeText EDCValidationTypeText
EDCCheckIDText _EDCCheckTypeText EDCCheckIDText
EDCNumberOfInProcessResults
EDCNumberOfAllResults
EDCCheckRelevanceReasonText 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'EDC Consistency Validation'
@VDM.viewType:#CONSUMPTION
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
define view entity C_EDCValidation
  as select from           I_EDCValidation
    left outer to one join C_EDCDocumentList    as _EDCDocumentList    on I_EDCValidation.EDCRecordUUID = _EDCDocumentList.EDCRecordUUID
    left outer to one join R_EDCValidationCheck as _EDCValidationCheck on  _EDCValidationCheck.EDCValidationType = I_EDCValidation.EDCValidationType
                                                                       and _EDCValidationCheck.EDCCompany        = _EDCDocumentList.EDCCompany
                                                                       and _EDCValidationCheck.EDCType           = I_EDCValidation.EDCType


  association [0..1] to R_EDCValidationTypeText as _EDCValidationTypeText on  $projection.EDCType   = _EDCValidationTypeText.EDCType
                                                                          and $projection.EDCValidationType   = _EDCValidationTypeText.EDCValidationType
                                                                          and _EDCValidationTypeText.Language = $session.system_language
  association [0..1] to R_EDCCheckIDText        as _EDCCheckTypeText      on  $projection.EDCCheckID     = _EDCCheckTypeText.EDCCheckID
                                                                          and _EDCCheckTypeText.Language = $session.system_language
  association [1..1] to R_EDCCheckIDPosition    as _EDCCheckIDPosition    on  $projection.EDCCheckID                = _EDCCheckIDPosition.EDCCheckID
                                                                          and _EDCCheckIDPosition.EDCType           = $projection.EDCType
                                                                          and _EDCCheckIDPosition.EDCValidationType = $projection.EDCValidationType
  //  association [1..1] to edccontypet    as _EDCTypeText           on  $projection.EDCType = _EDCTypeText.contype

  //                                                                 and _EDCTypeText.spras  = $session.system_language

{
         @UI.hidden: true
  key    I_EDCValidation.EDCRecordUUID,
         @ObjectModel.text.element: ['EDCValidationTypeText']
         @UI.textArrangement: #TEXT_ONLY
  key    I_EDCValidation.EDCValidationType,
         @ObjectModel.text.element: ['EDCCheckIDText']
         @UI.textArrangement: #TEXT_ONLY
  key    _EDCValidationCheck.EDCCheckID,
         @UI.hidden: true
         I_EDCValidation.EDCValidationSqncNmbr,
         @UI.hidden: true
         I_EDCValidation.EDCType,
         @UI.hidden: true
         I_EDCValidation.EDCValidationStatus,
         @UI.hidden: true
         substring(I_EDCValidation.EDCValidationStatus, cast(_EDCCheckIDPosition.EDCCheckPositionNumber as abap.int1), 1) as EDCCheckStatus,
         @UI.hidden: true
         I_EDCValidation.EDCSqncNmbr,
         I_EDCValidation.EDCCreatedByUser,
         I_EDCValidation.EDCCreatedOnDateTime,
         I_EDCValidation.EDCChangedByUser,
         I_EDCValidation.EDCChangedOnDateTime,
         I_EDCValidation.EDCOrganizationalUnit,
         I_EDCValidation.EDCOrganizationalUnitValue,
         @UI.hidden: true
         _EDCCheckIDPosition.EDCCheckPositionNumber,
         @UI.hidden: true
         _EDCCheckIDPosition.EDCCheckExecutionSequence,

         @UI.hidden: true
         _EDCDocumentList.EDCCompany,
         @UI.hidden: true
         _EDCValidationTypeText.EDCValidationTypeText,
         @UI.hidden: true
         _EDCCheckTypeText.EDCCheckIDText,

         @UI.hidden: true
         @ObjectModel.readOnly: true
         @ObjectModel.virtualElement
         @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VRTL_ELMNT_C_EDCVALIDATION'
         cast(0 as  abap.int8 ) as EDCNumberOfInProcessResults,

         @UI.hidden: true
         @ObjectModel.readOnly: true
         @ObjectModel.virtualElement
         @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VRTL_ELMNT_C_EDCVALIDATION'
         cast(0 as  abap.int8 ) as EDCNumberOfAllResults,
//         

//         @UI.hidden: true

//         @ObjectModel.readOnly: true

//         @ObjectModel.virtualElement

//         @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VRTL_ELMNT_C_EDCVALIDATION'         

//         cast(' ' as abap.char(1)) as EDCCheckRelevance,


         @UI.hidden: true
         @ObjectModel.readOnly: true
         @ObjectModel.virtualElement
         @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_VRTL_ELMNT_C_EDCVALIDATION'          
         cast(' ' as abap.char(120)) as EDCCheckRelevanceReasonText
}

Learn More