@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl: {
authorizationCheck: #MANDATORY,
personalData.blocking: #NOT_REQUIRED
}
@EndUserText.label: 'Direct Activity Allocation Item'
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
semanticKey: [ 'FiscalYear', 'ReferenceDocument', 'ControllingArea', 'ReferenceDocumentItem', 'LedgerGLLineItem', 'ReferenceDocumentType', 'ReferenceDocumentContext', 'AccountingDocument' ],
usageType: {
serviceQuality: #C,
sizeCategory: #XXL,
dataClass: #TRANSACTIONAL
}
}
@VDM: {
viewType: #CONSUMPTION,
usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
}
@UI.headerInfo: { typeName: 'Item',
typeNamePlural: 'Items' }
@UI.presentationVariant: [{
qualifier: 'VAR_ITEM',
visualizations: [{ type: #AS_LINEITEM}],
sortOrder: [{
by: 'ReferenceDocumentForEdit',
direction: #ASC
},
{
by: 'ReferenceDocumentItemForEdit',
direction: #ASC
},
{
by: 'DraftEntityCreationDateTime',
direction: #ASC
}],
requestAtLeast: ['CostAccountingDocumentAction']
}]
define view entity C_DrctActivityAllocationItemTP
as projection on R_DrctActivityAllocationItemTP as _ActivityAllocationItem
{
@UI.lineItem: [{ type: #FOR_ACTION, dataAction: 'CopyItem', label: 'Copy', position: 10, invocationGrouping: #CHANGE_SET },
{ type: #FOR_ACTION, dataAction: 'ResetItem', label: 'Reset', position: 20, invocationGrouping: #CHANGE_SET }]
@UI.hidden: true
key FiscalYear,
@UI.hidden: true
key ReferenceDocument,
@UI.hidden: true
key ControllingArea,
@UI.hidden: true
key ReferenceDocumentItem,
@UI.hidden: true
key LedgerGLLineItem,
@UI.hidden: true
key ReferenceDocumentType,
@UI.hidden: true
key ReferenceDocumentContext,
@UI.hidden: true
key AccountingDocument,
@UI.hidden: true
@ObjectModel.editableFieldFor: 'FiscalYear'
FiscalYearForEdit,
@ObjectModel.editableFieldFor: 'ReferenceDocument'
ReferenceDocumentForEdit,
@UI.hidden: true
@ObjectModel.editableFieldFor: 'ControllingArea'
ControllingAreaForEdit,
@UI.hidden: true
@ObjectModel.editableFieldFor: 'ReferenceDocumentItem'
ReferenceDocumentItemForEdit,
@UI.hidden: true
@ObjectModel.editableFieldFor: 'LedgerGLLineItem'
LedgerGLLineItemForEdit,
@ObjectModel.editableFieldFor: 'ReferenceDocumentType'
ReferenceDocumentTypeForEdit,
//@UI.hidden: true
@ObjectModel.editableFieldFor: 'AccountingDocument'
AccountingDocumentForEdit,
@UI.hidden: true
@ObjectModel.editableFieldFor: 'ReferenceDocumentContext'
ReferenceDocumentContextFoEd,
@UI.hidden: true
TransactionSubitem,
@UI.hidden: true
SourceLedger,
@Consumption.semanticObject: 'CompanyCode'
@ObjectModel.text.element: [ 'CompanyCodeName' ]
@UI.textArrangement: #TEXT_LAST
@EndUserText.label: 'Receiver Company Code'
@EndUserText.quickInfo: 'Receiver Company Code'
CompanyCode,
@Semantics.text: true
cast(_CompanyCodeText.CompanyCodeName as receivercompanycodename preserving type) as CompanyCodeName,
@Consumption.semanticObject: 'CompanyCode'
@ObjectModel.text.element: [ 'SourceCompanyCodeName' ]
@UI.textArrangement: #TEXT_LAST
SenderCompanyCode,
@Semantics.text: true
cast(_SenderCompanyCodeText.CompanyCodeName as sendercompanycodename preserving type) as SourceCompanyCodeName,
@EndUserText.label: 'Sender'
@EndUserText.quickInfo: 'Sender Object'
AccountAssignment,
@ObjectModel.text.element: [ 'AccountAssignmentTypeDesc' ]
@UI.textArrangement: #TEXT_LAST
@EndUserText.label: 'Sender Object Type'
@EndUserText.quickInfo: 'Sender Object Type'
AccountAssignmentType,
@Semantics.text: true
cast(_AccountAssignmentTypeT.AccountAssignmentTypeDesc as senderobjecttypename preserving type) as AccountAssignmentTypeDesc,
@EndUserText.label: 'Receiver'
@EndUserText.quickInfo: 'Receiver Object'
PartnerAccountAssignment,
@ObjectModel.text.element: [ 'PartAccountAssignmentTypeDesc' ]
@UI.textArrangement: #TEXT_LAST
@EndUserText.label: 'Receiver Object Type'
@EndUserText.quickInfo: 'Receiver Object Type'
PartnerAccountAssignmentType,
@Semantics.text: true
cast(_PartnerAccountAssignmentTypeT.AccountAssignmentTypeDesc as receiverobjecttypename preserving type ) as PartAccountAssignmentTypeDesc,
@UI: { lineItem: [{position: 20, importance: #HIGH }] }
@Consumption.semanticObject: 'ActivityType'
@Consumption.valueHelpDefinition: [{
entity: { name: 'C_ActyTypeWthCostCtrCostRateVH', element: 'CostCtrActivityType' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' },
{ localElement: 'SenderCostCenter', element: 'CostCenter' },
{ localElement: 'FiscalYearForEdit', element: 'FiscalYear' }],
label: 'Cost Center Activity Type Value Help' },
{ entity: { name: 'I_CostCenterActivityTypeVH', element: 'CostCtrActivityType' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' }],
qualifier: 'VH1',
label: 'Activity Type Value Help'
}]
@ObjectModel.text.element: [ 'CostCtrActivityTypeName' ]
@UI.textArrangement: #TEXT_LAST
@EndUserText.label: 'Sender Activity Type'
@EndUserText.quickInfo: 'Sender Activity Type'
CostCtrActivityType,
@Semantics.text: true
cast(_CostCtrActivityType._Text[1:Language = $session.system_language].CostCtrActivityTypeName as senderactivitytypename preserving type) as CostCtrActivityTypeName,
@Consumption.valueHelpDefinition: [{
entity: { name: 'C_CostCenterVH', element: 'CostCenter' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' }]
}]
@Consumption.semanticObject: 'CostCenter'
@UI: { lineItem: [{ position: 30 }] }
@EndUserText.label: 'Receiver Cost Center'
@EndUserText.quickInfo: 'Receiver Cost Center'
@ObjectModel.text.element: [ 'PartnerCostCenterName' ]
@UI.textArrangement: #TEXT_LAST
PartnerCostCenter,
@Semantics.text: true
cast(_PartnerCostCenter._Text[1:Language = $session.system_language].CostCenterName as receivercostcentername preserving type) as PartnerCostCenterName,
@Consumption.valueHelpDefinition: [{
entity: { name: 'C_CostCtrWthActyTypeCostRateVH', element: 'CostCenter' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' },
{ localElement: 'CostCtrActivityType', element: 'CostCtrActivityType' },
{ localElement: 'FiscalYearForEdit', element: 'FiscalYear' }],
label: 'Cost Center Activity Type Value Help' },
{ entity: { name: 'C_CostCenterVH', element: 'CostCenter' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea'}],
qualifier: 'VH1'
}]
@Consumption.semanticObject: 'CostCenter'
@UI: { lineItem: [{ position: 10, importance: #HIGH }] }
@ObjectModel.text.element: [ 'CostCenterName' ]
@UI.textArrangement: #TEXT_LAST
SenderCostCenter,
@Semantics.text: true
cast(_CostCenter._Text[1:Language = $session.system_language].CostCenterName as sendercostcentername preserving type ) as CostCenterName,
@UI: { lineItem: [{ position: 40 }] }
DocumentItemText,
@UI: { lineItem: [{ position: 80 }] }
@ObjectModel.text.element: [ 'GLAccountName' ]
@UI.textArrangement: #TEXT_LAST
@Consumption.semanticObject: 'GLAccount'
GLAccount,
@Semantics.text: true
cast(_GLAccountText[1:Language = $session.system_language].GLAccountName as fco_allocation_account_name preserving type) as GLAccountName,
@UI.hidden: true
ChartOfAccounts,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_PMUnitOfMeasureVH', element: 'UnitOfMeasure' }
}]
@ObjectModel.text.element: [ 'UnitOfMeasureLongName' ]
@UI.textArrangement: #TEXT_LAST
@Semantics.unitOfMeasure:true
BaseUnit,
@Semantics.text: true
_UnitOfMeasureText[1:Language = $session.system_language].UnitOfMeasureLongName as UnitOfMeasureLongName,
@UI: { lineItem: [{ position: 50 }] }
@EndUserText.label: 'Quantity'
@EndUserText.quickInfo: 'Quantity'
@Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
Quantity,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_CurrencyStdVH', element: 'Currency' }
}]
@Semantics.currencyCode:true
TransactionCurrency,
@UI: { lineItem: [{ position: 70 }] }
@Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
AmountInTransactionCurrency,
@UI: { lineItem: [{ position: 60 }] }
@Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
PrcTotAmtInTransactionCurrency,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_CurrencyStdVH', element: 'Currency' }
}]
@Semantics.currencyCode:true
CompanyCodeCurrency,
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
AmountInCompanyCodeCurrency,
@Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
PrcTotAmtInCompanyCodeCurrency,
@Semantics.currencyCode:true
GlobalCurrency,
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
AmountInGlobalCurrency,
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
PrcTotAmtInGlobalCurrency,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_WBSElementBasicDataStdVH', element: 'WBSElementExternalID' }
}]
@UI: { lineItem: [{ position: 35 }] }
@Consumption.semanticObject: 'WBSElement'
@EndUserText.label: 'Receiver WBS Element'
@EndUserText.quickInfo: 'Receiver WBS Element'
@ObjectModel.text.element: [ 'WBSDescription' ]
@UI.textArrangement: #TEXT_LAST
PartnerWBSElementExternalID,
@Semantics.text: true
cast(_PartnerWBSElementText.WBSDescription as receiverwbselementname preserving type) as WBSDescription,
@Consumption.semanticObject: 'Project'
@EndUserText.label: 'Receiver Project'
@EndUserText.quickInfo: 'Receiver Project'
PartnerProjectExternalID,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_AcctgServiceDocumentTypeVH', element: 'ServiceDocumentType' }
}]
@EndUserText.label: 'Receiver Service Doc. Type'
@EndUserText.quickInfo: 'Receiver Service Document Type'
@ObjectModel.text.element: [ 'ServiceDocumentTypeName' ]
@UI.textArrangement: #TEXT_LAST
PartnerServiceDocumentType,
@Semantics.text: true
cast(_PartnerServiceDocumentTypeTxt.ServiceDocumentTypeName as rcvrservicedocumenttypename preserving type) as ServiceDocumentTypeName,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_AcctgServiceDocumentVH', element: 'ServiceDocument' },
additionalBinding: [{ localElement: 'PartnerServiceDocumentType', element: 'ServiceDocumentType' }]
}]
@EndUserText.label: 'Receiver Service Document'
@EndUserText.quickInfo: 'Receiver Service Document'
PartnerServiceDocument,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_AcctgServiceDocumentItemVH', element: 'ServiceDocumentItem' },
additionalBinding: [{ localElement: 'PartnerServiceDocumentType', element: 'ServiceDocumentType' },
{ localElement: 'PartnerServiceDocument', element: 'ServiceDocument' }]
}]
@EndUserText.label: 'Receiver Service Doc. Item'
@EndUserText.quickInfo: 'Receiver Service Document Item'
PartnerServiceDocumentItem,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@EndUserText.label: 'Receiver Project Network'
@EndUserText.quickInfo: 'Receiver Project Network'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_ProjectNetworkStdVH', element: 'ProjectNetwork' }
}]
@ObjectModel.text.element: [ 'ProjectNetworkDescription' ]
@UI.textArrangement: #TEXT_LAST
PartnerProjectNetwork,
@Semantics.text: true
cast(_PartnerProjectNetwork.ProjectNetworkDescription as prtnprojectnetworkdescription preserving type) as ProjectNetworkDescription,
@Consumption.valueHelpDefinition: [{
entity: { name: 'C_OrderMasterVH', element: 'OrderID' }
}]
@EndUserText.label: 'Receiver Order'
@EndUserText.quickInfo: 'Receiver Order'
PartnerOrder,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@EndUserText.label: 'Receiver Project Network Activity'
@EndUserText.quickInfo: 'Receiver Project Network Activity'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_NetworkActivityValueHelp', element: 'NetworkActivity' },
additionalBinding: [{ localElement: 'PartnerProjectNetwork', element: 'ProjectNetwork' }]
}]
PartnerProjectNetworkActivity,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_CostCenterActivityTypeVH', element: 'CostCtrActivityType' }
}]
@Consumption.semanticObject: 'ActivityType'
@EndUserText.label: 'Receiver Activity Type'
@EndUserText.quickInfo: 'Receiver Activity Type'
@ObjectModel.text.element: [ 'PartnerCostCtrActivityTypeName' ]
@UI.textArrangement: #TEXT_LAST
PartnerCostCtrActivityType,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@Semantics.text: true
@EndUserText.label: 'Receiver Activity Type Name'
@EndUserText.quickInfo: 'Receiver Activity Type Name'
_PartnerCostCtrActivityType._Text[1:Language = $session.system_language].CostCtrActivityTypeName as PartnerCostCtrActivityTypeName,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@EndUserText.label: 'Receiver Cost Object'
@EndUserText.quickInfo: 'Receiver Cost Object'
PartnerCostObject,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_SalesDocumentStdVH', element: 'SalesDocument' }
}]
@Consumption.semanticObject: 'SalesDocument'
@EndUserText.label: 'Receiver Sales Document'
@EndUserText.quickInfo: 'Receiver Sales Document'
PartnerSalesDocument,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_SalesDocumentItemStdVH', element: 'SalesDocumentItem' },
additionalBinding: [{ localElement: 'PartnerSalesDocument', element: 'SalesDocument' }]
}]
@EndUserText.label: 'Receiver Sales Doc. Item'
@EndUserText.quickInfo: 'Receiver Sales Document Item'
@ObjectModel.text.element: [ 'SalesDocumentItemText' ]
@UI.textArrangement: #TEXT_LAST
PartnerSalesDocumentItem,
@Semantics.text: true
cast(_PartnerSalesDocumentItem.SalesDocumentItemText as rcvrsalesdocumentitemtext preserving type) as SalesDocumentItemText,
@Consumption.valueHelpDefinition: [{
entity: { name: 'C_WorkItemVH', element: 'WorkItem' }
}]
@Consumption.semanticObject: 'WorkItem'
@ObjectModel.text.element: [ 'WorkItemName' ]
@UI.textArrangement: #TEXT_LAST
WorkItem,
@Semantics.text: true
_WorkItemText.WorkItemName,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_WorkAssignmentsVH', element: 'WorkAssignment' },
additionalBinding: [{ element: 'WorkAssignmentExternalID', localElement: 'WorkAssignmentExternalID', usage: #RESULT }]
}]
PersonnelNumber,
_WorkForcePersonMappings.WorkAssignmentExternalID,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_PlantStdVH', element: 'Plant' } }]
@Consumption.semanticObject: 'Plant'
@ObjectModel.text.element: [ 'PlantName' ]
@UI.textArrangement: #TEXT_LAST
Plant,
@Semantics.text: true
_Plant.PlantName,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_ProductVH', element: 'Product' }
}]
@Consumption.semanticObject: 'Material'
@ObjectModel.text.element: [ 'ProductDescription' ]
@UI.textArrangement: #TEXT_LAST
Product,
@Semantics.text: true
_ProductText.ProductDescription,
@Consumption.valueHelpDefinition: [{
entity: { name: 'C_DrctActyAllocProcmtProcessVH', element: 'ProcurementProcess' },
additionalBinding: [{ localElement: 'Plant', element: 'Plant' },
{ localElement: 'Product', element: 'Material' }]
}]
ReceiverProcurementProcess,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_BusinessProcessStdVH', element: 'BusinessProcess' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' }]
}]
@Consumption.semanticObject: 'BusinessProcess'
@EndUserText.label: 'Receiver Business Process'
@EndUserText.quickInfo: 'Receiver Business Process'
@ObjectModel.text.element: [ 'BusinessProcessName' ]
@UI.textArrangement: #TEXT_LAST
PartnerBusinessProcess,
@Semantics.text: true
cast(_PartnerBusinessProcessText.BusinessProcessName as receiverbusinessprocessname preserving type) as BusinessProcessName,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_FundStdVH', element: 'Fund' }
}]
@ObjectModel.text.element: [ 'FundName' ]
@UI.textArrangement: #TEXT_LAST
Fund,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_FndsMgmtFuncnlAreaStdVH', element: 'FunctionalArea' }
}]
@ObjectModel.text.element: [ 'FunctionalAreaName' ]
@UI.textArrangement: #TEXT_LAST
FunctionalArea,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_GrantStdVH', element: 'GrantID' }
}]
@ObjectModel.text.element: [ 'GrantName' ]
@UI.textArrangement: #TEXT_LAST
GrantID,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_BudgetPeriodStdVH', element: 'BudgetPeriod' }
}]
@EndUserText.label: 'Sender Budget Period'
@EndUserText.quickInfo: 'Sender Budget Period'
@ObjectModel.text.element: [ 'BudgetPeriodName' ]
@UI.textArrangement: #TEXT_LAST
BudgetPeriod,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_FundStdVH', element: 'Fund' }
}]
@ObjectModel.text.element: [ 'ReceiverPostedFundName' ]
@UI.textArrangement: #TEXT_LAST
PartnerFund,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_FndsMgmtFuncnlAreaStdVH', element: 'FunctionalArea' }
}]
@ObjectModel.text.element: [ 'PartnerFunctionalAreaName' ]
@UI.textArrangement: #TEXT_LAST
PartnerFunctionalArea,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_GrantStdVH', element: 'GrantID' }
}]
@ObjectModel.text.element: [ 'ReceiverPostedGrantName' ]
@UI.textArrangement: #TEXT_LAST
PartnerGrant,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_BudgetPeriodStdVH', element: 'BudgetPeriod' }
}]
@EndUserText.label: 'Receiver Budget Period'
@EndUserText.quickInfo: 'Receiver Budget Period'
@ObjectModel.text.element: [ 'ReceiverPostedBudgetPeriodName' ]
@UI.textArrangement: #TEXT_LAST
PartnerBudgetPeriod,
@Semantics.text: true
cast(_FundText[1:Language = $session.system_language].FundName as senderfundname preserving type) as FundName,
@Semantics.text: true
cast(_PartnerFundText[1:Language = $session.system_language].FundName as receiverfundname preserving type) as ReceiverPostedFundName,
@Semantics.text: true
cast(_GrantText[1:Language = $session.system_language].GrantName as sendergrantname preserving type) as GrantName,
@Semantics.text: true
cast(_PartnerGrantText[1:Language = $session.system_language].GrantName as receivergrantname preserving type) as ReceiverPostedGrantName,
@Semantics.text: true
cast(_BudgetPeriodText[1:Language = $session.system_language].BudgetPeriodName as senderbudgetperiodname preserving type) as BudgetPeriodName,
@Semantics.text: true
cast(_PartnerBudgetPeriodText[1:Language = $session.system_language].BudgetPeriodName as receiverbudgetperiodname preserving type) as ReceiverPostedBudgetPeriodName,
@Semantics.text: true
cast(_FunctionalAreaText[1:Language = $session.system_language].FunctionalAreaName as senderfunctionalareaname preserving type) as FunctionalAreaName,
@Semantics.text: true
cast(_PartnerFunctionalAreaText[1:Language = $session.system_language].FunctionalAreaName as receiverfunctionalareaname preserving type) as PartnerFunctionalAreaName,
@EndUserText.label: 'Is Reposted'
@EndUserText.quickInfo: 'Is Reposted'
IsSettled,
@Consumption.valueHelpDefinition: [{
entity: { name: 'C_ControllingBillableControlVH', element: 'BillableControl' }
}]
@EndUserText.label: 'Receiver Accounting Indicator'
@EndUserText.quickInfo: 'Receiver Accounting Indicator'
@ObjectModel.text.element: [ 'BillableControlName' ]
@UI.textArrangement: #TEXT_LAST
BillableControl,
@Semantics.text: true
cast(_BillableControlText[1:Language = $session.system_language].BillableControlName as rcvracctgindcodename preserving type) as BillableControlName,
// Joint Venture
@Feature: 'BF:JOINT_VENTURE_ACCOUNTING'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_JntVntrRecoveryIndVH', element: 'JointVentureRecoveryCode' }
}]
@EndUserText.label: 'Receiver Recovery Indicator'
@EndUserText.quickInfo: 'Receiver Recovery Indicator'
@ObjectModel.text.element: [ 'PartnerCostRecoveryCodeName' ]
@UI.textArrangement: #TEXT_LAST
PartnerCostRecoveryCode,
@Feature: 'BF:JOINT_VENTURE_ACCOUNTING'
@Semantics.text: true
cast(_PartnerCostRecoveryCodeText.JointVentureRecoveryCodeName as partnercostrecoverycodename preserving type) as PartnerCostRecoveryCodeName,
@Feature: 'BF:JOINT_VENTURE_ACCOUNTING'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_JntVntrRecoveryIndVH', element: 'JointVentureRecoveryCode' }
}]
@EndUserText.label: 'Sender Recovery Indicator'
@EndUserText.quickInfo: 'Sender Recovery Indicator'
@ObjectModel.text.element: [ 'SenderCostRecoveryCodeName' ]
@UI.textArrangement: #TEXT_LAST
SenderCostRecoveryCode,
@Feature: 'BF:JOINT_VENTURE_ACCOUNTING'
@Semantics.text: true
cast(_SenderCostRecoveryCodeText.JointVentureRecoveryCodeName as sendercostrecoverycodename preserving type) as SenderCostRecoveryCodeName,
@UI.hidden: true
CostAccountingDocumentAction,
@UI.hidden: true
ControllingDocumentStatus,
@UI.hidden: true
ControllingDocumentItem,
@UI.hidden: true
PostingDate,
@UI.hidden: true
OperatingConcern,
@EndUserText.label: 'Profitability Segment'
@EndUserText.quickInfo: 'Profitability Segment'
PartnerProfitabilitySegment,
@UI.hidden: true
@Semantics.booleanIndicator
PartProfitabilitySgmtIsAssgd,
@EndUserText.label: 'Reposting Reference Document'
@EndUserText.quickInfo: 'Reposting Reference Document'
_SuccessorReferenceItem.SuccessorReferenceDocument as SuccessorReferenceDocument,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@EndUserText.label: 'Receiver Order Operation'
@EndUserText.quickInfo: 'Receiver Order Operation'
OrderOperation,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_CompanyCodeVH', element: 'CompanyCode' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' }]
}]
@EndUserText.label: 'Receiver Real Estate Company Code'
@EndUserText.quickInfo: 'Receiver Real Estate Company Code'
@ObjectModel.text.element: [ 'ReceiverRECompanyCodeName' ]
@UI.textArrangement: #TEXT_LAST
ReceiverRECompanyCode,
@Semantics.text: true
cast(_ReceiverRECompanyCodeText.CompanyCodeName as receiverrecompanycodename preserving type ) as ReceiverRECompanyCodeName,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_REBusinessEntityVH', element: 'REBusinessEntity' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' }]
}]
@EndUserText.label: 'Receiver Real Estate Business Entity'
@EndUserText.quickInfo: 'Receiver Real Estate Business Entity'
REPartnerBusinessEntity,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_REBuildingVH', element: 'RealEstateBuilding' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' }]
}]
@EndUserText.label: 'Receiver Real Estate Building'
@EndUserText.quickInfo: 'Receiver Real Estate Building'
RealEstatePartnerBuilding,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_REPropertyVH', element: 'RealEstateProperty' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' }]
}]
@EndUserText.label: 'Receiver Real Estate Property'
@EndUserText.quickInfo: 'Receiver Real Estate Property'
RealEstatePartnerProperty,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_RERentalObjectVH', element: 'RERentalObject' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' },
{ localElement: 'RealEstatePartnerBuilding', element: 'RealEstateBuilding'},
{ localElement: 'RealEstatePartnerProperty', element: 'RealEstateProperty' }]
}]
@EndUserText.label: 'Receiver Real Estate Rental Object'
@EndUserText.quickInfo: 'Receiver Real Estate Rental Object'
REPartnerRentalObject,
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_REContractVH', element: 'RealEstateContract' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' }]
}]
@EndUserText.label: 'Receiver Real Estate Contract'
@EndUserText.quickInfo: 'Receiver Real Estate Contract'
@ObjectModel.text.element: [ 'REContractName' ]
@UI.textArrangement: #TEXT_LAST
RealEstatePartnerContract,
@Semantics.text: true
cast(_RealEstatePartnerContract.REContractName as realestatepartnercontractname preserving type) as REContractName,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_RESettlementUnitVH',
element: 'REServiceChargeKey' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' }]
}]
@EndUserText.label: 'Receiver Real Estate Service Charge Key'
@EndUserText.quickInfo: 'Receiver Real Estate Service Charge Key'
REPartnerServiceChargeKey,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@Consumption.valueHelpDefinition: [{
entity: { name: 'I_RESettlementUnitVH', element: 'RESettlementUnitID' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' },
{ localElement: 'REPartnerServiceChargeKey', element: 'REServiceChargeKey' }]
}]
@EndUserText.label: 'Receiver Real Estate Settlement Unit'
@EndUserText.quickInfo: 'Receiver Real Estate Settlement Unit'
REPartnerSettlementUnitID,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@EndUserText.label: 'Receiver Real Estate Settlement Reference Date'
@EndUserText.quickInfo: 'Receiver Real Estate Settlement Reference Date'
PartnerSettlementReferenceDate,
@UI.hidden: true
ControllingBusTransacType,
@UI.hidden: true
PartnerProfitCenter,
@UI.hidden: true
ProfitCenter,
ServicesRenderedDate,
@UI.hidden: true
AccountingDocumentType,
@Semantics.currencyCode:true
FreeDefinedCurrency1,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
AmountInFreeDefinedCurrency1,
@Semantics.currencyCode:true
FreeDefinedCurrency2,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
AmountInFreeDefinedCurrency2,
@Semantics.currencyCode:true
FreeDefinedCurrency3,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
AmountInFreeDefinedCurrency3,
@Semantics.currencyCode:true
FreeDefinedCurrency4,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
AmountInFreeDefinedCurrency4,
@Semantics.currencyCode:true
FreeDefinedCurrency5,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
AmountInFreeDefinedCurrency5,
@Semantics.currencyCode:true
FreeDefinedCurrency6,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
AmountInFreeDefinedCurrency6,
@Semantics.currencyCode:true
FreeDefinedCurrency7,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
AmountInFreeDefinedCurrency7,
@Semantics.currencyCode:true
FreeDefinedCurrency8,
@Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
AmountInFreeDefinedCurrency8,
@Semantics.currencyCode:true
FunctionalCurrency,
@Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
AmountInFunctionalCurrency,
//Field for Predecessor Fiscal Year
@UI.hidden: true
ReferenceFiscalYear,
@UI.hidden: true
AccountingDocumentItemRef,
@UI.hidden: true
DraftCreationDateTime,
_Header : redirected to parent C_DirectActivityAllocationTP
}