C_DefectTaskFDP

@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@EndUserText.label: 'FDP view for QM Defect Task'
@VDM: {
    viewType: #CONSUMPTION,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
    [ #OUTPUT_FORM_DATA_PROVIDER ]
@ObjectModel.modelingPattern: #OUTPUT_FORM_DATA_PROVIDER
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #D },
    representativeKey: 'QualityTaskInternalId',
    semanticKey:  [ 'QualityTask' ]
}    
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@Consumption.semanticObject: 'Defect'
     
define view entity C_DefectTaskFDP as select from I_QualityTask as _QualityTask

    association [0..1] to C_DefectFDP               as _Defect                        on $projection.DefectInternalID = _Defect.DefectInternalID
    
    // new associations for text fields

    association [0..*] to I_UnitOfMeasureText       as _TimeBasedEffortUnitText       on $projection.QltyTaskTimeBasedEffortUoM = _TimeBasedEffortUnitText.UnitOfMeasure
    
{
  key _QualityTask.QualityTaskInternalId,

  _QualityTask.QualityTask,
  _QualityTask.QualityTaskOrigin,
  _QualityTaskOrigin._Text[ 1: Language = $session.system_language ].QualityTaskOriginText,
  @Semantics.text: true
  _QualityTask.QualityTaskText,
  _QualityTask.QualityTaskProcessor,
  _QualityTaskProcessor.FullName as QualityTaskProcessorFullName,
  cast( _QualityTask.MasterLanguage as vdm_j_masterlanguage ) as MasterLanguage,
  _QualityTask.NotifTaskCompletedByUser,
  // TODO: UserDescription/ FullName

  _QualityTask.QualityTaskType,
  _QualityTaskType._QualityTaskTypeText[ 1: Language = $session.system_language ].QualityTaskTypeText,
  _QualityTask.QualityTaskCodeCatalog,
  _QualityTask.QualityTaskCodeGroup,
  _QltyTskCodeGroup._QltyTskCodeGroupText[ 1: Language = $session.system_language ].QualityTaskCodeGroupText,
  _QualityTask.QualityTaskCode,
  _QltyTskCode._QltyTskCodeText[ 1: Language = $session.system_language ].QualityTaskCodeText,
  _QualityTask.NotifTaskTimeZone,
  _QualityTask.NotifTaskPlannedEndDate,
  _QualityTask.NotifTaskPlannedEndTime,
  _QualityTask.NotifTaskCompletionDate,
  _QualityTask.NotifTaskCompletionTime,
  @Consumption.hidden: true
  _QualityTask.NotifTaskResubmissionDate,
  @Consumption.hidden: true
  _QualityTask.NotifTaskResubmissionTime,
  @ObjectModel.foreignKey.association: '_Defect'
  @Consumption.hidden: true
  _QualityTask.DefectInternalID,
  _QualityTask.QltyTaskFollowUpAction,
  _QltyTaskFollowUpAction._QltyTaskFollowUpActionText[ 1: Language = $session.system_language ].QltyTaskFollowUpActionText,
  _QualityTask.QualityTaskLifecycleStatus,
  _QualityTaskStatus._QualityTaskStatusText[ 1: Language = $session.system_language ].QualityTaskLifecycleStatusText,
  @Consumption.hidden: true
  _QualityTask.QualityTaskArchivingStatus,
  _QualityTask.QltyTaskFllwUpActionSts,
  _QltyTaskFllwUpActionSts._QltyTaskFllwUpActionStsTxt[ 1: Language = $session.system_language ].QltyTaskFllwUpActionStsTxt,
  _QualityTask.CreatedByUser,
  cast( _CreatedByUserContactCard.FullName as vdm_createdbyuserdescription preserving type ) as CreatedByUserDescription,
  _QualityTask.CreationDate,
  _QualityTask.CreationTime,
  @Consumption.hidden: true
  _QualityTask.ChangedDateTime,
  _QualityTask.LastChangeDate,
  _QualityTask.LastChangeTime,
  _QualityTask.LastChangedByUser,
  cast( _LastChangedByUserContactCard.FullName as vdm_lastchangedbyuserdescripti preserving type ) as LastChangedByUserDescription,
  @Semantics.quantity.unitOfMeasure: 'QltyTaskTimeBasedEffortUoM'
  QltyTaskTimeBasedEffort,
  @ObjectModel.text.association: '_TimeBasedEffortUnitText'
  QltyTaskTimeBasedEffortUoM,
  
  /* Associations */
  _Defect,
  _TimeBasedEffortUnitText
  
} where QualityTaskOrigin = '01' // Only tasks related to a defect

    and IsDeleted is initial