C_Customer360InvoiceList

DDL: C_CUSTOMER360INVOICELIST Type: view_entity CONSUMPTION Package: ODATA_SD_ADVNCD_CUSTOMER360

Customer 360 Invoice List

C_Customer360InvoiceList is a Consumption CDS View that provides data about "Customer 360 Invoice List" in SAP S/4HANA. It reads from 2 data sources (I_Customer360BusDocSetting, I_BillingDocumentBasic) and exposes 12 fields with key field BillingDocument. It is exposed through 1 OData service (SD_ADVNCD_CUSTOMER360). Part of development package ODATA_SD_ADVNCD_CUSTOMER360.

2 data source(s) Exposed by 1 service(s) 12 fields

Data Sources (2)

SourceAliasJoin Type
I_Customer360BusDocSetting Customer360BusDocSetting inner
I_BillingDocumentBasic InvoiceList from

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label Customer 360 Invoice List view
Metadata.allowExtensions true view
Search.searchable true view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XXL view
VDM.viewType #CONSUMPTION view

OData Services (1)

ServiceBindingVersionContractRelease
SD_ADVNCD_CUSTOMER360 SD_ADVNCD_CUSTOMER360 V4 C1 NOT_RELEASED

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY BillingDocument I_BillingDocumentBasic BillingDocument
SoldToParty I_BillingDocumentBasic SoldToParty
CustomerName
BillingDocumentType I_BillingDocumentBasic BillingDocumentType
OverallBillingStatus I_BillingDocumentBasic OverallBillingStatus
BillingDocumentDate I_BillingDocumentBasic BillingDocumentDate
CreationDate I_BillingDocumentBasic CreationDate
SalesOrganization I_BillingDocumentBasic SalesOrganization
TotalNetAmount I_BillingDocumentBasic TotalNetAmount
TransactionCurrency I_BillingDocumentBasic TransactionCurrency
_SoldToParty I_BillingDocumentBasic _SoldToParty
_TransactionCurrency I_BillingDocumentBasic _TransactionCurrency 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Customer 360 Invoice List'
@Metadata.allowExtensions: true
@Search.searchable: true
@ObjectModel: {
//   compositionRoot: true,

//   representativeKey: 'SalesDocument',

   usageType: {
 dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
@VDM.viewType: #CONSUMPTION
define view entity C_Customer360InvoiceList
as select from I_BillingDocumentBasic as InvoiceList
inner join I_Customer360BusDocSetting as Customer360BusDocSetting
  on Customer360BusDocSetting.Cust360BusDocCategory = '3'
    and Customer360BusDocSetting.BusinessDocumentIsEnabled = 'X'
{
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key InvoiceList.BillingDocument as BillingDocument,

      @ObjectModel.text.element: ['CustomerName']   
      @ObjectModel.foreignKey.association: '_SoldToParty'
      InvoiceList.SoldToParty,
      
      @UI.hidden: true
      InvoiceList._SoldToParty.CustomerName as CustomerName,
      
      InvoiceList.BillingDocumentType,
      InvoiceList.OverallBillingStatus,

      InvoiceList.BillingDocumentDate,
      InvoiceList.CreationDate,

      //    For DCL

      InvoiceList.SalesOrganization,


      //@Semantics.currencyCode: true

      //      @Consumption.valueHelpDefinition: [ { entity : { name: 'I_CurrencyStdVH',

      //                                                       element: 'Currency' } } ]

      InvoiceList.TotalNetAmount,

      //  Associations

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      InvoiceList.TransactionCurrency,

      InvoiceList._SoldToParty,
      InvoiceList._TransactionCurrency
}
where
      InvoiceList.CreationDate > dats_add_days( tstmp_to_dats(tstmp_current_utctimestamp(), abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL'), -Customer360BusDocSetting.BusDocumentDurationInDays, 'INITIAL')
  and InvoiceList.CreationDate <= $session.system_date
  and InvoiceList.SDDocumentCategory = '3'

Learn More