C_CustomerProjectDetails

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CCUSTPROJDETAILS'
@EndUserText.label: 'Customer Project Details'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED

@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define view C_CustomerProjectDetails
  as select from           I_CustomerProject           as CustomerProject
    left outer to one join C_EngagementProjectPlanData as EngagementProjectPlanData on EngagementProjectPlanData.EngagementProject = CustomerProject.CustomerProject
    left outer join        I_Customer                  as Customer                  on CustomerProject.Customer = Customer.Customer
  association [0..*] to I_PersnWrkAgreementDet         as _PersonWorkAgreement          on  $projection.CustProjMgrPersonnelNumber = _PersonWorkAgreement.PersonWorkAgreement
  association [1..1] to I_EngagementProjectStage       as _CustomerProjectStage         on  $projection.CustomerProjectStage = _CustomerProjectStage.EngagementProjectStage
  association [0..*] to I_CostCenter                   as _CostCenter                   on  $projection.CostCenter               =  _CostCenter.CostCenter
                                                                                        and $projection.ControllingArea          =  _CostCenter.ControllingArea
                                                                                        and $projection.CustomerProjectStartDate >= _CostCenter.ValidityStartDate
                                                                                        and $projection.CustomerProjectStartDate <= _CostCenter.ValidityEndDate
  association [0..*] to I_ProfitCenter                 as _ProfitCenter                 on  $projection.ProfitCenter             =  _ProfitCenter.ProfitCenter
                                                                                        and $projection.ControllingArea          =  _ProfitCenter.ControllingArea
                                                                                        and $projection.CustomerProjectStartDate >= _ProfitCenter.ValidityStartDate
                                                                                        and $projection.CustomerProjectStartDate <= _ProfitCenter.ValidityEndDate
  association [1..1] to I_EngagementProjectSrvcOrg     as _EngmntProjSrvcOrgDetails     on  $projection.CustomerProjectServiceOrg = _EngmntProjSrvcOrgDetails.EngagementProjectServiceOrg
  association [1..*] to I_EngagementProjectSrvcOrgDets as _EngagementProjectSrvcOrgDets on  $projection.CustomerProjectServiceOrg                  = _EngagementProjectSrvcOrgDets.EngagementProjectServiceOrg
                                                                                        and _EngagementProjectSrvcOrgDets.AssignedOrganisationType = 'CA'
  association [1..1] to I_Currency                     as _Currency                     on  $projection.Currency = _Currency.Currency
  association [1..1] to I_Address                      as _Address                      on  Customer.AddressID = _Address.AddressID
  association [1..1] to C_CustomerProjectPlndActlData  as _CustomerProjectPlndActlData  on  $projection.CustomerProject = _CustomerProjectPlndActlData.CustomerProject

  association [1..1] to I_EngmntProjCustInfo           as _Customer                     on  CustomerProject.Customer = _Customer.Customer
  
  //Expose association for DCL checks

  association [1..1] to I_EngagementProject            as _EngagementProject            on $projection.CustomerProject = _EngagementProject.EngagementProject
{
  key    CustomerProject.CustomerProjectUUID                                                                                as                                                     CustomerProjectUUID,
  key    CustomerProject.CustomerProject                                                                                    as                                                     CustomerProject,
         CustomerProject.CustomerProjectServiceOrg                                                                          as                                                     CustomerProjectServiceOrg,
         CustomerProject.CustomerProjectType                                                                                as                                                     CustomerProjectType,
         CustomerProject.CustProjFinancialPlanUUID                                                                          as                                                     CustProjFinancialPlanUUID,
         CustomerProject.CustomerProjectVisibility                                                                          as                                                     CustomerProjectVisibility,

         CustomerProject.CustomerProjectStage                                                                               as                                                     CustomerProjectStage,
      //--[ GENERATED:012:GlBfhyJl7kY4nRd09JNw30

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CostCenterStdVH',
                     element: 'CostCenter' },
          additionalBinding: [{ localElement: 'ControllingArea',
                                element: 'ControllingArea' },
                              { localElement: 'CustomerProjectStartDate',
                                element: 'ValidityStartDate' },
                              { localElement: 'CustomerProjectStartDate',
                                element: 'ValidityEndDate' }]
        }]
      // ]--GENERATED

         CustomerProject.CostCenter                                                                                         as                                                     CostCenter,
      //--[ GENERATED:012:GlBfhyJl7kY4nRd09JNw30

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_ProfitCenterStdVH',
                     element: 'ProfitCenter' },
          additionalBinding: [{ localElement: 'ControllingArea',
                                element: 'ControllingArea' },
                              { localElement: 'CustomerProjectStartDate',
                                element: 'ValidityStartDate' },
                              { localElement: 'CustomerProjectStartDate',
                                element: 'ValidityEndDate' }]
        }]
      // ]--GENERATED

         CustomerProject.ProfitCenter                                                                                       as                                                     ProfitCenter,

         _EngagementProjectSrvcOrgDets.AssignedOrganisation                                                                 as                                                     ControllingArea,
         CustomerProject.CustomerProjectName                                                                                as                                                     CustomerProjectName,
         
       @Semantics.currencyCode: true
         CustomerProject.Currency                                                                                           as                                                     Currency,
      //--[ GENERATED:012:GlBfhyJl7kY4nRd09JNw30

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_EngmntProjCustInfoStdVH',
                     element: 'Customer' }
        }]
      // ]--GENERATED

         CustomerProject.Customer                                                                                           as                                                     Customer,
         _Address.AddressID                                                                                                 as                                                     AddressID,
         @Semantics.dateTime:true
         @Semantics.systemDateTime.lastChangedAt:true
         CustomerProject.LastChangeDateTime                                                                                 as                                                     LastChangeDateTime,
         Customer.CustomerName                                                                                              as                                                     CustomerName,
         Customer.OrganizationBPName1                                                                                       as                                                     OrganizationBPName1,
         Customer.OrganizationBPName2                                                                                       as                                                     OrganizationBPName2,
         CustomerProject.CustProjMgrPersonnelNumber                                                                         as                                                     CustProjMgrPersonnelNumber,
         _PersonWorkAgreement._WorkforcePerson.PersonFullName                                                               as                                                     CustomerProjectManagerName,
         CustomerProject.CustomerProjectStartDate                                                                           as                                                     CustomerProjectStartDate,
         CustomerProject.CustomerProjectEndDate                                                                             as                                                     CustomerProjectEndDate,
         _PersonWorkAgreement._WorkforcePerson.Person                                                                       as                                                     PersonnelNumber,
         _PersonWorkAgreement._WorkforcePerson.UserID                                                                       as                                                     BusinessUser,
         _PersonWorkAgreement._WorkforcePerson.PersonExternalID                                                             as                                                     Employee,

         1                                                                                                                  as                                                     CustProjWrkPckgPlanMarginPct,
         @Semantics.unitOfMeasure: true
         cast('%' as abap.unit( 3 ))  
         
                                                                                                                            as                                                      UnitOfMeasure,
          @Semantics.amount.currencyCode: 'Currency'
         _CustomerProjectPlndActlData.CustProjWrkPckgActualRevenue                                                          as                                                     CustProjWrkPckgActualRevenue,
         @Semantics.amount.currencyCode: 'Currency'
         _CustomerProjectPlndActlData.ActualCost                                                                            as                                                     ActualCost,

         1                                                                                                                  as                                                     CustProjWrkPckgActualMarginPct,


         1                                                                                                                  as                                                     CompletionRateInPercent,


         @Semantics.amount.currencyCode: 'Currency'
         EngagementProjectPlanData.PlndCostAmt                                                                              as                                                     CustProjWrkPckgPlanCost,
         
         @Semantics.amount.currencyCode: 'Currency'
         EngagementProjectPlanData.PlndRevnAmt                                                                              as                                                     CustProjWrkPckgPlanRevenue,
         @Semantics.quantity.unitOfMeasure:'UnitOfMeasure'
         EngagementProjectPlanData.PlndEffortQty                                                                            as                                                     CustProjWrkPckgPlanEffortQty,
         _Address.CityName                                                                                                  as                                                     CityName,
         _Address.Country                                                                                                   as                                                     Country,
         _CustomerProjectStage,
         _CostCenter,
         _EngmntProjSrvcOrgDetails,
         _Currency,
         _ProfitCenter,
         _Customer,
         _PersonWorkAgreement,
         _EngagementProject
        
}