C_CreditOpenItem

@AbapCatalog.sqlViewName: 'CCREDITOPENITEM'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Credit Open Items'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
define view C_CreditOpenItem
  as select from I_OperationalAcctgDocItem 
  
  association [0..1] to I_PaytAdviceItemFromAssignment as _PaytAdviceItemFromAssignment on _PaytAdviceItemFromAssignment.FiscalYear = $projection.FiscalYear
                                                                                       and _PaytAdviceItemFromAssignment.CompanyCode = $projection.CompanyCode
                                                                                       and _PaytAdviceItemFromAssignment.AccountingDocument = $projection.AccountingDocument
                                                                                       and _PaytAdviceItemFromAssignment.AccountingDocumentItem = $projection.AccountingDocumentItem
                                                                                       and _PaytAdviceItemFromAssignment.Customer = $projection.Customer
                                                                                       and _PaytAdviceItemFromAssignment.DocumentDate = $projection.DocumentDate
                                                                                       and _PaytAdviceItemFromAssignment.ClearingDate = $projection.ClearingDate
                                                                                       and _PaytAdviceItemFromAssignment.DebitCreditCode = $projection.DebitCreditCode
                                                                                       and _PaytAdviceItemFromAssignment.PaymentAdvice like '09%'
                                                                  
{
  key CompanyCode,
      @Consumption.semanticObject: 'AccountingDocument'
  key AccountingDocument,
  key FiscalYear,
  key AccountingDocumentItem,
      @Semantics.currencyCode: true
      TransactionCurrency,
      @ObjectModel.text.element: ['CustomerName']
      @Consumption.semanticObject: 'Customer'
      Customer,
      AccountingDocumentType,
      PostingKey,
      DocumentDate,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast(AmountInTransactionCurrency as farp_transaction_amount preserving type) as AmountInTransactionCurrency,
      FinancialAccountType,
      SpecialGLCode,
      SpecialGLTransactionType,
      ClearingDate,
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'ClearingJournalEntry'    
      ClearingAccountingDocument,
      ClearingJournalEntry,
      AssignmentReference,
      DocumentItemText,
      @UI.hidden: true
      DebitCreditCode,
      @UI.hidden: true
      _Customer.CustomerName,
      _Customer,
      _PaytAdviceItemFromAssignment.PaymentAdvice,
      Reference1IDByBusinessPartner, 
      _JournalEntry.DocumentReferenceID
}

where
      FinancialAccountType                  =  'D'
  and ClearingAccountingDocument            = ''
  and AccountingDocumentCategory            <> 'D'
  and AccountingDocumentCategory            <> 'M'
  and ( (  DebitCreditCode                   =  'H' 
         and IsNegativePosting             <> 'X' )
     or  ( DebitCreditCode                   =  'S' 
         and IsNegativePosting             =  'X' ) )
  and AmountInTransactionCurrency           <=  0
  and _PaytAdviceItemFromAssignment.PaymentAdvice is null