@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Direct Activity Allocation'
//@Metadata.ignorePropagatedAnnotations: true
@AccessControl.privilegedAssociations: ['_CreatedByContactCard']
@ObjectModel: {
semanticKey: [ 'FiscalYearForEdit', 'ReferenceDocumentForEdit', 'ControllingAreaForEdit', 'ReferenceDocumentTypeForEdit', 'ReferenceDocumentContextFoEd' ],
usageType: {
serviceQuality: #C,
sizeCategory: #XXL,
dataClass: #TRANSACTIONAL
}
}
@VDM: {
viewType: #CONSUMPTION,
usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
}
@UI.headerInfo: {
typeName: 'Document',
typeNamePlural: 'Documents',
title: {
value: 'ReferenceDocumentForEdit',
label: 'Reference Document'
},
description: { type: #STANDARD, value: 'AccountingDocumentHeaderText' }
}
@UI.presentationVariant: [{
text: 'Activity Allocations',
qualifier: 'VAR_DOCHEADER',
sortOrder: [{
by: 'DocumentDate',
direction: #DESC
},
{
by: 'ReferenceDocumentForEdit',
direction: #DESC
}]
}]
@Consumption.dbHints: ['USE_HEX_PLAN']
define root view entity C_DirectActivityAllocationTP
provider contract transactional_query
as projection on R_DirectActivityAllocationTP
association [1..*] to C_DrctActyAllocJournalEntry_2 as _JournalEntry on $projection.ControllingArea = _JournalEntry.ControllingArea
and $projection.ReferenceDocumentType = _JournalEntry.ReferenceDocumentType
and $projection.ReferenceDocument = _JournalEntry.ReferenceDocument
and $projection.ReferenceDocumentContext = _JournalEntry.ReferenceDocumentContext
association [1..*] to C_DrctActyAllocOriginalItem as _OriginalItem on $projection.ReferenceFiscalYear = _OriginalItem.FiscalYear
and $projection.PredecessorReferenceDocument = _OriginalItem.ReferenceDocument
and $projection.ControllingAreaForEdit = _OriginalItem.ControllingArea
and $projection.PredecessorReferenceDocType = _OriginalItem.ReferenceDocumentType
and $projection.PredecessorReferenceDocCntxt = _OriginalItem.ReferenceDocumentContext
association [1..*] to C_DrctActyAllocCompanyCode_2 as _ReceiverCompanyCode on $projection.FiscalYear = _ReceiverCompanyCode.FiscalYear
and $projection.ReferenceDocument = _ReceiverCompanyCode.ReferenceDocument
and $projection.ControllingArea = _ReceiverCompanyCode.ControllingArea
and $projection.ReferenceDocumentType = _ReceiverCompanyCode.ReferenceDocumentType
and $projection.ReferenceDocumentContext = _ReceiverCompanyCode.ReferenceDocumentContext
association [1..*] to C_DrctActyAllocSndrCoCode_2 as _SenderCompanyCode on $projection.FiscalYear = _SenderCompanyCode.FiscalYear
and $projection.ReferenceDocument = _SenderCompanyCode.ReferenceDocument
and $projection.ControllingArea = _SenderCompanyCode.ControllingArea
and $projection.ReferenceDocumentType = _SenderCompanyCode.ReferenceDocumentType
and $projection.ReferenceDocumentContext = _SenderCompanyCode.ReferenceDocumentContext
association [0..*] to C_DrctActyAllocSuccssrRefDoc as _SuccessorReferenceDocument on $projection.FiscalYear = _SuccessorReferenceDocument.FiscalYear
and $projection.ReferenceDocument = _SuccessorReferenceDocument.ReferenceDocument
and $projection.ControllingArea = _SuccessorReferenceDocument.ControllingArea
and $projection.ReferenceDocumentType = _SuccessorReferenceDocument.ReferenceDocumentType
and $projection.ReferenceDocumentContext = _SuccessorReferenceDocument.ReferenceDocumentContext
{
@UI.facet:[
// does not have a target/is not used, was causing ui5 issue, commenting for now
// { id: 'HeaderForFilter',
// label: 'Header',
// purpose: #FILTER,
// type: #FIELDGROUP_REFERENCE,
// hidden: true,
// targetQualifier: 'HeaderFilter'
// },
// Header Facet
{ id: 'HeaderFacet1',
purpose: #HEADER,
type: #FIELDGROUP_REFERENCE,
position: 1,
targetQualifier: 'HeaderFacet1'
},
{ id: 'HeaderFacet2',
purpose: #HEADER,
type: #FIELDGROUP_REFERENCE,
position: 10,
targetQualifier: 'HeaderFacet2'
},
{ targetQualifier: 'ControllingDocumentStatus',
type: #DATAPOINT_REFERENCE,
purpose: #HEADER,
position: 20,
importance: #HIGH
},
// Section 'Header Information'
{ label: 'Header Information',
id: 'HeaderInfoFAC',
type: #COLLECTION,
position: 10
},
{ //label: 'Header Information',
id: 'HeaderInfoGroup',
parentId: 'HeaderInfoFAC',
type: #FIELDGROUP_REFERENCE,
position: 10,
targetQualifier: 'HeaderInfoGroup'
},
// Section Items
{ id: 'ItemsFAC',
label: 'Allocation Items',
type: #PRESENTATIONVARIANT_REFERENCE,
position: 20,
targetElement: '_Item',
targetQualifier: 'VAR_ITEM'
},
// Original Items
{ id: 'OriginalItemsFAC',
label: 'Original Allocation Items',
// type: #LINEITEM_REFERENCE,
type: #PRESENTATIONVARIANT_REFERENCE,
hidden: #(UICT_OriginalItemsTabIsHidden),
position: 25,
targetElement: '_OriginalItem',
targetQualifier: 'VAR_ORIG_ITEM'
},
// Journal Entries
{ id: 'JournalEntryFAC',
label: 'Journal Entries',
type: #LINEITEM_REFERENCE,
hidden: #(UICT_JournalEntriesTabIsHidden),
position: 30,
targetElement: '_JournalEntry'
},
// Sender and Receiver fields visible only in filters
{ label: 'Senders',
id: 'SendersGroup',
purpose: #FILTER,
type: #FIELDGROUP_REFERENCE,
hidden: true,
targetQualifier: 'SendersGroup'
},
{ label: 'Receivers',
id: 'ReceiversGroup',
purpose: #FILTER,
type: #FIELDGROUP_REFERENCE,
hidden: true,
targetQualifier: 'ReceiversGroup'
}]
// Object Page
@UI.identification: [{ type: #FOR_ACTION, dataAction: 'Reverse', label: 'Reverse', position: 10 },
{ type: #FOR_ACTION, dataAction: 'Copy', label: 'Copy', position: 30 }]
// List report
@UI.lineItem: [{ type: #FOR_ACTION, dataAction: 'ReverseMultipleDocuments', label: 'Reverse', position: 10, invocationGrouping: #CHANGE_SET }]
@UI.hidden: true
key FiscalYear,
@UI.hidden: true
key ReferenceDocument,
@UI.hidden: true
key ControllingArea,
@UI.hidden: true
key ReferenceDocumentType,
@UI.hidden: true
key ReferenceDocumentContext,
@Semantics.fiscal.year: true
@UI: {
fieldGroup: [{
qualifier: 'HeaderInfoGroup',
position: 40,
importance: #HIGH,
groupLabel: 'Header Information'
}]
}
@ObjectModel.editableFieldFor: 'FiscalYear'
FiscalYearForEdit,
@UI: {
lineItem: [{ position: 10 }],
selectionField: [{ position: 20 }]
}
@ObjectModel.editableFieldFor: 'ReferenceDocument'
ReferenceDocumentForEdit,
@Consumption.filter.hidden: true
@UI: { lineItem: [{ hidden: true }],
fieldGroup: [{ qualifier: 'HeaderInfoGroup',
position: 50,
importance: #HIGH,
hidden: #(UICT_ControllingAreaIsHidden) }] }
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_ControllingAreaStdVH', element: 'ControllingArea' } }]
@ObjectModel.editableFieldFor: 'ControllingArea'
@ObjectModel.text.element: [ 'ControllingAreaName' ]
@UI.textArrangement: #TEXT_LAST
ControllingAreaForEdit,
@Consumption.valueHelpDefinition: [{ entity:{ name: 'C_DrctActyAllocRefDocTypeVH', element: 'ReferenceDocumentType' } }]
@ObjectModel.editableFieldFor: 'ReferenceDocumentType'
@ObjectModel.text.element: [ 'ReferenceDocumentTypeName' ]
@UI.textArrangement: #TEXT_LAST
@UI: {
selectionField: [{ position: 60 }],
lineItem: [{ position: 15 }],
fieldGroup: [{ position: 20, qualifier: 'HeaderFacet2' }]
}
@Consumption.filter.defaultValue: 'COBK'
ReferenceDocumentTypeForEdit,
@UI.hidden: true
@ObjectModel.editableFieldFor: 'ReferenceDocumentContext'
ReferenceDocumentContextFoEd,
@Semantics.text: true
_ControllingArea.ControllingAreaName,
@UI: {
lineItem: [{ position: 30 }],
fieldGroup: [{
qualifier: 'HeaderInfoGroup',
position: 5,
importance: #HIGH,
hidden: #(UICT_AcctgDocHeaderTxtIsHidden)
}]
}
AccountingDocumentHeaderText,
@UI: {
lineItem: [{ position: 20 }],
selectionField: [{ position: 40 }],
fieldGroup: [{
qualifier: 'HeaderInfoGroup',
position: 10,
importance: #HIGH
}]
}
@Consumption.filter.selectionType: #INTERVAL
DocumentDate,
@UI: {
lineItem: [{ position: 25 }],
selectionField: [{ position: 50 }],
fieldGroup: [{
qualifier: 'HeaderInfoGroup',
position: 20,
importance: #HIGH
}]
}
@Consumption.filter.selectionType: #INTERVAL
PostingDate,
@Semantics.fiscal.period: true
@UI: {
fieldGroup: [{
qualifier: 'HeaderInfoGroup',
position: 30,
importance: #HIGH
}]
}
FiscalPeriod,
@Semantics.fiscal.yearPeriod: true
FiscalYearPeriod,
@UI: { fieldGroup: [{ position: 10, qualifier: 'HeaderFacet1' }] }
@Consumption.filter.selectionType: #INTERVAL
AccountingDocumentCreationDate,
@UI: {
selectionField: [{ position: 70 }],
fieldGroup: [{ position: 20, qualifier: 'HeaderFacet1' }]
}
@ObjectModel.foreignKey.association: '_CreatedByContactCard'
@Consumption.valueHelpDefinition: [{ entity: { name : 'C_DrctActivityAllocationUserVH', element : 'UserID' } }]
@ObjectModel.text.element: [ 'FullName' ]
@UI.textArrangement: #TEXT_ONLY
AccountingDocCreatedByUser,
@Semantics.text: true
@EndUserText.label: 'Created By Full Name'
@EndUserText.quickInfo: 'Created By Full Name'
_CreatedByContactCard.FullName,
@Semantics.nullValueIndicatorFor: 'AccountingDocCreatedByUser'
ConditionRateValueIsNull,
@UI.hidden: true
IsReversal,
@UI.hidden: true
IsReversed,
@UI.textArrangement: #TEXT_ONLY
@UI.dataPoint: { title: 'Status',
criticality: 'CtrlgOverheadStatusCriticality' }
@UI: { selectionField: [{ position: 80 }],
lineItem: [{ position: 40,
criticality: 'CtrlgOverheadStatusCriticality',
criticalityRepresentation: #WITHOUT_ICON,
cssDefault: {width: '12rem'} }] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'R_CostAcctgDocStatusDomainVal', element: 'ControllingDocumentStatus' }}]
@ObjectModel.text.element: [ 'StatusName' ]
ControllingDocumentStatus,
@Consumption.filter.hidden: true
@Semantics.text: true
_ControllingDocumentStatusTxt.StatusName,
@UI.hidden: true
CtrlgOverheadStatusCriticality,
@UI: { selectionField: [{ position: 90 }],
lineItem: [{ position: 50,
cssDefault: {width: '11rem'} }],
fieldGroup: [{ position: 10, qualifier: 'HeaderFacet2' }] }
@ObjectModel.text.element: [ 'AllocationPostingTypeText' ]
@Consumption.valueHelpDefinition: [{ entity: { name: 'R_CostAcctgDocPostgTypeDomain', element: 'AllocationPostingType' }}]
@UI.textArrangement: #TEXT_ONLY
AllocationPostingType,
@UI.hidden: true
@Consumption.filter.hidden: true
@Semantics.text: true
_AllocationPostingTypeTxt.AllocationPostingTypeText,
@Consumption.filter.hidden: true
@Semantics.text: true
cast(_ReferenceDocumentTypeText.ReferenceDocumentTypeName as fac_text_typ preserving type) as ReferenceDocumentTypeName,
@UI: {
fieldGroup: [{
qualifier: 'HeaderInfoGroup',
position: 25,
importance: #HIGH
}]
}
@Consumption.filter.selectionType: #INTERVAL
ExchangeRateDate,
@UI: {
fieldGroup: [{
qualifier: 'HeaderInfoGroup',
position: 60,
importance: #HIGH,
hidden: #(PrdcssrRefDocumentIsHidden)
}]
}
@EndUserText.label: 'Reposted Reference Document'
@EndUserText.quickInfo: 'Reposted Reference Document'
PredecessorReferenceDocument,
@UI.hidden: true
PredecessorReferenceDocType,
@UI.hidden: true
PredecessorReferenceDocCntxt,
@UI: {
fieldGroup: [{
qualifier: 'HeaderInfoGroup',
position: 60,
importance: #HIGH,
hidden: #(RvslReferenceDocumentIsHidden)
}]
}
ReversalReferenceDocument,
@UI: {
fieldGroup: [{
qualifier: 'HeaderInfoGroup',
position: 60,
importance: #HIGH,
hidden: #(RvsdReferenceDocumentIsHidden)
}]
}
ReversedReferenceDocument,
@Consumption.valueHelpDefinition: [{
entity: {
name: 'I_CurrencyStdVH',
element: 'Currency'
}
}]
@Semantics.currencyCode:true
GlobalCurrency,
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
@UI: { fieldGroup: [{qualifier: 'HeaderInfoGroup', position: 100, importance: #HIGH }] }
@EndUserText.label: 'Total Amount in Glob. Crcy'
@EndUserText.quickInfo: 'Total Amount in Global Currency'
TotalAmountInGlobalCurrency,
@UI: { fieldGroup: [{qualifier: 'HeaderInfoGroup', position: 110, importance: #HIGH, hidden: #(UICT_AcctgDocumentTypeIsHidden), groupLabel: 'Header Information' }],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_AccountingDocumentTypeStdVH', element: 'AccountingDocumentType' } }]
@ObjectModel.text.element: [ 'AccountingDocumentTypeName' ]
@UI.textArrangement: #TEXT_LAST
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM' }
AccountingDocumentType,
@Consumption.filter.hidden: true
@Semantics.text: true
_AccountingDocumentTypeText.AccountingDocumentTypeName,
@UI.hidden: true
ControllingBusTransacType,
//Field for Predecessor Fiscal Year
@UI.hidden: true
ReferenceFiscalYear,
@UI.hidden: true
CostAccountingDocumentAction,
@UI.hidden: true
CostAcctgDocumentActionSource,
@UI.hidden: true
LocalLastChangeDateTime,
@UI.hidden: true
LastChangeDateTime,
// Item fields for filtering
@UI: { fieldGroup: [{qualifier: 'HeaderInfoGroup', position: 60, importance: #HIGH, hidden: #(UICT_SuccssrRefDocIsHidden) }]}
@EndUserText.label: 'Reposting Reference Document'
@EndUserText.quickInfo: 'Reposting Reference Document'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT',
sort.enabled: false }
virtual SuccessorReferenceDocument : successorreferencedocument,
@UI: { selectionField: [{ position: 30 }] }
@Consumption.semanticObject: 'AccountingDocument'
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_JournalEntryVH', element: 'AccountingDocument' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual AccountingDocument : fis_belnr,
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}] }
@Consumption.semanticObject: 'CompanyCode'
@ObjectModel.text.element: [ 'CompanyCodeName' ]
@UI.textArrangement: #TEXT_LAST
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
@EndUserText.label: 'Receiver Company Code'
@EndUserText.quickInfo: 'Receiver Company Code'
virtual CompanyCode : fis_bukrs,
@UI.hidden: true
@Semantics.text: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual CompanyCodeName : butxt,
@UI: { fieldGroup: [{ qualifier: 'SendersGroup' }] }
@Consumption.semanticObject: 'CompanyCode'
@ObjectModel.text.element: [ 'SourceCompanyCodeName' ]
@UI.textArrangement: #TEXT_LAST
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual SenderCompanyCode : sendercompanycode,
@UI.hidden: true
@Semantics.text: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual SourceCompanyCodeName : butxt,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup', groupLabel: 'Receivers'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CostRevnReassgmtAllocAcctVH', element: 'GLAccount' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' }] }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual GLAccount : fco_allocation_account,
@UI: { fieldGroup: [{qualifier: 'SendersGroup', groupLabel: 'Senders'}],
lineItem: [{hidden: true}] }
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual AccountAssignment : accas,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'SendersGroup'}],
lineItem: [{hidden: true}] }
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual AccountAssignmentType : fis_accasty,
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual PartnerAccountAssignment : fis_paccas,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual PartnerAccountAssignmentType : fins_paccasty,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'SendersGroup'}],
selectionField: [{ position: 100 }],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CostCenterVH', element: 'CostCenter' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' }] }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual SenderCostCenter : sendercostcenter,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'SendersGroup'}],
selectionField: [{ position: 110 }],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CostCenterActivityTypeVH', element: 'CostCtrActivityType' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' }],
label: 'Activity Type Value Help' }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Sender Activity Type'
@EndUserText.quickInfo: 'Sender Activity Type'
virtual CostCtrActivityType : lstar,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CostCenterVH', element: 'CostCenter' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' }] }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Cost Center'
@EndUserText.quickInfo: 'Receiver Cost Center'
virtual PartnerCostCenter : fis_skost,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_WBSElementBasicDataStdVH', element: 'WBSElementExternalID' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver WBS Element'
@EndUserText.quickInfo: 'Receiver WBS Element'
virtual PartnerWBSElementExternalID : fis_par_psp_pnr_ext,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Project'
@EndUserText.quickInfo: 'Receiver Project'
virtual PartnerProjectExternalID : fis_part_projectext_no_conv,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_AcctgServiceDocumentTypeVH', element: 'ServiceDocumentType' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Service Doc. Type'
@EndUserText.quickInfo: 'Receiver Service Document Type'
virtual PartnerServiceDocumentType : fco_psrvdoc_type,
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_AcctgServiceDocumentVH', element: 'ServiceDocument' },
additionalBinding: [{ localElement: 'PartnerServiceDocumentType', element: 'ServiceDocumentType' }] }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Service Document'
@EndUserText.quickInfo: 'Receiver Service Document'
virtual PartnerServiceDocument : fco_psrvdoc_id,
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_AcctgServiceDocumentItemVH', element: 'ServiceDocumentItem' },
additionalBinding: [{ localElement: 'PartnerServiceDocumentType', element: 'ServiceDocumentType' },
{ localElement: 'PartnerServiceDocument', element: 'ServiceDocument' }] }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Service Doc. Item'
@EndUserText.quickInfo: 'Receiver Service Document Item'
virtual PartnerServiceDocumentItem : fco_psrvdoc_item_id,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProjectNetworkStdVH', element: 'ProjectNetwork' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Project Network'
@EndUserText.quickInfo: 'Receiver Project Network'
virtual PartnerProjectNetwork : par_npln,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_NetworkActivityValueHelp', element: 'NetworkActivity' },
additionalBinding: [{ localElement: 'PartnerProjectNetwork', element: 'ProjectNetwork' }] }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Project Network Activity'
@EndUserText.quickInfo: 'Receiver Project Network Activity'
virtual PartnerProjectNetworkActivity : fis_par_vornr_auf_no_conv,
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_OrderMasterVH', element: 'OrderID' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Order'
@EndUserText.quickInfo: 'Receiver Order'
virtual PartnerOrder : fis_par_aufnr,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CostCenterActivityTypeVH', element: 'CostCtrActivityType' }}]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Activity Type'
@EndUserText.quickInfo: 'Receiver Activity Type'
virtual PartnerCostCtrActivityType : fis_par_lstar,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@EndUserText.label: 'Receiver Cost Object'
@EndUserText.quickInfo: 'Receiver Cost Object'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual PartnerCostObject : par_kstrg,
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_CostRevnReassgmtSalesDocVH', element: 'SalesDocument' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Sales Document'
@EndUserText.quickInfo: 'Receiver Sales Document'
virtual PartnerSalesDocument : fis_par_kdauf,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_SalesDocumentItemStdVH', element: 'SalesDocumentItem' },
additionalBinding: [{ localElement: 'PartnerSalesDocument', element: 'SalesDocument' }] }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Sales Doc. Item'
@EndUserText.quickInfo: 'Receiver Sales Document Item'
virtual PartnerSalesDocumentItem : fis_par_kdpos,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'C_WorkItemVH', element: 'WorkItem' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual WorkItem : /cpd/pfp_workitem_id,
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_WorkAssignmentsVH', element: 'WorkAssignment' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual PersonnelNumber : pernr_d,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_BusinessProcessStdVH', element: 'BusinessProcess' },
additionalBinding: [{ localElement: 'ControllingAreaForEdit', element: 'ControllingArea' }] }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual PartnerBusinessProcess : par_prznr,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'SendersGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_FundStdVH', element: 'Fund' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual Fund : fm_sfonds,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'SendersGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_FndsMgmtFuncnlAreaStdVH', element: 'FunctionalArea' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual FunctionalArea : fm_sfarea,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'SendersGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_GrantStdVH', element: 'GrantID' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual GrantID : gm_grant_sender,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'SendersGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_BudgetPeriodStdVH', element: 'BudgetPeriod' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Sender Budget Period'
@EndUserText.quickInfo: 'Sender Budget Period'
virtual BudgetPeriod : fm_budget_period,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_FundStdVH', element: 'Fund' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual PartnerFund : fm_efonds,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_FndsMgmtFuncnlAreaStdVH', element: 'FunctionalArea' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Functional Area'
@EndUserText.quickInfo: 'Receiver Functional Area'
virtual PartnerFunctionalArea : fm_efarea,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_GrantStdVH', element: 'GrantID' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual PartnerGrant : gm_grant_receiver,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_BudgetPeriodStdVH', element: 'BudgetPeriod' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Budget Period'
@EndUserText.quickInfo: 'Receiver Budget Period'
virtual PartnerBudgetPeriod : fm_pbudget_period,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_PlantStdVH', element: 'Plant' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual Plant : werks_d,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_ProductVH', element: 'Product' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual Product : productnumber,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [ { entity: { name: 'C_ControllingBillableControlVH', element: 'BillableControl' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Accounting Indicator'
@EndUserText.quickInfo: 'Receiver Accounting Indicator'
virtual BillableControl : fis_bemot,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_JntVntrRecoveryIndVH', element: 'JointVentureRecoveryCode' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@Feature: 'BF:JOINT_VENTURE_ACCOUNTING'
@EndUserText.label: 'Receiver Recovery Indicator'
@EndUserText.quickInfo: 'Receiver Recovery Indicator'
virtual PartnerCostRecoveryCode : jv_recind_cds,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'SendersGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_JntVntrRecoveryIndVH', element: 'JointVentureRecoveryCode' } }]
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@Feature: 'BF:JOINT_VENTURE_ACCOUNTING'
@EndUserText.label: 'Sender Recovery Indicator'
@EndUserText.quickInfo: 'Sender Recovery Indicator'
virtual SenderCostRecoveryCode : jv_srecind_cds,
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Semantics.booleanIndicator
@Consumption.filter.selectionType: #SINGLE
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@EndUserText.label: 'Receiver Profitability Sgmt Is Assigned'
@EndUserText.quickInfo: 'Receiver Profitability Segment Is Assigned'
virtual PartProfitabilitySgmtIsAssgd : profitabilitysegmentisassigned,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@EndUserText.label: 'Receiver Order Operation'
@EndUserText.quickInfo: 'Receiver Order Operation'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual OrderOperation : vdm_vornr,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
@EndUserText.label: 'Receiver Real Estate Company Code'
@EndUserText.quickInfo: 'Receiver Real Estate Company Code'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual ReceiverRECompanyCode : pbukrs,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_REBusinessEntityVH', element: 'REBusinessEntity' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' }] }]
@EndUserText.label: 'Receiver Real Estate Business Entity'
@EndUserText.quickInfo: 'Receiver Real Estate Business Entity'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual REPartnerBusinessEntity : rebdvdmpbeno,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_REBuildingVH', element: 'RealEstateBuilding' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' }] }]
@EndUserText.label: 'Receiver Real Estate Building'
@EndUserText.quickInfo: 'Receiver Real Estate Building'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual RealEstatePartnerBuilding : rebdvdmpbuno,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_REPropertyVH', element: 'RealEstateProperty' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' }] }]
@EndUserText.label: 'Receiver Real Estate Property'
@EndUserText.quickInfo: 'Receiver Real Estate Property'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual RealEstatePartnerProperty : rebdvdmpprno,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_RERentalObjectVH', element: 'RERentalObject' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity'},
{ localElement: 'RealEstatePartnerBuilding', element: 'RealEstateBuilding' },
{ localElement: 'RealEstatePartnerProperty', element: 'RealEstateProperty' }] }]
@EndUserText.label: 'Receiver Real Estate Rental Object'
@EndUserText.quickInfo: 'Receiver Real Estate Rental Object'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual REPartnerRentalObject : rebdvdmprono,
@ObjectModel.text.element: [ 'UICT_Text' ]
@UI.textArrangement: #TEXT_LAST
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_REContractVH', element: 'RealEstateContract' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' }] }]
@EndUserText.label: 'Receiver Real Estate Contract'
@EndUserText.quickInfo: 'Receiver Real Estate Contract'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual RealEstatePartnerContract : recnvdmpcnnr,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_RESettlementUnitVH', element: 'REServiceChargeKey' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' }] }]
@EndUserText.label: 'Receiver Real Estate Service Charge Key'
@EndUserText.quickInfo: 'Receiver Real Estate Service Charge Key'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual REPartnerServiceChargeKey : rescvdmpsckey,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_RESettlementUnitVH', element: 'RESettlementUnitID' },
additionalBinding: [{ localElement: 'ReceiverRECompanyCode', element: 'CompanyCode' },
{ localElement: 'REPartnerBusinessEntity', element: 'REBusinessEntity' },
{ localElement: 'REPartnerServiceChargeKey', element: 'REServiceChargeKey' }] }]
@EndUserText.label: 'Receiver Real Estate Settlement Unit'
@EndUserText.quickInfo: 'Receiver Real Estate Settlement Unit'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual REPartnerSettlementUnitID : rescvdmpsuid,
@Feature:'NOT SW:FINS_PARALLEL_ACCOUNTING_RS'
@UI: { fieldGroup: [{qualifier: 'ReceiversGroup'}],
lineItem: [{hidden: true}] }
@Consumption.filter.selectionType: #INTERVAL
@EndUserText.label: 'Receiver Real Estate Settlement Reference Date'
@EndUserText.quickInfo: 'Receiver Real Estate Settlement Reference Date'
@ObjectModel: { filter.transformedBy: 'ABAP:CL_COSTACCTGDOC_FLTR_TRANSFORM',
virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual PartnerSettlementReferenceDate : fins_par_dabrbez,
@UI.hidden: true
@Feature: 'SW:FINS_PARALLEL_ACCOUNTING_RS'
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual ParallelAccountingIsActive : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual PrdcssrRefDocumentIsHidden : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual RvslReferenceDocumentIsHidden : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual RvsdReferenceDocumentIsHidden : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual UICT_OriginalItemsTabIsHidden : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual UICT_JournalEntriesTabIsHidden : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual UICT_JournalEntryIsMultiple : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual UICT_CompanyCodeIsMultiple : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual UICT_SndrCompanyCodeIsMultiple : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual UICT_AcctgDocHeaderTxtIsHidden : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual UICT_AcctgDocumentTypeIsHidden : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual UICT_SuccssrRefDocIsHidden : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual UICT_SuccssrRefDocIsMultiple : abap_boolean,
@UI.hidden: true
@Semantics.text: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
virtual UICT_Text : abap.char( 50 ),
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COSTACCTGDOC_SADL_EXIT' }
@UI.identification: [{ type: #FOR_ACTION, dataAction: 'Repost', label: 'Repost', position: 20 }]
@UI.lineItem: [{ type: #FOR_ACTION, dataAction: 'Repost', label: 'Repost', position: 15, invocationGrouping: #CHANGE_SET, hidden: true }]
virtual UICT_Repost : abap_boolean,
@UI.hidden: true
@ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COST_ACCTG_POSTG_SADL_EXIT' }
virtual UICT_ControllingAreaIsHidden : abap_boolean,
/* Associations */
_Item : redirected to composition child C_DrctActivityAllocationItemTP,
_OriginalItem,
_JournalEntry,
_ReceiverCompanyCode,
_SenderCompanyCode,
_SuccessorReferenceDocument,
@Consumption.filter.hidden: true
_CreatedByContactCard
}