C_DefectMngQltyNotificationVH

@AbapCatalog.sqlViewName: 'CDEFECTMNGQNVH'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUserContactCard']

@EndUserText.label: 'Quality Notification'

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION

@ObjectModel.representativeKey: 'QualityNotification'
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #C
}
@ObjectModel.dataCategory: #VALUE_HELP
@Search.searchable: true
@Consumption.ranked: true

define view C_DefectMngQltyNotificationVH as select from I_QltyNotification 

{

    @UI: {
        lineItem: [{ position: '10' }],
        selectionField: [{ position: '10' }],
        textArrangement: #TEXT_LAST
    }
    @ObjectModel.text.element: ['NotificationText']
    @Consumption.semanticObject: 'QualityNotification'
    @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
    key QualityNotification,

    @UI: {
        lineItem: [{ position: '20' }],
        selectionField: [{ position: '20' }]
    }
    @Consumption.valueHelpDefinition: [
        {
            entity: {
                name: 'I_QltyNotificationTypeVH',
                element: 'NotificationType'
            }
        }
    ]
    NotificationType,

    @UI: {
        lineItem: [{ position: '30' }],
        selectionField: [{ position: '30' }]
    }
    @Consumption.defaultValue: '1'
    @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW } 
    NotifProcessingPhase,

    @UI: {
        lineItem: [{ position: '40' }],
        selectionField: [{ position: '40' }]
    }
    @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW }
    NotificationText,

    @Consumption.hidden: true
    IsBusinessPurposeCompleted,

    @UI: {
        lineItem: [{ position: '50' }],
        selectionField: [{ position: '50' }]
    }
    @UI.hidden: true
    NotificationCatalog,

    @Consumption.valueHelpDefinition: [
         { entity: { name: 'I_NotificationCodeGroupVH', element: 'NotificationCodeGroup' } },
         { additionalBinding: [{ element: 'NotificationCatalog', localElement: 'NotificationCatalog' }] }
    ]
    @UI: {
        lineItem: [{ position: '60' }],
        selectionField: [{ position: '60' }]
    }
    @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW }
    NotificationCodeGroup,

    @Consumption.valueHelpDefinition: [
         { entity: { name: 'I_NotificationCodeVH', element: 'NotificationCodeID' } },
         { additionalBinding: [
             { element: 'NotificationCatalog', localElement: 'NotificationCatalog' },
             { element: 'NotificationCodeGroup', localElement: 'NotificationCodeGroup' }
           ]}
    ]
    @UI: {
        lineItem: [{ position: '70' }],
        selectionField: [{ position: '70' }]
    }
    @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW }
    NotificationCodeID,

    @ObjectModel: {  text.element:  [ 'MaterialName' ] }
    @Consumption.valueHelpDefinition: [
         { entity: { name: 'I_ProductVH', element: 'Product' } }
    ]
    @UI: {
        lineItem: [{ position: '80' }],
        selectionField: [{ position: '80' }]
    }
    @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW }
    Material,
    
    @Semantics.text: true
    @UI.hidden: true
    _Product._Text[1:Language=$session.system_language].ProductName as MaterialName,

    @ObjectModel: {
      foreignKey.association: null,  
      text.element:  [ 'PlantName' ] 
    }
    @Consumption.valueHelpDefinition: [
         { entity: { name: 'I_PlantStdVH', element: 'Plant' } }
    ]
    @UI: {
        lineItem: [{ position: '90' }],
        selectionField: [{ position: '90' }]
    }
    @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW } 
    Plant,
    
    @Semantics.text: true
    @UI.hidden: true
    _Plant.PlantName,
    
    @Consumption.valueHelpDefinition: [
         { entity: { name: 'I_Supplier_VH', element: 'Supplier' } }
    ]
    Supplier,
    
    @Consumption.valueHelpDefinition: [
         { entity: { name: 'I_Customer_VH', element: 'Customer' } }
    ]
    Customer,
    
    CreatedByUser,
    CreationDate,
    LastChangedDate,

    @Consumption.filter.hidden: true
    _Product,
    @Consumption.filter.hidden: true
    _NotificationType,
    @Consumption.filter.hidden: true
    _NotifProcessingPhase,
    @Consumption.filter.hidden: true
    _NotificationCatalog,
    @Consumption.filter.hidden: true
    _NotificationCodeGroup,
    @Consumption.filter.hidden: true
    _NotificationCode,
    @Consumption.filter.hidden: true
    _Plant,
    @Consumption.filter.hidden: true
    _Supplier,
    @Consumption.filter.hidden: true
    _CreatedByUserContactCard

}