C_DemandDrivenBOMComponents

@AbapCatalog.sqlViewName: 'CDDBOMCOMP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Lists out BOM Components'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #X, sizeCategory: #XXL, dataClass: #MIXED}
@VDM.viewType: #CONSUMPTION
@Hierarchy.parentChild: [{ recurse: {parent: 'Material', child: 'BillOfMaterialComponent'} }]
define view C_DemandDrivenBOMComponents
  as select from I_DemandDrivenMaterialData as _DemandDrivenMaterialData
  inner join   I_SDMAreaOfResponsibility as _SDMAreaOfResponsibility on  _DemandDrivenMaterialData.Plant          = _SDMAreaOfResponsibility.Plant
                                                                       and _DemandDrivenMaterialData.MRPController  = _SDMAreaOfResponsibility.MRPController
                                                                       and _SDMAreaOfResponsibility.UserID = $session.user
  association [0..*] to C_DmndDrivenSupDmndList     as _SupDmndList    on  $projection.Material = _SupDmndList.Material
                                                                       and $projection.Plant    = _SupDmndList.Plant
                                                                       and $projection.MRPArea  = _SupDmndList.MRPArea
  association [1..*] to C_ProductStockRqmtListChart as _BufferedChart  on  $projection.Material = _BufferedChart.Material
                                                                       and $projection.Plant    = _BufferedChart.Plant
                                                                       and $projection.MRPArea  = _BufferedChart.MRPArea
  association [1..*] to C_DDProjtdStkChart          as _ProjtdStkChart on  $projection.Material = _ProjtdStkChart.Material
                                                                       and $projection.Plant    = _ProjtdStkChart.Plant
                                                                       and $projection.MRPArea  = _ProjtdStkChart.MRPArea
  association [0..*] to C_ProductPlantTextInfo      as _Note           on  $projection.Material = _Note.Product
                                                                       and $projection.Plant    = _Note.Plant
  association [1..*] to I_ProductUnitsOfMeasure     as _Unit           on  $projection.Material = _Unit.Product
  association [0..*] to C_DDMaterialSOS             as _MatSOS         on  $projection.Material = _MatSOS.Material
                                                                       and $projection.Plant    = _MatSOS.Plant
                                                                       and $projection.MRPArea  = _MatSOS.MRPArea
  association [1..1] to C_ProductInformation        as _ProductInfo    on  $projection.Material = _ProductInfo.Material
                                                                       and $projection.Plant    = _ProductInfo.Plant
                                                                       and $projection.MRPArea  = _ProductInfo.MRPArea
  association [0..*] to C_DmndDrivenSupOrder        as _DDOrderCRUD    on  $projection.Material = _DDOrderCRUD.Material
                                                                       and $projection.Plant    = _DDOrderCRUD.Plant
                                                                       and $projection.MRPArea  = _DDOrderCRUD.MRPArea
  association [0..*] to C_DDOrderDetails            as _DDOrderDetails on  $projection.Material = _DDOrderDetails.Material
                                                                       and $projection.Plant    = _DDOrderDetails.Plant
{
  key _DemandDrivenMaterialData.Material,
  key _DemandDrivenMaterialData.Plant,
  key MRPArea,
      Material                                        as BillOfMaterialComponent,
      cast('' as maktx)                               as MaterialName,
      _MRPType.MRPType                                as MRPType,
      cast('' as dibez)                               as MRPTypeName,
      _MRPType.MRPProcedure                           as MRPProcedure,
      _DemandDrivenMaterialData.MRPController        as MRPController,
      cast(0 as abap.int4)                            as BillOfMaterialItemNodeNumber,
      cast(0 as abap.int4)                            as BOMExplosionLevel,
      cast(0 as abap.int4)                            as ParentNode,
      cast('expanded' as dtinf_hierarchy_drill_state) as DemandDrivenBOMCompDrillState,
      0                                               as BOMItemNodeCount,
      0                                               as SolutionRank,
      cast('' as abap.char( 1 ))                      as MaterialShortageStatus,
      cast('' as abap.char( 60 ))                     as BOMItemReferenceID,
      cast('' as abap.char( 60 ))                     as MaterialBOMObjectID,
      cast(0 as pph_decoupled_leadtime)               as DecoupledLeadTime,
      cast(0 as pph_ind_lead_time)                    as IndividualLeadTime,
      IsBulkMaterial,
      IsPhantomItem,
      _DemandDrivenMaterialData.MRPMaterialStatus,
      _DemandDrivenMaterialData._MatStatus[MRPMaterialStatus = _DemandDrivenMaterialData.MRPMaterialStatus].MRPMaterialStatusName,
      _Note,
      _Unit,
      _SupDmndList,
      //_ProductInfo,

      _DDOrderCRUD,
      _MatSOS,
      _DDOrderDetails
}