C_DefectMngInspectionSubset

@AbapCatalog.sqlViewName: 'CDEFECTINSPSBST'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #L, //expected number of rows < 100.000

    serviceQuality: #C // includes A,B as well

    }
@EndUserText.label: 'Defects Inspection Subset'

@Consumption.semanticObject: 'InspectionSubset'
define view C_DefectMngInspectionSubset
  as select distinct from I_InspectionSubset as _InspectionSubset

  association [1..1] to I_InspectionLot              as _InspectionLot              on $projection.InspectionLot = _InspectionLot.InspectionLot

  association [0..1] to I_InspSubsetFieldCombination as _InspSubsetFieldCombination on $projection.InspSubsetFieldCombination = _InspSubsetFieldCombination.InspSubsetFieldCombination

{


      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_InspectionLotStdVH',
                     element: 'InspectionLot' }
        }]
      // ]--GENERATED

       @ObjectModel.foreignKey.association: '_InspectionLot'     
  key  InspectionLot,

       @UI.hidden: true
  key  InspectionSubsetInternalID,

      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_InspectionOperationStdVH',
                     element: 'InspPlanOperationInternalID' },
          additionalBinding: [{ localElement: 'InspectionLot',
                                element: 'InspectionLot' }]
        }]
      // ]--GENERATED

       @UI.hidden: true
  key  InspPlanOperationInternalID,

       @ObjectModel: {
         readOnly: true,
         virtualElement: true,
         virtualElementCalculatedBy: 'ABAP:cl_qm_defect_manage_exit'
       }
       @UI.fieldGroup: [{position: '10', qualifier: 'InspSbst1'}]
       @EndUserText.label: 'Inspection Point'
       cast('' as qpruefpkt)                                                                                               as  InspectionSubset,

       @EndUserText.label: 'Inspection Operation'
       @UI.fieldGroup: [{position: '20', qualifier: 'InspSbst1'}]
       concat_with_space(_InspectionOperation.InspectionOperation,  _InspectionOperation.OperationText, 3 )                as  OperationText,


       _InspectionOperation.InspectionOperation,

       @EndUserText.label: 'Inspection Point Type'
       @ObjectModel.text.element:  [ 'InspSubsetFldCombinationTxt' ]
       _InspectionLot.InspSubsetFieldCombination                                                                           as  InspSubsetFieldCombination,

       @UI.hidden: true
       _InspectionLot._InspSubsetFieldCombination._Text[1:Language = $session.system_language].InspSubsetFldCombinationTxt as  InspSubsetFldCombinationTxt,

       @ObjectModel.text.element:  [ 'UsageDecisionCodeText' ]
       @UI.fieldGroup: [{position: '20', qualifier: 'InspSbst2'}]
       @EndUserText.label: 'Inspection Point Usage Decision'
       @UI.textArrangement: #TEXT_LAST
       _InspectionSubset.InspSubsetUsageDcsnCode,

       @UI.hidden: true
       _InspectionSubset._UsageDecisionCode.UsageDecisionCodeText                                                          as  UsageDecisionCodeText,


       @ObjectModel.text.association: '_InspSubsetUsageDcsnValnTxt'
       @UI.fieldGroup: [{position: '10', qualifier: 'InspSbst2', criticality: 'InspSbstUsgeValnCriticality' }]
       @EndUserText.label: 'Valuation'
       @UI.textArrangement: #TEXT_LAST
       _InspectionSubset.InspSubsetUsageDcsnValuation,

       @UI.hidden: true
       case _InspectionSubset.InspSubsetUsageDcsnValuation
       /* 'Neutral' is reflected by 0, 'Negative' is reflected by 1, the value 'Critical' by 2, and the value 'Positive' by 3.*/
       when 'A' then 3 // 2=Released --> 3=Positive

       when 'R' then 1 // 3=Can no longer be used --> 1=Negative

       else 0
       end                                                                                                                 as  InspSbstUsgeValnCriticality,

       @ObjectModel.readOnly: 'EXTERNAL_CALCULATED'
       MaterialSample,

       @ObjectModel.readOnly: 'EXTERNAL_CALCULATED'
       Equipment,

       @ObjectModel.readOnly: 'EXTERNAL_CALCULATED'
       FunctionalLocation,

       @ObjectModel.readOnly: 'EXTERNAL_CALCULATED'
       _InspectionSubset.InspSubsetLongNumericKey,

       @ObjectModel.readOnly: 'EXTERNAL_CALCULATED'
       _InspectionSubset.InspSubsetShortNumericKey,

       @ObjectModel.readOnly: 'EXTERNAL_CALCULATED'
       _InspectionSubset.InspectionSubsetLongCharKey,

       @ObjectModel.readOnly: 'EXTERNAL_CALCULATED'
       _InspectionSubset.InspectionSubsetShortCharKey,

       @UI.hidden: true
       InspSbstShrtTxtFldProperty,

       @ObjectModel.readOnly: 'EXTERNAL_CALCULATED'
       _InspectionSubset.InspectionSubsetDate,


       case _InspectionSubset.InspectionSubsetTime
            when '' then '000000'
            else _InspectionSubset.InspectionSubsetTime
       end                                                                                                                 as  InspectionSubsetTime,

        //-- fields needed for authority check       

       @Consumption.hidden: true
       _InspectionOperation,
       
  



       //Association

       @Consumption.filter.hidden: true
       _InspectionLot,
       @Consumption.filter.hidden: true
       _InspSubsetFieldCombination,
       @Consumption.filter.hidden: true
       _InspSubsetUsageDcsnValn,
       @Consumption.filter.hidden: true
       _InspSubsetUsageDcsnValnTxt

}