C_DspDocFlwSolutionOrderVH

DDL: C_DSPDOCFLWSOLUTIONORDERVH Type: view_entity CONSUMPTION Package: ODATA_GL_DSP_DOC_FLW

Solution Order

C_DspDocFlwSolutionOrderVH is a Consumption CDS View that provides data about "Solution Order" in SAP S/4HANA. It reads from 1 data source (I_ServiceDocument) and exposes 22 fields with key fields BusinessSolutionOrder, ServiceDocumentType. Part of development package ODATA_GL_DSP_DOC_FLW.

1 data source(s) 22 fields

Data Sources (1)

SourceAliasJoin Type
I_ServiceDocument SolutionOrder from

Annotations (11)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey BusinessSolutionOrder view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #CONSUMPTION view
EndUserText.label Solution Order view
Search.searchable true view
Consumption.ranked true view

Fields (22)

KeyFieldSource TableSource FieldDescription
KEY BusinessSolutionOrder I_ServiceDocument ServiceDocument
KEY ServiceDocumentType I_ServiceDocument ServiceDocumentType
ServiceDocumentTypeName
SalesOrganization I_ServiceDocument SalesOrganization
DistributionChannel I_ServiceDocument DistributionChannel
Division I_ServiceDocument Division
SalesOffice I_ServiceDocument SalesOffice
SalesGroup I_ServiceDocument SalesGroup
SalesOrganizationOrgUnitID I_ServiceDocument SalesOrganizationOrgUnitID
SalesOfficeOrgUnitID I_ServiceDocument SalesOfficeOrgUnitID
SalesGroupOrgUnitID I_ServiceDocument SalesGroupOrgUnitID
AnchorDocument
ReferenceDocumentType
_ServiceDocument _ServiceDocument
_SalesOrganization I_ServiceDocument _SalesOrganization
_DistributionChannel I_ServiceDocument _DistributionChannel
_Division I_ServiceDocument _Division
_SalesOffice I_ServiceDocument _SalesOffice
_SalesGroup I_ServiceDocument _SalesGroup
_SalesOrganizationOrgUnit_2 I_ServiceDocument _SalesOrganizationOrgUnit_2
_SalesOfficeOrgUnit_2 I_ServiceDocument _SalesOfficeOrgUnit_2
_SalesGroupOrgUnit_2 I_ServiceDocument _SalesGroupOrgUnit_2 
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'BusinessSolutionOrder'
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL }

@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Solution Order'
@Search.searchable: true
@Consumption.ranked: true
define view entity C_DspDocFlwSolutionOrderVH
  as select from I_ServiceDocument as SolutionOrder
  
  association[1..1] to I_ServiceDocument as _ServiceDocument 
      on  $projection.BusinessSolutionOrder = _ServiceDocument.ServiceDocument
      and $projection.ServiceDocumentType = _ServiceDocument.ServiceDocumentType
  
{
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
  key SolutionOrder.ServiceDocument as BusinessSolutionOrder,
      @Consumption.hidden: true
  key SolutionOrder.ServiceDocumentType,  
      @Consumption.filter.hidden: true
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      SolutionOrder._ServiceDocumentType.
          _ServiceDocumentTypeText[1:Language = $session.system_language].ServiceDocumentTypeName,  
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SolutionOrder.SalesOrganization,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      SolutionOrder.DistributionChannel,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_Division'
      SolutionOrder.Division,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SolutionOrder.SalesOffice,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SolutionOrder.SalesGroup,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SolutionOrder.SalesOrganizationOrgUnitID,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SolutionOrder.SalesOfficeOrgUnitID,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SolutionOrder.SalesGroupOrgUnitID,
      
      @UI.hidden: true
      cast( SolutionOrder.ServiceDocument as fac_ddf_anchor_document )          as AnchorDocument,
      @UI.hidden: true
      cast( 'SOLO' as fis_awtyp )                                              as ReferenceDocumentType,

      _ServiceDocument,
      SolutionOrder._SalesOrganization,
      SolutionOrder._DistributionChannel,
      SolutionOrder._Division,
      SolutionOrder._SalesOffice,
      SolutionOrder._SalesGroup,
      SolutionOrder._SalesOrganizationOrgUnit_2,
      SolutionOrder._SalesOfficeOrgUnit_2,
      SolutionOrder._SalesGroupOrgUnit_2
}

where
      ServiceObjectType           = 'BUS2000172'
  and ServiceDocumentIsQuotation  = ' '
  and ServiceDocumentTemplateType = ' '

Learn More