C_DspDocFlwServiceOrderVH

DDL: C_DSPDOCFLWSERVICEORDERVH Type: view_entity CONSUMPTION Package: ODATA_PROCESS_FLOW_AR

Service Order

C_DspDocFlwServiceOrderVH is a Consumption CDS View that provides data about "Service Order" in SAP S/4HANA. It reads from 1 data source (I_ServiceOrderStdVH) and exposes 22 fields with key fields ServiceOrder, ServiceDocumentType. Part of development package ODATA_PROCESS_FLOW_AR.

1 data source(s) 22 fields

Data Sources (1)

SourceAliasJoin Type
I_ServiceOrderStdVH ServiceOrder from

Annotations (11)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey ServiceOrder view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #CONSUMPTION view
EndUserText.label Service Order view
Search.searchable true view
Consumption.ranked true view

Fields (22)

KeyFieldSource TableSource FieldDescription
KEY ServiceOrder I_ServiceOrderStdVH ServiceDocument
KEY ServiceDocumentType I_ServiceOrderStdVH ServiceDocumentType
ServiceDocumentTypeName
SalesOrganization I_ServiceOrderStdVH SalesOrganization
DistributionChannel I_ServiceOrderStdVH DistributionChannel
Division I_ServiceOrderStdVH Division
SalesOffice I_ServiceOrderStdVH SalesOffice
SalesGroup I_ServiceOrderStdVH SalesGroup
SalesOrganizationOrgUnitID I_ServiceOrderStdVH SalesOrganizationOrgUnitID
SalesOfficeOrgUnitID I_ServiceOrderStdVH SalesOfficeOrgUnitID
SalesGroupOrgUnitID I_ServiceOrderStdVH SalesGroupOrgUnitID
AnchorDocument
ReferenceDocumentType
_ServiceOrder _ServiceOrder
_SalesOrganization I_ServiceOrderStdVH _SalesOrganization
_DistributionChannel I_ServiceOrderStdVH _DistributionChannel
_Division I_ServiceOrderStdVH _Division
_SalesOffice I_ServiceOrderStdVH _SalesOffice
_SalesGroup I_ServiceOrderStdVH _SalesGroup
_SalesOrganizationOrgUnit_2 I_ServiceOrderStdVH _SalesOrganizationOrgUnit_2
_SalesOfficeOrgUnit_2 I_ServiceOrderStdVH _SalesOfficeOrgUnit_2
_SalesGroupOrgUnit_2 I_ServiceOrderStdVH _SalesGroupOrgUnit_2 
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'ServiceOrder'
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #XL,
  dataClass: #TRANSACTIONAL }

@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Service Order'
@Search.searchable: true
@Consumption.ranked: true
define view entity C_DspDocFlwServiceOrderVH
  as select from I_ServiceOrderStdVH as ServiceOrder
  
  association[1..1] to I_ServiceOrderStdVH as _ServiceOrder 
      on  $projection.ServiceOrder = _ServiceOrder.ServiceDocument
      and $projection.ServiceDocumentType = _ServiceOrder.ServiceDocumentType
  
{
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
  key ServiceOrder.ServiceDocument as ServiceOrder,
      @Consumption.hidden: true
  key ServiceOrder.ServiceDocumentType,  
      @Consumption.filter.hidden: true
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      ServiceOrder._ServiceDocumentType.
          _ServiceDocumentTypeText[1:Language = $session.system_language].ServiceDocumentTypeName,  
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      ServiceOrder.SalesOrganization,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      ServiceOrder.DistributionChannel,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_Division'
      ServiceOrder.Division,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesOffice'
      ServiceOrder.SalesOffice,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesGroup'
      ServiceOrder.SalesGroup,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      ServiceOrder.SalesOrganizationOrgUnitID,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      ServiceOrder.SalesOfficeOrgUnitID,
      @Search: { defaultSearchElement: true, ranking: #LOW}
      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      ServiceOrder.SalesGroupOrgUnitID,
      
      @UI.hidden: true
      cast( ServiceOrder.ServiceDocument as fac_ddf_anchor_document )          as AnchorDocument,
      @UI.hidden: true
      cast( 'CSVO' as fis_awtyp )                                              as ReferenceDocumentType,

      _ServiceOrder,
      ServiceOrder._SalesOrganization,
      ServiceOrder._DistributionChannel,
      ServiceOrder._Division,
      ServiceOrder._SalesOffice,
      ServiceOrder._SalesGroup,
      ServiceOrder._SalesOrganizationOrgUnit_2,
      ServiceOrder._SalesOfficeOrgUnit_2,
      ServiceOrder._SalesGroupOrgUnit_2
}

Learn More