C_CrdtMemoReqReferenceInvoice

DDL: C_CRDTMEMOREQREFERENCEINVOICE Type: view_entity CONSUMPTION Package: ODATA_SD_CREDITMEMOREQUEST

Credit Memo Request Reference Invoice

C_CrdtMemoReqReferenceInvoice is a Consumption CDS View that provides data about "Credit Memo Request Reference Invoice" in SAP S/4HANA. It reads from 1 data source (I_BillingDocumentBasic) and exposes 11 fields with key field BillingDocument. It has 2 associations to related views. It is exposed through 1 OData service (UI_CREDITMEMOREQUESTMANAGE). Part of development package ODATA_SD_CREDITMEMOREQUEST.

1 data source(s) Exposed by 1 service(s) 11 fields

Data Sources (1)

SourceAliasJoin Type
I_BillingDocumentBasic ReferenceDocument from

Associations (2)

CardinalityTargetAliasCondition
[0..1] I_BillingDocument _BillingDocument $projection.BillingDocument = _BillingDocument.BillingDocument
[0..*] C_CreditMemoReqRefInvoiceItem _ReferenceDocumentItem $projection.BillingDocument = _ReferenceDocumentItem.ReferenceDocument

Annotations (11)

NameValueLevelField
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Credit Memo Request Reference Invoice view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
ObjectModel.representativeKey BillingDocument view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.modelingPattern #NONE view
Search.searchable true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_CREDITMEMOREQUESTMANAGE UI_CREDITMEMOREQUESTMANAGE V4 C1 NOT_RELEASED

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY BillingDocument
BillingDocumentType I_BillingDocumentBasic BillingDocumentType
SoldToParty SoldToParty
CustomerName
TotalNetAmount TotalNetAmount
TransactionCurrency TransactionCurrency
_BillingDocument _BillingDocument
SalesOrganization I_BillingDocumentBasic SalesOrganization
DistributionChannel I_BillingDocumentBasic DistributionChannel
Division I_BillingDocumentBasic Division
_ReferenceDocumentItem _ReferenceDocumentItem 
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Credit Memo Request Reference Invoice'

@Metadata:
{
  ignorePropagatedAnnotations: true,
  allowExtensions: true
}
@ObjectModel: {
  representativeKey: 'BillingDocument',
  usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
  },
  supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
  modelingPattern: #NONE
}
@Search.searchable: true
define view entity C_CrdtMemoReqReferenceInvoice as select from I_BillingDocumentBasic as ReferenceDocument

  association [0..1] to I_BillingDocument         as _BillingDocument       on $projection.BillingDocument = _BillingDocument.BillingDocument
  association [0..*] to C_CreditMemoReqRefInvoiceItem as _ReferenceDocumentItem on $projection.BillingDocument = _ReferenceDocumentItem.ReferenceDocument
{
      @UI.fieldGroup: [{qualifier: 'ReferenceDocInfor1', position: 10, importance: #HIGH}]
      @Search.defaultSearchElement: true
  key cast(ReferenceDocument.BillingDocument as vdm_invoice preserving type ) as BillingDocument,
      ReferenceDocument.BillingDocumentType,

      //Solt-To Party

      @ObjectModel.text.element: [ 'CustomerName' ]
      @UI.textArrangement: #TEXT_FIRST
      @UI.fieldGroup: [{qualifier: 'ReferenceDocInfor2', position: 10, importance: #HIGH}]
      SoldToParty,
      @UI.hidden: true
      _BillingDocument._SoldToParty.CustomerName,

      //Total Amount

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @UI.fieldGroup: [{qualifier: 'ReferenceDocInfor3', position: 10, importance: #HIGH}]
      TotalNetAmount,
      TransactionCurrency,
      
      //ACL

      @Consumption.hidden:true
      _BillingDocument,
      @Consumption.hidden:true
      ReferenceDocument.SalesOrganization,
      @Consumption.hidden:true
      ReferenceDocument.DistributionChannel,
      @Consumption.hidden:true
      ReferenceDocument.Division,

      // Association

     _ReferenceDocumentItem
}
where
  ReferenceDocument.SDDocumentCategory = 'M'

Learn More