C_CrdtMBusPartnerRatingTP

DDL: C_CRDTMBUSPARTNERRATINGTP Type: view_entity CONSUMPTION Package: ODATA_CREDIT_MGMT_MASTER

Credit Rating of a Business Partner

C_CrdtMBusPartnerRatingTP is a Consumption CDS View that provides data about "Credit Rating of a Business Partner" in SAP S/4HANA. It reads from 1 data source (R_CrdtMBusPartnerRatingTP) and exposes 17 fields with key fields BusinessPartner, BPRatingValidityEndDate, BusinessPartnerRatingProcedure. It is exposed through 1 OData service (UI_CRDTMGMTACCOUNT_MANAGE). It is used in 1 Fiori application: Manage Credit Accounts. Part of development package ODATA_CREDIT_MGMT_MASTER.

1 data source(s) Exposed by 1 service(s) Used in 1 Fiori app(s) 17 fields

Data Sources (1)

SourceAliasJoin Type
R_CrdtMBusPartnerRatingTP R_CrdtMBusPartnerRatingTP projection

Annotations (7)

NameValueLevelField
EndUserText.label Credit Rating of a Business Partner view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.serviceQuality #C view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
Metadata.allowExtensions true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_CRDTMGMTACCOUNT_MANAGE UI_CRDTMGMTACCOUNT_MANAGE V2 C1 NOT_TO_BE_RELEASED_STABLE

Fiori Apps (1)

App IDApp NameTypeDescription
F4596 Manage Credit Accounts Transactional

Manage Credit Accounts

Business Role: Credit Controller

Use this app to display and update the credit data for business parters. Edit the credit data of business partners and update the scoring. On the global credit data page, you can see the credit profile for your business partners, as well as detailed information about blocked sales documents or credit limit requests. Find the credit exposure and credit limit utilization highlighted for each credit segment. Navigate to credit segment level to find further information about credit-relevant data, or details about the related sales documents.

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY BusinessPartner BusinessPartner
KEY BPRatingValidityEndDate BPRatingValidityEndDate
KEY BusinessPartnerRatingProcedure BusinessPartnerRatingProcedure
BPRatingProcedureDescriptionlocalized
BPRatingValidityStartDate BPRatingValidityStartDate
BusinessPartnerRatingGrade BusinessPartnerRatingGrade
BusinessPartnerRatingTrend BusinessPartnerRatingTrend
BusinessPartnerRatingTrendDesclocalized
BPRatingCreationDate BPRatingCreationDate
BusinessPartnerRatingComment BusinessPartnerRatingComment
BPRatingValidityEndDateForEdit BPRatingValidityEndDateForEdit
BusinessPartnerRatingIsExpired BusinessPartnerRatingIsExpired
_BPRatingProcedure _BPRatingProcedure
_BPRatingProcedureGrade _BPRatingProcedureGrade
_BPRatingTrend _BPRatingTrend
_BusinessPartner _BusinessPartner
_BPFinancialServicesExtn _BPFinancialServicesExtn 
@EndUserText.label: 'Credit Rating of a Business Partner'

@ObjectModel: { usageType: { dataClass:      #MASTER,
                             sizeCategory:   #L,      //we expecte to have less than 10.000.000 records

                             serviceQuality: #C       //intended for mass processing (building a list by SADL). Unfortunately the basic view promises only serviceQuality: #C

                           }
              }
  
@VDM: {
        viewType:   #CONSUMPTION,
        usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE]
      }

//@ObjectModel: {

//                query: { implementedBy: 'ABAP:CL_UKM_RATING_VE' }

//              }


@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions: true
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]

define view entity C_CrdtMBusPartnerRatingTP
  as projection on R_CrdtMBusPartnerRatingTP
{
  key     BusinessPartner,
  key     BPRatingValidityEndDate,

          @ObjectModel.text.element: ['BPRatingProcedureDescription']
          @Consumption.valueHelpDefinition: [{ entity:{ name:    'I_BPRatingProcedureVH',
                                                        element: 'BusinessPartnerRatingProcedure' } }]
  key     BusinessPartnerRatingProcedure,
          @Semantics.text:true
          _BPRatingProcedure._Text.BPRatingProcedureDescription                                          : localized,

          BPRatingValidityStartDate,

          @ObjectModel.text.element: ['BusinessPartnerRatingGradeDesc']
          @Consumption.valueHelpDefinition: [{ entity:            { name:    'I_BPRatingProcedureGradeVH',
                                                                    element: 'BusinessPartnerRatingGrade'
                                                                  },
                                               additionalBinding: [{ localElement: 'BusinessPartnerRatingProcedure',
                                                                     element:   'BusinessPartnerRatingProcedure',
                                                                     usage:#FILTER
                                                                  }]
                                            }]
          BusinessPartnerRatingGrade,

          @Semantics.text:true
          _BPRatingProcedureGrade._Text.BusinessPartnerRatingGradeDesc as BusinessPartnerRatingGradeDesc : localized,

          @ObjectModel.text.element: ['BusinessPartnerRatingTrendDesc']
          @Consumption.valueHelpDefinition: [{ entity:{ name:    'I_BPRatingTrendVH',
                                                        element: 'BusinessPartnerRatingTrend' } }]
          BusinessPartnerRatingTrend,
          @Semantics.text:true
          _BPRatingTrend._Text.BusinessPartnerRatingTrendDesc                                            : localized,

          BPRatingCreationDate,
          BusinessPartnerRatingComment,

          BPRatingValidityEndDateForEdit,

          BusinessPartnerRatingIsExpired, //for DCL - access control for old ratings


          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_UKM_RATING_VE'
  virtual BPRatingTrendCriticality : ukm_rating_trend_criticality,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_UKM_RATING_VE'
  virtual BPRatingIsValidOnKeyDate : bp_rat_valid,

          _BPRatingProcedure,
          _BPRatingProcedureGrade,
          _BPRatingTrend,
          _BusinessPartner,

          _BPFinancialServicesExtn,

          _CrdtMBusinessPartnerTP : redirected to parent C_CrdtMBusinessPartnerTP
}

Learn More